[gentoo-commits] gentoo-x86 commit in net-misc/curl: ChangeLog curl-7.23.1.ebuild

[Mike Frysinger (vapier)]

vapier      11/12/01 18:35:02

  Modified:             ChangeLog
  Added:                curl-7.23.1.ebuild
  Log:
  Version bump.  Should include fix for #387641 by Tim Harder and for #382241 by Alessandro Surace.
  
  (Portage version: 2.2.0_alpha75/cvs/Linux x86_64)

Revision  Changes    Path
1.194                net-misc/curl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/ChangeLog?rev=1.194&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/ChangeLog?rev=1.194&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/ChangeLog?r1=1.193&r2=1.194

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v
retrieving revision 1.193
retrieving revision 1.194
diff -u -r1.193 -r1.194
--- ChangeLog	14 Nov 2011 17:10:55 -0000	1.193
+++ ChangeLog	1 Dec 2011 18:35:02 -0000	1.194
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/curl
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v 1.193 2011/11/14 17:10:55 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v 1.194 2011/12/01 18:35:02 vapier Exp $
+
+*curl-7.23.1 (01 Dec 2011)
+
+  01 Dec 2011; Mike Frysinger <vapier@g.o> +curl-7.23.1.ebuild:
+  Version bump. Should include fix for #387641 by Tim Harder and for #382241 by
+  Alessandro Surace.
 
   14 Nov 2011; Christoph Mende <angelos@g.o> curl-7.22.0.ebuild:
   Prefer openssl over nss



1.1                  net-misc/curl/curl-7.23.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/curl-7.23.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/curl-7.23.1.ebuild?rev=1.1&content-type=text/plain

Index: curl-7.23.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/curl-7.23.1.ebuild,v 1.1 2011/12/01 18:35:02 vapier Exp $

EAPI=4

inherit autotools eutils prefix

DESCRIPTION="A Client that groks URLs"
HOMEPAGE="http://curl.haxx.se/"
SRC_URI="http://curl.haxx.se/download/${P}.tar.bz2"

LICENSE="MIT"
SLOT="0"
#KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="ares gnutls idn ipv6 kerberos ldap libssh2 nss ssl static-libs test threads"

RDEPEND="ldap? ( net-nds/openldap )
	gnutls? ( net-libs/gnutls dev-libs/libgcrypt app-misc/ca-certificates )
	ssl? ( !gnutls? ( dev-libs/openssl ) )
	nss? ( !gnutls? ( !ssl? ( dev-libs/nss app-misc/ca-certificates ) ) )
	idn? ( net-dns/libidn )
	ares? ( >=net-dns/c-ares-1.6 )
	kerberos? ( virtual/krb5 )
	libssh2? ( >=net-libs/libssh2-0.16 )"

# rtmpdump ( media-video/rtmpdump )  / --with-librtmp
# fbopenssl (not in gentoo) --with-spnego
# krb4 http://web.mit.edu/kerberos/www/krb4-end-of-life.html

DEPEND="${RDEPEND}
	sys-apps/ed
	test? (
		sys-apps/diffutils
		dev-lang/perl
	)"
# used - but can do without in self test: net-misc/stunnel

# ares must be disabled for threads and both can be disabled
# one can use wether gnutls or nss if ssl is enabled
REQUIRED_USE="threads? ( !ares )
	nss? ( !gnutls )"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-7.20.0-strip-ldflags.patch \
		"${FILESDIR}"/${PN}-7.19.7-test241.patch \
		"${FILESDIR}"/${PN}-7.18.2-prefix.patch \
		"${FILESDIR}"/${PN}-respect-cflags-3.patch
	sed -i '/LD_LIBRARY_PATH=/d' configure.ac || die #382241

	eprefixify curl-config.in
	eautoreconf
}

src_configure() {
	local myconf

	if use gnutls; then
		myconf+=" --without-ssl --with-gnutls --without-nss"
		myconf+=" --with-ca-bundle=${EPREFIX}/etc/ssl/certs/ca-certificates.crt"
	elif use ssl; then
		myconf+=" --without-gnutls --without-nss --with-ssl"
		myconf+=" --without-ca-bundle --with-ca-path=${EPREFIX}/etc/ssl/certs"
	elif use nss; then
		myconf+=" --without-ssl --without-gnutls --with-nss"
		myconf+=" --with-ca-bundle=${EPREFIX}/etc/ssl/certs/ca-certificates.crt"
	else
		myconf+=" --without-gnutls --without-nss --without-ssl"
	fi

	econf \
		$(use_enable ldap) \
		$(use_enable ldap ldaps) \
		$(use_with idn libidn) \
		$(use_with kerberos gssapi "${EPREFIX}"/usr) \
		$(use_with libssh2) \
		$(use_enable static-libs static) \
		$(use_enable ipv6) \
		$(use_enable threads threaded-resolver) \
		$(use_enable ares) \
		--enable-http \
		--enable-ftp \
		--enable-gopher \
		--enable-file \
		--enable-dict \
		--enable-manual \
		--enable-telnet \
		--enable-smtp \
		--enable-pop3 \
		--enable-imap \
		--enable-rtsp \
		--enable-nonblocking \
		--enable-largefile \
		--enable-maintainer-mode \
		--disable-sspi \
		--without-krb4 \
		--without-librtmp \
		--without-spnego \
		${myconf}
}

src_compile() {
	default
	ed - lib/curl_config.h < "${FILESDIR}"/config.h.ed || die
	ed - src/curl_config.h < "${FILESDIR}"/config.h.ed || die
	ed - include/curl/curlbuild.h < "${FILESDIR}"/curlbuild.h.ed || die
}

src_install() {
	default
	find "${ED}" -name '*.la' -delete
	rm -rf "${ED}"/etc/

	# https://sourceforge.net/tracker/index.php?func=detail&aid=1705197&group_id=976&atid=350976
	insinto /usr/share/aclocal
	doins docs/libcurl/libcurl.m4

	dodoc CHANGES README
	dodoc docs/FEATURES docs/INTERNALS
	dodoc docs/MANUAL docs/FAQ docs/BUGS docs/CONTRIBUTE
}