[gentoo-commits] gentoo-x86 commit in sys-apps/kexec-tools: kexec-tools-2.0.9-r2.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        15/06/29 07:49:24

  Modified:             ChangeLog
  Added:                kexec-tools-2.0.9-r2.ebuild
  Log:
  Correctly handle loaded image during reboot with LOAD_DURING_SHUTDOWN, bug #553372; thanks AaylaSecura for the patch
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

Revision  Changes    Path
1.67                 sys-apps/kexec-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/ChangeLog?r1=1.66&r2=1.67

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/kexec-tools/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog	15 Apr 2015 08:37:14 -0000	1.66
+++ ChangeLog	29 Jun 2015 07:49:24 -0000	1.67
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/kexec-tools
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kexec-tools/ChangeLog,v 1.66 2015/04/15 08:37:14 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kexec-tools/ChangeLog,v 1.67 2015/06/29 07:49:24 jlec Exp $
+
+*kexec-tools-2.0.9-r2 (29 Jun 2015)
+
+  29 Jun 2015; Justin Lecher <jlec@g.o> +files/kexec.init-2.0.4-r3,
+  +kexec-tools-2.0.9-r2.ebuild:
+  Correctly handle loaded image during reboot with LOAD_DURING_SHUTDOWN, bug
+  #553372; thanks AaylaSecura for the patch
 
 *kexec-tools-2.0.9-r1 (15 Apr 2015)
 



1.1                  sys-apps/kexec-tools/kexec-tools-2.0.9-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/kexec-tools-2.0.9-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/kexec-tools-2.0.9-r2.ebuild?rev=1.1&content-type=text/plain

Index: kexec-tools-2.0.9-r2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/kexec-tools/kexec-tools-2.0.9-r2.ebuild,v 1.1 2015/06/29 07:49:24 jlec Exp $

EAPI=5

inherit autotools-utils linux-info systemd

DESCRIPTION="Load another kernel from the currently executing Linux kernel"
HOMEPAGE="http://kernel.org/pub/linux/utils/kernel/kexec/"
SRC_URI="mirror://kernel/linux/utils/kernel/kexec/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="booke lzma xen zlib"

REQUIRED_USE="lzma? ( zlib )"

DEPEND="
	lzma? ( app-arch/xz-utils )
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}"

CONFIG_CHECK="~KEXEC"

PATCHES=(
	"${FILESDIR}"/${PN}-2.0.4-disable-kexec-test.patch
	"${FILESDIR}"/${PN}-2.0.4-out-of-source.patch
	"${FILESDIR}"/${PN}-2.0.9-hardened.patch
)

pkg_setup() {
	# GNU Make's $(COMPILE.S) passes ASFLAGS to $(CCAS), CCAS=$(CC)
	export ASFLAGS="${CCASFLAGS}"
}

src_configure() {
	local myeconfargs=(
		$(use_with booke)
		$(use_with lzma)
		$(use_with xen)
		$(use_with zlib)
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	dodoc "${FILESDIR}"/README.Gentoo

	newinitd "${FILESDIR}"/kexec.init-2.0.4-r3 kexec
	newconfd "${FILESDIR}"/kexec.conf-2.0.4 kexec

	insinto /etc
	doins "${FILESDIR}"/kexec.conf

	insinto /etc/kernel/postinst.d
	doins "${FILESDIR}"/90_kexec

	systemd_dounit "${FILESDIR}"/kexec.service
}

pkg_postinst() {
	if systemd_is_booted || has_version sys-apps/systemd; then
		elog "For systemd support the new config file is"
		elog "   /etc/kexec.conf"
		elog "Please adopt it to your needs as there is no autoconfig anymore"
	fi
}