[gentoo-commits] repo/gentoo:master commit in: app-arch/zpaq/

[Michał Górny]

commit:     7b99fb52d2c9f8e3a3ffc9659bfe17c8906af09d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Jul  3 13:27:05 2016 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jul  3 13:29:24 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7b99fb52

app-arch/zpaq: Merge libzpaq into the package

 app-arch/zpaq/zpaq-7.13-r1.ebuild | 54 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/app-arch/zpaq/zpaq-7.13-r1.ebuild b/app-arch/zpaq/zpaq-7.13-r1.ebuild
new file mode 100644
index 0000000..a05100b
--- /dev/null
+++ b/app-arch/zpaq/zpaq-7.13-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit flag-o-matic toolchain-funcs
+
+MY_P=${PN}${PV/./}
+DESCRIPTION="Journaling incremental deduplicating archiving compressor"
+HOMEPAGE="http://mattmahoney.net/dc/zpaq.html"
+SRC_URI="http://mattmahoney.net/dc/${MY_P}.zip"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug +jit"
+
+# now 2in1!
+RDEPEND="!app-arch/libzpaq"
+# perl for pod2man
+DEPEND="
+	app-arch/unzip
+	dev-lang/perl"
+
+S=${WORKDIR}
+
+src_prepare() {
+	default
+	sed -i -e '/^zpaq:/,+1s/libzpaq\.o/$(SONAME)/' Makefile || die
+}
+
+src_compile() {
+	use debug || append-cppflags -DNDEBUG
+	use jit || append-cppflags -DNOJIT
+	emake CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS}"
+}
+
+src_test() {
+	local -x LD_LIBRARY_PATH=".${LD_LIBRARY_PATH+:${LD_LIBRARY_PATH}}"
+	default
+}
+
+src_install() {
+	emake install PREFIX="${ED%/}"/usr LIBDIR="\$(PREFIX)/$(get_libdir)"
+	einstalldocs
+}
+
+pkg_postinst() {
+	if ! has_version app-arch/zpaq-extras; then
+		elog "You may also want to install app-arch/zpaq-extras package which provides"
+		elog "few additional configs and preprocessors for use with zpaq."
+	fi
+}