[gentoo-commits] gentoo-x86 commit in sci-libs/scikits_statsmodels: scikits_statsmodels-0.3.0.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    11/07/26 17:28:59

  Modified:             ChangeLog
  Added:                scikits_statsmodels-0.3.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.7/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  sci-libs/scikits_statsmodels/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_statsmodels/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_statsmodels/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_statsmodels/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/scikits_statsmodels/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	19 Jan 2011 16:59:10 -0000	1.2
+++ ChangeLog	26 Jul 2011 17:28:59 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for sci-libs/scikits_statsmodels
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_statsmodels/ChangeLog,v 1.2 2011/01/19 16:59:10 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_statsmodels/ChangeLog,v 1.3 2011/07/26 17:28:59 bicatali Exp $
+
+*scikits_statsmodels-0.3.0 (26 Jul 2011)
+
+  26 Jul 2011; Sébastien Fabbro <bicatali@g.o>
+  +scikits_statsmodels-0.3.0.ebuild:
+  Version bump
 
   19 Jan 2011; Sébastien Fabbro <bicatali@g.o>
   scikits_statsmodels-0.2.0.ebuild:



1.1                  sci-libs/scikits_statsmodels/scikits_statsmodels-0.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_statsmodels/scikits_statsmodels-0.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_statsmodels/scikits_statsmodels-0.3.0.ebuild?rev=1.1&content-type=text/plain

Index: scikits_statsmodels-0.3.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_statsmodels/scikits_statsmodels-0.3.0.ebuild,v 1.1 2011/07/26 17:28:59 bicatali Exp $

EAPI="2"

PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"

inherit distutils

MY_P="${P/scikits_/scikits.}"

DESCRIPTION="Statistical computations and models for use with SciPy"
HOMEPAGE="http://scikits.appspot.com/statsmodels"
SRC_URI="mirror://pypi/${PN:0:1}/scikits.statsmodels/${MY_P}.zip"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples test"

RDEPEND="sci-libs/scipy
	sci-libs/scikits"
DEPEND="dev-python/numpy
	dev-python/setuptools
	doc? ( dev-python/sphinx )
	test? ( dev-python/nose )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# remove badly placed docs and examples
	sed -i \
		-e '/statsmodels\/docs/d' \
		-e '/statsmodels\/examples/d' \
		setup.py || die
	mv scikits/statsmodels/{docs,examples} .
	distutils_src_prepare
}

src_compile() {
	distutils_src_compile
	if use doc; then
		"$(PYTHON -f)" setup.py build_sphinx || die "Generation of documentation failed"
	fi
}

src_test() {
	testing() {
		"$(PYTHON)" setup.py \
			build -b "build-${PYTHON_ABI}" \
			install --home="${S}/test-${PYTHON_ABI}"
		pushd "${S}/test-${PYTHON_ABI}/lib" > /dev/null
		PYTHONPATH=. "$(PYTHON)" -c "import scikits.statsmodels; scikits.statsmodels.test()" 2>&1 | tee test.log
		grep -Eq '^(ERROR|FAIL):' test.log && return 1
		popd > /dev/null
		rm -fr test-${PYTHON_ABI}
	}
	python_execute_function testing
}

src_install() {
	find "${S}" -name \*LICENSE.txt -delete
	distutils_src_install
	remove_scikits() {
		rm -f "${ED}"$(python_get_sitedir)/scikits/__init__.py || die
	}
	python_execute_function -q remove_scikits
	insinto /usr/share/doc/${PF}
	if use doc; then
		doins -r build/sphinx/html || die
	fi
	if use examples; then
		doins -r examples || die
	fi
}