[gentoo-commits] repo/gentoo:master commit in: media-libs/libv4l/

[James Le Cuirot]

commit:     6b3fad27b0187e52a632e1a79b1ac101f0a63736
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 18 22:41:50 2023 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Sat Mar 18 23:38:17 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6b3fad27

media-libs/libv4l: Version bump to 1.24.1

Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 media-libs/libv4l/Manifest             |  1 +
 media-libs/libv4l/libv4l-1.24.1.ebuild | 74 ++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/media-libs/libv4l/Manifest b/media-libs/libv4l/Manifest
index eaca215a25f2..9a88ad1c15fe 100644
--- a/media-libs/libv4l/Manifest
+++ b/media-libs/libv4l/Manifest
@@ -1 +1,2 @@
 DIST v4l-utils-1.22.1.tar.bz2 2086238 BLAKE2B a3f01a17ea7c8925c74dd883d30b42f54b7926d253dac79e4cadaba43abc33672804257b3b92e5aa640ead6b5aaaa2458f05e21642044d7dea77e5580a8dbe9a SHA512 8a634d8995d13f453dfaf90ca5d0dfb26f2f4b10a0d200d76a949c46f77040d12fc0a5b35e05d7b1ba68bcfc85a445be5a5ab1d4a7d4eabfe3a254038ccc6170
+DIST v4l-utils-1.24.1.tar.bz2 2238340 BLAKE2B 1702918699d47b17467e012c2b1875c58851175c1007351a3b40d0b0fa40437eb695efa9e21afe3351f66780899d45798eef7f23c90a4831bface70a245b8a54 SHA512 1e82ba125285e875bf4a216adedab9147009e6af1aadd79a3a1770231d3c96ec29245b33e75f69a9ce1b25011e71746db242c778ac3369148de1e9de2e318663

diff --git a/media-libs/libv4l/libv4l-1.24.1.ebuild b/media-libs/libv4l/libv4l-1.24.1.ebuild
new file mode 100644
index 000000000000..f740eb8669a1
--- /dev/null
+++ b/media-libs/libv4l/libv4l-1.24.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools linux-info multilib-minimal
+
+MY_P="v4l-utils-${PV}"
+
+DESCRIPTION="Separate libraries ebuild from upstream v4l-utils package"
+HOMEPAGE="https://git.linuxtv.org/v4l-utils.git"
+SRC_URI="https://linuxtv.org/downloads/v4l-utils/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="dvb jpeg"
+
+RDEPEND="
+	dvb? ( virtual/libudev[${MULTILIB_USEDEP}] )
+	!elibc_glibc? ( sys-libs/argp-standalone )
+	jpeg? ( >=virtual/jpeg-0-r2:0=[${MULTILIB_USEDEP}] )
+	!media-tv/v4l2-ctl
+	!<media-tv/ivtv-utils-1.4.0-r2
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	CONFIG_CHECK="~SHMEM"
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# Hard disable the flags that apply only to the utils.
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-static \
+		$(use_enable dvb libdvbv5) \
+		--disable-qv4l2 \
+		--disable-qvidcap \
+		--disable-v4l-utils \
+		$(use_with jpeg) \
+		$(use_with dvb libudev)
+}
+
+multilib_src_compile() {
+	emake -C lib
+}
+
+multilib_src_install() {
+	emake -j1 -C lib DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+	dodoc ChangeLog README.lib* TODO
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
+}