[gentoo-commits] repo/gentoo:master commit in: media-video/vdr/

[Jörg Bornkessel]

commit:     78de03dc358755693e6e1f8144872d5c877868de
Author:     Joerg Bornkessel <hd_brummy <AT> gentoo <DOT> org>
AuthorDate: Fri Mar  6 22:43:32 2020 +0000
Commit:     Jörg Bornkessel <hd_brummy <AT> gentoo <DOT> org>
CommitDate: Fri Mar  6 22:44:19 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=78de03dc

media-video/vdr: use-flag permashift,support for acct/guid handling

for the next gentoo-vdr-scripts version
with acct/{user,group} handling
we have to change the old homedir
/var/vdr to /var/lib/vdr.
this affects also the VIDEODIR
first improvement in this version.

Package-Manager: Portage-2.3.90, Repoman-2.3.20
Signed-off-by: Joerg Bornkessel <hd_brummy <AT> gentoo.org>

 media-video/vdr/Manifest            |   1 +
 media-video/vdr/vdr-2.4.1-r3.ebuild | 206 ++++++++++++++++++++++++++++++++++++
 2 files changed, 207 insertions(+)

diff --git a/media-video/vdr/Manifest b/media-video/vdr/Manifest
index 645fd58bd16..715cb3e5d65 100644
--- a/media-video/vdr/Manifest
+++ b/media-video/vdr/Manifest
@@ -1,6 +1,7 @@
 DIST extpng-vdr-2.2.0-gentoo-edition-v1.patch.bz2 34664 BLAKE2B 81b68ebe0ef4588c3676f0b7a2c766d8d4d4f754a987b3be5868f3c6eff9158d4cea8e492ca81df535e637dbdc5baff638d1fafb4163e9d9a2d0125aba17e2e1 SHA512 16d6fbb8201f003dfe653b6a49424b794d7e697e27ad6f2383dbe17b76712ea5a3da88a676900b84d75ff7425bf3eb9084d60a89a4598758f482dc1f013f7b3e
 DIST vdr-2.1.5-naludump-0.1.diff 21548 BLAKE2B f193d982d072bbba2261d7dabd82e27795b2e4d8d18ae4486d8c559e7325b87f5902def7bb313e98585331144af62597f6f025f44ca142187e724516bc32c175 SHA512 d9188d5bfcf0588c22dc526fc1082253a1b505b322ccfbe676b8b2c12d4471af7b605924bcea85e879c9606d5e2cecdf6a6e8819cd9b8d877e5bb9f62b91251f
 DIST vdr-2.2.0.tar.bz2 922708 BLAKE2B 975e07d6d4c5bd13ee92be5d6a1826d6404b0c59e20fa2e30689b185a61e02d54782ad528e6a4f15e0d36806b30bcf48aa336d63adb3604e78056ff318e0fd2c SHA512 183f58133915c6c0fe8ec2b88becbcb2a36418210e6dcf7931053d3771d727c3581593f9eb5c9693abf39e22e728f7b41c42079cd704610c3636ec05134ea93d
+DIST vdr-2.4-patch-for-permashift.diff 20424 BLAKE2B 426139bd890e50e491d0061111445d988468441c6bf2f489d35b2b0e290c064ac87e8989cdd9a05e2befd0488300a0d4faa017ab9901152003c6b0f066cce5de SHA512 f21bd6d7b883354c254e1c92d730449dad6eac8ebdd2a593c907a962c2bf3a74859d66e1418984da5b62892d7b7d170282956f15af11d7a788bc759506454ba8
 DIST vdr-2.4.0-ttxtsubs.patch.bz2 16721 BLAKE2B d5c3da713cd82ed8c3baccd1336d283404ebf1099116e76776c26a41ac193aa88bcb5bc2aaa8409a6d40e61c122bbc8ac0d67cb6ff8f83b0dbaea392101643b9 SHA512 99f2cab268d3f6af11607333a35583e5802f90636712e0429eb89eb66ccea7b1fb16a0d3ed2ff266e6f87c338bf77f97028a372eef5e6116b27220a5670a6d31
 DIST vdr-2.4.1.tar.bz2 940623 BLAKE2B 6fa7858e1c0fc25d3332d20347b30515276fc2b54905f32109dfa7f59e4e0c8a83687be405fac063a673c89d77e191f62162b1bd0ed6ee179d32a27f73076fb3 SHA512 b851ebf626de1a6aea11ee9c0cd87d78ebebdc34128925d2027a7030db1262064edb8818566a87ce22d37a9bd2b4f0b4ff1aad8dd251061d9ff972ffe0cf022d
 DIST vdr-2.4.1_mainmenuhook-1.0.1.patch.bz2 1463 BLAKE2B 2be3597a273a92d02be0d072e3d74b39275cbbe17d22e570f416d42c46b53f43209498e569142a2cc357e5f7176d2454cb2a86d0822b29cca913eab2ae9cc27f SHA512 9d3eb501fa06ff5b03361ef65c8ddeeba5f37493cc0edc2d4f54e200e48e17607957fa95bd1540f028bc9a98ad6f42b4d38cf79e9ce971de36bed30def108759

diff --git a/media-video/vdr/vdr-2.4.1-r3.ebuild b/media-video/vdr/vdr-2.4.1-r3.ebuild
new file mode 100644
index 00000000000..288169d7293
--- /dev/null
+++ b/media-video/vdr/vdr-2.4.1-r3.ebuild
@@ -0,0 +1,206 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils flag-o-matic multilib toolchain-funcs
+
+DESCRIPTION="Video Disk Recorder - turns a pc into a powerful set top box for DVB"
+HOMEPAGE="http://www.tvdr.de/"
+SRC_URI="ftp://ftp.tvdr.de/vdr/${P}.tar.bz2
+	mainmenuhooks? ( http://vdr.websitec.de/download/${PN}/${P}/${P}_mainmenuhook-1.0.1.patch.bz2 )
+	menuorg? ( https://projects.vdr-developer.org/projects/plg-menuorg/repository/revisions/master/raw/vdr-patch/vdr-menuorg-2.3.x.diff )
+	naludump? ( http://www.udo-richter.de/vdr/files/vdr-2.1.5-naludump-0.1.diff )
+	pinplugin? ( http://vdr.websitec.de/download/${PN}/${P}/${P}_pinplugin.patch.bz2 )
+	ttxtsubs? ( http://vdr.websitec.de/download/${PN}/${P}/${PN}-2.4.0-ttxtsubs.patch.bz2 )
+	permashift? ( https://raw.githubusercontent.com/eikesauer/Permashift/master/vdr-2.4-patch-for-permashift.diff )"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="bidi debug demoplugins html keyboard mainmenuhooks menuorg naludump pinplugin permashift systemd ttxtsubs verbose"
+
+COMMON_DEPEND="
+	virtual/jpeg:*
+	sys-libs/libcap
+	>=media-libs/fontconfig-2.4.2
+	>=media-libs/freetype-2"
+DEPEND="${COMMON_DEPEND}
+	>=virtual/linuxtv-dvb-headers-5.3"
+RDEPEND="${COMMON_DEPEND}
+	dev-lang/perl
+	media-tv/gentoo-vdr-scripts
+	media-fonts/corefonts
+	bidi? ( dev-libs/fribidi )
+	systemd? ( sys-apps/systemd )"
+BDEPEND="sys-devel/gettext"
+
+REQUIRED_USE="pinplugin? ( !mainmenuhooks )
+	permashift? ( !naludump !pinplugin )"
+
+CONF_DIR="/etc/vdr"
+CAP_FILE="${S}/capabilities.sh"
+CAPS="# Capabilities of the vdr-executable for use by startscript etc."
+
+pkg_setup() {
+	use debug && append-flags -g
+
+	PLUGIN_LIBDIR="/usr/$(get_libdir)/vdr/plugins"
+
+	# use the corrected DIR /var/lib/vdr/* for acct/{user,group) handling
+	if has_version ">=media-tv/gentoo-vdr-scripts-3.0_rc1"; then
+		VIDEO_DIR="/var/lib/vdr/video"
+	else
+		VIDEO_DIR="/var/vdr/video"
+	fi
+
+	tc-export CC CXX AR
+}
+
+add_cap() {
+	local arg
+	for arg; do
+		CAPS="${CAPS}\n${arg}=1"
+	done
+}
+
+lang_po() {
+	LING_PO=$( ls ${S}/po | sed -e "s:.po::g" | cut -d_ -f1 | tr \\\012 ' ' )
+}
+
+src_configure() {
+	# support languages, written from right to left
+	export "BIDI=$(usex bidi 1 0)"
+	# systemd notification support
+	export "SDNOTIFY=$(usex systemd 1 0)"
+	# with/without keyboard
+	export "USE_KBD=$(usex keyboard 1 0)"
+	# detailed compile output for debug
+	export "VERBOSE=$(usex verbose 1 0)"
+}
+
+src_prepare() {
+	# apply maintenance-patches
+	ebegin "Changing paths for gentoo"
+
+	local DVBDIR=/usr/include
+	local i
+	for i in ${DVB_HEADER_PATH} /usr/include/v4l-dvb-hg /usr/include; do
+		[[ -d ${i} ]] || continue
+		if [[ -f ${i}/linux/dvb/dmx.h ]]; then
+			einfo "Found DVB header files in ${i}"
+			DVBDIR=${i}
+			break
+		fi
+	done
+
+	# checking for s2api headers
+	local api_version
+	api_version=$(awk -F' ' '/define DVB_API_VERSION / {print $3}' "${DVBDIR}"/linux/dvb/version.h)
+	api_version=${api_version}*$(awk -F' ' '/define DVB_API_VERSION_MINOR / {print $3}' "${DVBDIR}"/linux/dvb/version.h)
+
+	if [[ ${api_version:-0} -lt 5*3 ]]; then
+		eerror "DVB header files do not contain s2api support or too old for ${P}"
+		eerror "You cannot compile VDR against old dvb-header"
+		die "DVB headers too old"
+	fi
+
+	cat > Make.config <<-EOT || die "cannot write to Make.config"
+		#
+		# Generated by ebuild ${PF}
+		#
+		PREFIX			= /usr
+		DVBDIR			= ${DVBDIR}
+		PLUGINLIBDIR	= ${PLUGIN_LIBDIR}
+		CONFDIR			= ${CONF_DIR}
+		ARGSDIR			= \$(CONFDIR)/conf.d
+		VIDEODIR		= ${VIDEO_DIR}
+		LOCDIR			= \$(PREFIX)/share/locale
+		INCDIR			= \$(PREFIX)/include
+
+		DEFINES			+= -DCONFDIR=\"\$(CONFDIR)\"
+		INCLUDES		+= -I\$(DVBDIR)
+
+		# >=vdr-1.7.36-r1; parameter only used for compiletime on vdr
+		# PLUGINLIBDIR (plugin Makefile old) = LIBDIR (plugin Makefile new)
+		LIBDIR			= ${PLUGIN_LIBDIR}
+		PCDIR			= /usr/$(get_libdir)/pkgconfig
+
+	EOT
+	eend 0
+
+	eapply "${FILESDIR}/${P}_gentoo.patch"
+	eapply "${FILESDIR}/vdr-2.2.0-jpeg-9c.patch"
+	use demoplugins || eapply "${FILESDIR}/vdr-2.4_remove_plugins.patch"
+	eapply "${FILESDIR}/${P}_makefile-variables.patch"
+	eapply "${FILESDIR}/${P}_glibc-2.31.patch"
+
+	use naludump && eapply "${DISTDIR}/${PN}-2.1.5-naludump-0.1.diff"
+	use permashift && eapply "${DISTDIR}/${PN}-2.4-patch-for-permashift.diff"
+	use pinplugin && eapply "${WORKDIR}/${P}_pinplugin.patch"
+	use ttxtsubs && eapply "${WORKDIR}/${PN}-2.4.0-ttxtsubs.patch"
+	use ttxtsubs && eapply "${FILESDIR}/${P}_ttxtsubs_segfault.patch"
+	use menuorg && eapply "${DISTDIR}/vdr-menuorg-2.3.x.diff"
+	use mainmenuhooks && eapply "${WORKDIR}/${P}_mainmenuhook-1.0.1.patch"
+
+	add_cap CAP_UTF8 \
+		CAP_IRCTRL_RUNTIME_PARAM \
+		CAP_VFAT_RUNTIME_PARAM \
+		CAP_CHUID \
+		CAP_SHUTDOWN_AUTO_RETRY
+
+	echo -e ${CAPS} > "${CAP_FILE}" || die "cannot write to CAP_FILE"
+
+	# LINGUAS support
+	einfo "\n \t VDR supports the LINGUAS values"
+
+	lang_po
+
+	einfo "\t Please set one of this values in your sytem make.conf"
+	einfo "\t LINGUAS=\"${LING_PO}\"\n"
+
+	if [[ -z ${LINGUAS} ]]; then
+		einfo "\n \t No values in LINGUAS="
+		einfo "\t You will get only english text on OSD \n"
+	fi
+
+	strip-linguas ${LING_PO} en
+
+	default
+}
+
+src_install() {
+	# trick the makefile to not create a VIDEODIR by supplying it with an
+	# existing directory
+	emake VIDEODIR="/" DESTDIR="${ED}" install
+
+	keepdir "${PLUGIN_LIBDIR}"
+
+	# backup for plugins they don't be able to create this dir
+	keepdir "${CONF_DIR}/plugins"
+
+	if use html; then
+		local HTML_DOCS=( *.html )
+	fi
+	local DOCS=( MANUAL INSTALL README* HISTORY CONTRIBUTORS UPDATE-2* )
+	einstalldocs
+
+	insinto /usr/share/vdr
+	doins "${CAP_FILE}"
+
+	fowners vdr:vdr "${CONF_DIR}" -R
+}
+
+pkg_postinst() {
+	elog "Please read the /usr/share/doc/${PF}/UPDATE-2.4"
+	elog "for major changes in this version\n"
+
+	elog "It is a good idea to run vdrplugin-rebuild now.\n"
+
+	elog "To get nice symbols in OSD we recommend to install"
+	elog "\t1. emerge media-fonts/vdrsymbols-ttf"
+	elog "\t2. select font VDRSymbolsSans in Setup\n"
+
+	elog "To get an idea how to proceed now, have a look at our vdr-guide:"
+	elog "\thttps://wiki.gentoo.org/wiki/VDR"
+}