[gentoo-commits] gentoo-x86 commit in dev-java/stringtemplate: metadata.xml stringtemplate-3.2.ebuild ChangeLog

[Petteri Raty (betelgeuse)]

betelgeuse    09/03/29 00:13:43

  Added:                metadata.xml stringtemplate-3.2.ebuild ChangeLog
  Log:
  Moving stringtemplate to the main tree from java-experimental. Several Java team members showed in the logs. Part of bug #146952.
  (Portage version: 2.2_rc27/cvs/Linux i686)

Revision  Changes    Path
1.1                  dev-java/stringtemplate/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/stringtemplate/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/stringtemplate/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>java</herd>
</pkgmetadata>



1.1                  dev-java/stringtemplate/stringtemplate-3.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/stringtemplate/stringtemplate-3.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/stringtemplate/stringtemplate-3.2.ebuild?rev=1.1&content-type=text/plain

Index: stringtemplate-3.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/stringtemplate/stringtemplate-3.2.ebuild,v 1.1 2009/03/29 00:13:43 betelgeuse Exp $

EAPI="2"
JAVA_PKG_IUSE="doc source"
WANT_ANT_TASKS="ant-antlr"

inherit eutils java-pkg-2 java-ant-2

MY_PV="${PV/_beta/b}"
S_PV="${PV/_beta/.b}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="A Java template engine"
HOMEPAGE="http://www.stringtemplate.org/"
SRC_URI="http://www.stringtemplate.org/download/${MY_P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

# no junit targets in build.xml, but unconditional compile and jar of test
# classes, oh well
COMMON_DEPEND="dev-java/antlr:0
	dev-java/junit:0"

RDEPEND=">=virtual/jre-1.4
	${COMMON_DEPEND}"

DEPEND=">=virtual/jdk-1.4
	${COMMON_DEPEND}"

S="${WORKDIR}/${PN}-${S_PV}"

java_prepare() {
	# fix <javadoc> call
	epatch "${FILESDIR}/${PN}-3.1_beta1-javadoc.patch"
	java-ant_rewrite-classpath
	rm -v lib/*.jar || die
	# force regeneration with our antlr2
	touch src/org/antlr/stringtemplate/language/*.g || die
}

EANT_GENTOO_CLASSPATH="antlr,junit"
EANT_DOC_TARGET="javadocs"

src_install() {
	java-pkg_dojar build/${PN}.jar

	dodoc README.txt CHANGES.txt || die
	use doc && java-pkg_dojavadoc docs/api
	use source && java-pkg_dosrc src/org
}



1.1                  dev-java/stringtemplate/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/stringtemplate/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/stringtemplate/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-java/stringtemplate
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/stringtemplate/ChangeLog,v 1.1 2009/03/29 00:13:43 betelgeuse Exp $

*stringtemplate-3.2 (29 Mar 2009)

  29 Mar 2009; Petteri Räty <betelgeuse@g.o>
  +files/stringtemplate-3.1_beta1-javadoc.patch, +metadata.xml,
  +stringtemplate-3.2.ebuild:
  Moving stringtemplate to the main tree from java-experimental. Several Java
  team members showed in the logs. Part of bug #146952.