[gentoo-commits] repo/gentoo:master commit in: dev-python/pyopenssl/

[Tim Harder]

commit:     b6a25e84652feefac732dd27148c692c44b6d070
Author:     Tim Harder <radhermit <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 30 09:21:22 2018 +0000
Commit:     Tim Harder <radhermit <AT> gentoo <DOT> org>
CommitDate: Sun Dec 30 09:22:26 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b6a25e84

dev-python/pyopenssl: version bump to 18.0.0

Signed-off-by: Tim Harder <radhermit <AT> gentoo.org>

 dev-python/pyopenssl/Manifest                |  1 +
 dev-python/pyopenssl/pyopenssl-18.0.0.ebuild | 67 ++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-python/pyopenssl/Manifest b/dev-python/pyopenssl/Manifest
index 3ca7bd7f784..8c8c81327f9 100644
--- a/dev-python/pyopenssl/Manifest
+++ b/dev-python/pyopenssl/Manifest
@@ -1 +1,2 @@
 DIST pyOpenSSL-17.5.0.tar.gz 170870 BLAKE2B e8b8986a7c5475ac3898df4877a8be86db359af79e1718bad85149440cff543c501ee23eb369270d2c539a9e3f4e13165ea87b858ef6916ee79ca6e49f6e5370 SHA512 f194662b5842f1e3a4fcb910b9f2e6482d1dcdf834f306acc3dd6d9723f65038f7bff550248fa6268d90c839c9d9e8248bb6c7d399495fe6aed25291b93ece86
+DIST pyOpenSSL-18.0.0.tar.gz 167296 BLAKE2B 3a9c8db02e92858353389508d9791d2ff0b07b54150d27a513b4c26ef62899167d184702cd8ac3a9fb5be120a92e31259ce265a400513de4622c30b1269ecd9f SHA512 7106d4116243a164c1f458ad495564c2cf3a46b4b0fbb1d452b4174ead4409bc9c783c3a4674231ed3c26ecf588077b01dadbdefe033d5e7251a61531c6f6c15

diff --git a/dev-python/pyopenssl/pyopenssl-18.0.0.ebuild b/dev-python/pyopenssl/pyopenssl-18.0.0.ebuild
new file mode 100644
index 00000000000..f302d4d1027
--- /dev/null
+++ b/dev-python/pyopenssl/pyopenssl-18.0.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN=pyOpenSSL
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python interface to the OpenSSL library"
+HOMEPAGE="
+	http://pyopenssl.sourceforge.net/
+	https://launchpad.net/pyopenssl
+	https://pypi.org/project/pyOpenSSL/
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.2.1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		virtual/python-cffi[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.0.1[${PYTHON_USEDEP}]
+	)"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+	# Requires network access
+	sed -i -e 's/test_set_default_verify_paths/_&/' tests/test_ssl.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	TZ=UTC py.test -v || die "Testing failed with ${EPYTHON}" # Fixes bug #627530
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	if use examples ; then
+		docinto examples
+		dodoc -r examples/*
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}