[gentoo-commits] repo/gentoo:master commit in: dev-libs/libinput/

[Lars Wendler]

commit:     cc4aefe13d2368b2013554545aafbd4471b4620b
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 17 11:17:38 2021 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Sep 17 11:17:38 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cc4aefe1

dev-libs/libinput: Bump to version 1.19.0

Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 dev-libs/libinput/Manifest               |  1 +
 dev-libs/libinput/libinput-1.19.0.ebuild | 88 ++++++++++++++++++++++++++++++++
 2 files changed, 89 insertions(+)

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 1aa164f2eb7..3ae76ad5b8c 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1,2 +1,3 @@
 DIST libinput-1.18.0.tar.xz 616732 BLAKE2B 4f12080b5e3496fdb5ccb1375a073860c26037ba47033a7d2d69a2f817b4ab5791aa89be08b193925cddd566a04144c73399cbb196a4cc9d3e07dcfb806d3eff SHA512 9a834f075d7a1f892416bb6b241eb052f749d3aa883c4b39c0f1c9616c115d6b9a541b587508646fddaf0d3fe57af92fe4629b522d1d51196499e7b523e0aa90
 DIST libinput-1.18.1.tar.xz 618524 BLAKE2B 17c5959b6319838dc65f6df7c532d8e048b0295d20178e636dcb3d7a0418f7c107ffc34f280ac0da66011cc80fb8e9f0881b5edd6a4fb64fb674dff6bb5b4526 SHA512 450e38c0f8245aa0165a8047d25aebee646332f0f2ed442bb2d1bd3e723c2082b6d00d6e3bda308981ece8e29b5cddbd56eab900d2b7497705a45fc27b281828
+DIST libinput-1.19.0.tar.xz 654308 BLAKE2B 6942e704881360724d02f94a9ab87b90c350d16c28305af796a55eed67665cb4c4cbf035a0aaa085ccfc0027bb1936e722bf43dea53dee1c80b2376859dfba9f SHA512 daf42ce797f2b5aef8d6f7a5c0d967590581e6ac12c26fa6bde5fbc619d75319e39ca55d65d5347e554dd6a48b91f5fed4d3167eabef8ad1ebc43bc0c3e8e220

diff --git a/dev-libs/libinput/libinput-1.19.0.ebuild b/dev-libs/libinput/libinput-1.19.0.ebuild
new file mode 100644
index 00000000000..7eac9e2a392
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.19.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 2014-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? ( dev-util/valgrind )
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+	>=dev-libs/libevdev-1.3
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-libs/check-0.9.10 )"
+
+python_check_deps() {
+	has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+	has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed "s@, '-Werror'@@" -i meson.build || die #744250
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		$(meson_use test tests)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	pkgname="dev-python/python-libevdev"
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "${pkgname}" ; then
+		einfo "${pkgname} must be installed to use the"
+		einfo "libinput measure and libinput replay tools."
+	fi
+
+	udevadm hwdb --update --root="${ROOT}"
+}