[gentoo-commits] gentoo-x86 commit in games-fps/warsow: metadata.xml ChangeLog warsow-0.5.ebuild

[Tristan Heaven (nyhm)]

nyhm        09/09/02 19:29:22

  Modified:             metadata.xml ChangeLog
  Added:                warsow-0.5.ebuild
  Log:
  Version bump, bug #283168
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  games-fps/warsow/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/warsow/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/warsow/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/warsow/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-fps/warsow/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	26 Jul 2008 03:57:13 -0000	1.2
+++ metadata.xml	2 Sep 2009 19:29:22 -0000	1.3
@@ -3,6 +3,7 @@
 <pkgmetadata>
   <herd>games</herd>
   <use>
+    <flag name="angelscript">Enable AngelScript support</flag>
     <flag name="irc">Enable IRC support</flag>
   </use>
 </pkgmetadata>



1.23                 games-fps/warsow/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/warsow/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/warsow/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/warsow/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-fps/warsow/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	26 May 2009 07:16:00 -0000	1.22
+++ ChangeLog	2 Sep 2009 19:29:22 -0000	1.23
@@ -1,6 +1,12 @@
 # ChangeLog for games-fps/warsow
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/warsow/ChangeLog,v 1.22 2009/05/26 07:16:00 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/warsow/ChangeLog,v 1.23 2009/09/02 19:29:22 nyhm Exp $
+
+*warsow-0.5 (02 Sep 2009)
+
+  02 Sep 2009; Tristan Heaven <nyhm@g.o> +warsow-0.5.ebuild,
+  +files/warsow-0.5-build.patch, +files/warsow-0.5-openal.patch:
+  Version bump, bug #283168
 
   26 May 2009; Michael Sterrett <mr_bones_@g.o> warsow-0.4.2.ebuild:
   curl is also needed for USE=dedicated (bug #270048)



1.1                  games-fps/warsow/warsow-0.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/warsow/warsow-0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/warsow/warsow-0.5.ebuild?rev=1.1&content-type=text/plain

Index: warsow-0.5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/warsow/warsow-0.5.ebuild,v 1.1 2009/09/02 19:29:22 nyhm Exp $

EAPI=2
inherit eutils toolchain-funcs versionator games

MY_P=${PN}_${PV}
DESCRIPTION="Multiplayer FPS based on the QFusion engine (evolved from Quake 2)"
HOMEPAGE="http://www.warsow.net/"
SRC_URI="http://static.warsow.net/release/${MY_P}_unified.zip
	http://static.warsow.net/release/${MY_P}_sdk.zip
	mirror://gentoo/${PN}.png"

LICENSE="GPL-2 warsow"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+angelscript debug dedicated irc openal opengl"

UIRDEPEND="media-libs/jpeg
	media-libs/libvorbis
	media-libs/libsdl
	virtual/opengl
	x11-libs/libXinerama
	x11-libs/libXxf86dga
	x11-libs/libXxf86vm
	openal? ( media-libs/openal )"
RDEPEND="net-misc/curl
	opengl? ( ${UIRDEPEND} )
	!opengl? ( !dedicated? ( ${UIRDEPEND} ) )"
UIDEPEND="x11-proto/xineramaproto
	x11-proto/xf86dgaproto
	x11-proto/xf86vidmodeproto
	openal? ( dev-util/pkgconfig )"
DEPEND="${RDEPEND}
	app-arch/unzip
	x11-misc/makedepend
	opengl? ( ${UIDEPEND} )
	!opengl? ( !dedicated? ( ${UIDEPEND} ) )"

S=${WORKDIR}/source

src_prepare() {
	sed -i \
		-e "/fs_basepath =/ s:\.:${GAMES_DATADIR}/${PN}:" \
		qcommon/files.c \
		|| die "sed files.c failed"

	cd "${WORKDIR}"
	epatch \
		"${FILESDIR}"/${P}-build.patch \
		"${FILESDIR}"/${P}-openal.patch
}

src_compile() {
	yesno() { use ${1} && echo YES || echo NO ; }

	local client="NO" irc="NO" openal="NO"
	if use opengl || ! use dedicated ; then
		client="YES"
		use irc && irc="YES"
		use openal && openal="YES"
	fi

	tc-export CC AR RANLIB

	if use angelscript ; then
		emake \
			-C ../libsrcs/angelscript/angelSVN/sdk/angelscript/projects/gnuc \
			|| die "emake angelscript failed"
	fi

	emake \
		BINDIR=bin \
		BUILD_CLIENT=${client} \
		BUILD_SERVER=$(yesno dedicated) \
		BUILD_TV_SERVER=$(yesno dedicated) \
		BUILD_ANGELWRAP=$(yesno angelscript) \
		BUILD_IRC=${irc} \
		BUILD_SND_OPENAL=${openal} \
		BUILD_SND_QF=${client} \
		DEBUG_BUILD=$(yesno debug) \
		|| die "emake failed"
}

src_install() {
	cd bin

	if use opengl || ! use dedicated ; then
		newgamesbin ${PN}.* ${PN} || die "newgamesbin ${PN} failed"
		doicon "${DISTDIR}"/${PN}.png
		make_desktop_entry ${PN} Warsow
	fi

	if use dedicated ; then
		newgamesbin wsw_server.* ${PN}-ded || die "newgamesbin ${PN}-ded failed"
		newgamesbin wswtv_server.* ${PN}-tv || die "newgamesbin ${PN}-tv failed"
	fi

	exeinto "$(games_get_libdir)"/${PN}
	doexe */*.so || die "doexe failed"

	insinto "${GAMES_DATADIR}"/${PN}
	doins -r "${WORKDIR}"/basewsw || die "doins failed"

	local so
	for so in basewsw/*.so ; do
		dosym "$(games_get_libdir)"/${PN}/${so##*/} \
			"${GAMES_DATADIR}"/${PN}/${so} || die "dosym ${so} failed"
	done

	if [[ -e libs ]] ; then
		dodir "${GAMES_DATADIR}"/${PN}/libs
		for so in libs/*.so ; do
			dosym "$(games_get_libdir)"/${PN}/${so##*/} \
				"${GAMES_DATADIR}"/${PN}/${so} || die "dosym ${so} failed"
		done
	fi

	dodoc "${WORKDIR}"/docs/*
	prepgamesdirs
}