[gentoo-commits] gentoo-x86 commit in games-strategy/warzone2100: ChangeLog warzone2100-2.3.2.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    10/07/28 19:10:15

  Modified:             ChangeLog
  Added:                warzone2100-2.3.2.ebuild
  Log:
  version bump
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.46                 games-strategy/warzone2100/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/warzone2100/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/warzone2100/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/warzone2100/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/warzone2100/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	23 Jul 2010 11:32:02 -0000	1.45
+++ ChangeLog	28 Jul 2010 19:10:14 -0000	1.46
@@ -1,6 +1,12 @@
 # ChangeLog for games-strategy/warzone2100
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/warzone2100/ChangeLog,v 1.45 2010/07/23 11:32:02 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/warzone2100/ChangeLog,v 1.46 2010/07/28 19:10:14 mr_bones_ Exp $
+
+*warzone2100-2.3.2 (28 Jul 2010)
+
+  28 Jul 2010; Michael Sterrett <mr_bones_@g.o>
+  +warzone2100-2.3.2.ebuild:
+  version bump
 
   23 Jul 2010; Peter Volkov <pva@g.o> warzone2100-2.3.1.ebuild:
   amd64 stable, bug 328277



1.1                  games-strategy/warzone2100/warzone2100-2.3.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/warzone2100/warzone2100-2.3.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/warzone2100/warzone2100-2.3.2.ebuild?rev=1.1&content-type=text/plain

Index: warzone2100-2.3.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/warzone2100/warzone2100-2.3.2.ebuild,v 1.1 2010/07/28 19:10:14 mr_bones_ Exp $

EAPI=2
inherit versionator games

MY_PV=$(get_version_component_range -2)
VIDEOS_P=${P}-videos.wz
DESCRIPTION="3D real-time strategy game"
HOMEPAGE="http://wz2100.net/"
SRC_URI="mirror://sourceforge/warzone2100/${P}.tar.gz
	videos? ( mirror://sourceforge/warzone2100/warzone2100/Videos/2.2/high-quality-en/sequences.wz -> ${VIDEOS_P} )"

LICENSE="GPL-2 CCPL-Attribution-ShareAlike-3.0 public-domain"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
# upstream requested debug support
IUSE="debug nls videos"

RDEPEND="dev-db/sqlite:3
	>=dev-games/physfs-2[zip]
	dev-libs/popt
	media-libs/libogg
	media-libs/libpng
	media-libs/libsdl[opengl,video]
	media-libs/libtheora
	media-libs/libvorbis
	media-libs/openal
	media-libs/sdl-net
	media-libs/quesoglc
	virtual/glu
	virtual/opengl
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	app-arch/zip
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"
RDEPEND="${RDEPEND}
	media-fonts/dejavu"

src_configure() {
	egamesconf \
		--disable-dependency-tracking \
		--docdir=/usr/share/doc/${PF} \
		--localedir=/usr/share/locale \
		--with-distributor="Gentoo ${PF}" \
		--with-icondir=/usr/share/pixmaps \
		--with-applicationdir=/usr/share/applications \
		$(use_enable debug debug relaxed) \
		$(use_enable nls)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	rm -f "${D}"/usr/share/doc/${PF}/COPYING*
	if use videos ; then
		insinto "${GAMES_DATADIR}"/${PN}
		newins "${DISTDIR}"/${VIDEOS_P} sequences.wz \
			|| die "newins failed"
	fi
	prepgamesdirs
}