[gentoo-commits] gentoo-x86 commit in dev-cpp/eigen: ChangeLog eigen-3.0.2.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    11/09/06 21:23:11

  Modified:             ChangeLog
  Added:                eigen-3.0.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.13/cvs/Linux x86_64)

Revision  Changes    Path
1.49                 dev-cpp/eigen/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-cpp/eigen/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	3 Sep 2011 22:04:07 -0000	1.48
+++ ChangeLog	6 Sep 2011 21:23:11 -0000	1.49
@@ -1,6 +1,11 @@
 # ChangeLog for dev-cpp/eigen
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/ChangeLog,v 1.48 2011/09/03 22:04:07 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/ChangeLog,v 1.49 2011/09/06 21:23:11 dilfridge Exp $
+
+*eigen-3.0.2 (06 Sep 2011)
+
+  06 Sep 2011; Andreas K. Huettel <dilfridge@g.o> +eigen-3.0.2.ebuild:
+  Version bump
 
 *eigen-2.0.16 (03 Sep 2011)
 



1.1                  dev-cpp/eigen/eigen-3.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/eigen-3.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/eigen-3.0.2.ebuild?rev=1.1&content-type=text/plain

Index: eigen-3.0.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/eigen-3.0.2.ebuild,v 1.1 2011/09/06 21:23:11 dilfridge Exp $

EAPI="2"

inherit cmake-utils

DESCRIPTION="C++ template library for linear algebra: vectors, matrices, and related algorithms"
HOMEPAGE="http://eigen.tuxfamily.org/"
SRC_URI="http://bitbucket.org/eigen/eigen/get/${PV}.tar.bz2 -> ${P}.tar.bz2"

LICENSE="LGPL-2 GPL-3"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
SLOT="3"
IUSE="debug doc"

DEPEND="doc? ( app-doc/doxygen )"
RDEPEND="!dev-cpp/eigen:0"

PATCHES=( "${FILESDIR}"/${PN}-3.0.0-gcc46.patch )

src_unpack() {
	unpack ${A}
	mv ${PN}* ${P}
}

src_configure() {
	# benchmarks (BTL) brings up damn load of external deps including fortran
	# compiler
	CMAKE_BUILD_TYPE="release"
	mycmakeargs=(
		-DEIGEN_BUILD_BTL=OFF
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	if use doc; then
		cd "${CMAKE_BUILD_DIR}"
		emake doc || die "building documentation failed"
	fi
}

src_install() {
	cmake-utils_src_install
	if use doc; then
		cd "${CMAKE_BUILD_DIR}"/doc
		dohtml -r html/* || die "dohtml failed"
	fi
}

src_test() {
	mycmakeargs=(
		-DEIGEN_BUILD_TESTS=ON
		-DEIGEN_TEST_NO_FORTRAN=ON
	)
	cmake-utils_src_configure
	cmake-utils_src_compile
	cmake-utils_src_test
}