[gentoo-commits] gentoo-x86 commit in net-p2p/transmission: transmission-1.77.ebuild ChangeLog

[Remi Cardona (remi)]

remi        10/02/04 08:03:13

  Modified:             ChangeLog
  Added:                transmission-1.77.ebuild
  Log:
  net-p2p/transmission: bump to 1.77
  (Portage version: 2.2_rc62/cvs/Linux i686)

Revision  Changes    Path
1.103                net-p2p/transmission/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.103&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.103&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/ChangeLog?r1=1.102&r2=1.103

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v
retrieving revision 1.102
retrieving revision 1.103
diff -u -r1.102 -r1.103
--- ChangeLog	29 Dec 2009 18:03:00 -0000	1.102
+++ ChangeLog	4 Feb 2010 08:03:12 -0000	1.103
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/transmission
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.102 2009/12/29 18:03:00 armin76 Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.103 2010/02/04 08:03:12 remi Exp $
+
+*transmission-1.77 (04 Feb 2010)
+
+  04 Feb 2010; Rémi Cardona <remi@g.o> +transmission-1.77.ebuild:
+  bump to 1.77
 
   29 Dec 2009; Raúl Porcel <armin76@g.o> transmission-1.72.ebuild,
   transmission-1.75.ebuild, transmission-1.76.ebuild:



1.1                  net-p2p/transmission/transmission-1.77.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/transmission-1.77.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/transmission-1.77.ebuild?rev=1.1&content-type=text/plain

Index: transmission-1.77.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-1.77.ebuild,v 1.1 2010/02/04 08:03:12 remi Exp $

EAPI=2
inherit autotools eutils fdo-mime gnome2-utils qt4

DESCRIPTION="A Fast, Easy and Free BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com"
SRC_URI="http://download.${PN}bt.com/${PN}/files/${P}.tar.bz2"

LICENSE="MIT GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
IUSE="+dht gtk libnotify qt4"

RDEPEND=">=dev-libs/libevent-1.4.11
	<dev-libs/libevent-2
	>=dev-libs/openssl-0.9.4
	|| ( >=net-misc/curl-7.16.3[openssl]
		>=net-misc/curl-7.16.3[ssl]
		>=net-misc/curl-7.16.3[gnutls] )
	gtk? ( >=dev-libs/glib-2.15.5:2
		>=x11-libs/gtk+-2.12:2
		>=dev-libs/dbus-glib-0.70
		libnotify? ( >=x11-libs/libnotify-0.4.3 ) )
	qt4? ( x11-libs/qt-gui:4 )"
DEPEND="${RDEPEND}
	>=sys-devel/libtool-2.2
	sys-devel/gettext
	>=dev-util/intltool-0.40
	dev-util/pkgconfig
	sys-apps/sed"

src_prepare() {
	sed -e 's:-g -O0::g' -e 's:-g -O3::g' -i configure.ac || die "sed failed"
	sed -e \
		's:$${TRANSMISSION_TOP}/third-party/libevent/.libs/libevent.a:-levent:' \
		-i qt/qtr.pro || die "sed failed"
	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_enable dht) \
		$(use_enable gtk) \
		$(use_enable libnotify)

	if use qt4; then
		cd qt
		eqmake4 qtr.pro
	fi
}

src_compile() {
	emake || die "emake failed"

	if use qt4; then
		cd qt
		emake || die "emake failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS NEWS
	rm -f "${D}"/usr/share/${PN}/web/LICENSE

	newinitd "${FILESDIR}"/${PN}-daemon.initd.2 ${PN}-daemon
	newconfd "${FILESDIR}"/${PN}-daemon.confd.1 ${PN}-daemon

	if use qt4; then
		cd qt
		emake INSTALL_ROOT="${D}/usr" install || die "emake install failed"
		make_desktop_entry qtr "Transmission Qt BitTorrent Client" ${PN} \
			"Network;FileTransfer;P2P;Qt"
		use gtk || doicon qt/icons/transmission.png
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}