[gentoo-commits] repo/gentoo:master commit in: games-emulation/dosbox-staging/

[Bernard Cafarelli]

commit:     b543b99a457e15cff0389a7954fa9641cb5eac10
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 21 13:17:45 2020 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Fri Aug 21 13:19:54 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b543b99a

games-emulation/dosbox-staging: fix sdl2-net dep

Also add a USE-flag for it

Closes: https://bugs.gentoo.org/738360
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 .../dosbox-staging/dosbox-staging-0.75.1-r1.ebuild | 50 ++++++++++++++++++++++
 games-emulation/dosbox-staging/metadata.xml        |  1 +
 2 files changed, 51 insertions(+)

diff --git a/games-emulation/dosbox-staging/dosbox-staging-0.75.1-r1.ebuild b/games-emulation/dosbox-staging/dosbox-staging-0.75.1-r1.ebuild
new file mode 100644
index 00000000000..dbebde3b22e
--- /dev/null
+++ b/games-emulation/dosbox-staging/dosbox-staging-0.75.1-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools desktop
+
+DESCRIPTION="Modernized DOSBox soft-fork"
+HOMEPAGE="https://dosbox-staging.github.io/"
+SRC_URI="https://github.com/dosbox-staging/dosbox-staging/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug dynrec network opengl opus"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	debug? ( sys-libs/ncurses:0= )
+	network? ( media-libs/sdl2-net )
+	opengl? ( virtual/opengl )
+	opus? ( media-libs/opusfile )
+	media-libs/libpng:0=
+	media-libs/libsdl2[joystick,opengl?,video,X]
+	sys-libs/zlib
+	!games-emulation/dosbox"
+DEPEND="${RDEPEND}"
+BDEPEND=""
+
+PATCHES=( "${FILESDIR}"/${P}-pthread.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable alsa alsa-midi) \
+		$(use_enable debug) \
+		$(use_enable !dynrec dynamic-x86) \
+		$(use_enable dynrec) \
+		$(use_enable network) \
+		$(use_enable opengl) \
+		$(use_enable opus opus-cdda)
+}
+
+src_install() {
+	default
+	doicon contrib/icons/${PN}.svg
+	make_desktop_entry dosbox DOSBox-staging ${PN}
+}

diff --git a/games-emulation/dosbox-staging/metadata.xml b/games-emulation/dosbox-staging/metadata.xml
index ea78ea742a7..91406d636bc 100644
--- a/games-emulation/dosbox-staging/metadata.xml
+++ b/games-emulation/dosbox-staging/metadata.xml
@@ -7,6 +7,7 @@
 	</maintainer>
 	<use>
 		<flag name="dynrec">Use recompiling cpu core instead of dynamic x86/x64 specific cpu core</flag>
+		<flag name="network">Enable networking features (modem, ipx)</flag>
 		<flag name="opus">Support compressed audio tracks (.opus) used with CDROM images</flag>
 	</use>
 	<upstream>