[gentoo-commits] gentoo-x86 commit in media-sound/csound: csound-5.16.6.ebuild ChangeLog metadata.xml Manifest

[Tim Harder (radhermit)]

radhermit    12/02/27 05:37:48

  Added:                csound-5.16.6.ebuild ChangeLog metadata.xml
                        Manifest
  Log:
  Initial import. Ebuild by me.
  
  (Portage version: 2.2.0_alpha87/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  media-sound/csound/csound-5.16.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/csound-5.16.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/csound-5.16.6.ebuild?rev=1.1&content-type=text/plain

Index: csound-5.16.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/csound/csound-5.16.6.ebuild,v 1.1 2012/02/27 05:37:48 radhermit Exp $

EAPI="4"
PYTHON_DEPEND="python? 2"

inherit eutils multilib python java-pkg-opt-2 scons-utils toolchain-funcs versionator

MY_PN="${PN/c/C}"
MY_P="${MY_PN}${PV}"
DOCS_P="${MY_PN}$(get_version_component_range 1-2)"

DESCRIPTION="A sound design and signal processing system providing facilities for composition and performance"
HOMEPAGE="http://csounds.com/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz
	html? (
		linguas_fr? ( mirror://sourceforge/${PN}/${DOCS_P}_manual-fr_html.zip )
		!linguas_fr? ( mirror://sourceforge/${PN}/${DOCS_P}_manual_html.zip )
	)
	doc? (
		linguas_fr? ( mirror://sourceforge/${PN}/${DOCS_P}_manual-fr_pdf.zip )
		!linguas_fr? ( mirror://sourceforge/${PN}/${DOCS_P}_manual_pdf.zip )
	)"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
LANGS=" de en_GB en_US es_CO fr it ro ru"
IUSE="+alsa beats chua csoundac +cxx debug double-precision dssi examples fltk +fluidsynth
html +image jack java keyboard linear lua nls osc openmp doc portaudio portmidi pulseaudio
python samples static-libs stk tcl test +threads +utils vim-syntax vst ${LANGS// / linguas_}"

RDEPEND=">=media-libs/libsndfile-1.0.16
	alsa? ( media-libs/alsa-lib )
	csoundac? ( x11-libs/fltk:1[threads?]
		dev-libs/boost
		=dev-lang/python-2* )
	dssi? ( media-libs/dssi
		media-libs/ladspa-sdk )
	fluidsynth? ( media-sound/fluidsynth )
	fltk? ( x11-libs/fltk:1[threads?] )
	image? ( media-libs/libpng )
	jack? ( media-sound/jack-audio-connection-kit )
	java? ( >=virtual/jdk-1.5 )
	keyboard? ( x11-libs/fltk:1[threads?] )
	linear? ( sci-mathematics/gmm )
	lua? ( dev-lang/luajit:2 )
	osc? ( media-libs/liblo )
	portaudio? ( media-libs/portaudio )
	portmidi? ( media-libs/portmidi )
	pulseaudio? ( media-sound/pulseaudio )
	stk? ( media-libs/stk )
	tcl? ( >=dev-lang/tcl-8.5
		>=dev-lang/tk-8.5 )
	utils? ( !media-sound/snd )
	vst? ( x11-libs/fltk:1[threads?]
		dev-libs/boost
		=dev-lang/python-2* )"
DEPEND="${RDEPEND}
	sys-devel/flex
	virtual/yacc
	chua? ( dev-libs/boost )
	csoundac? ( dev-lang/swig )
	html? ( app-arch/unzip )
	doc? ( app-arch/unzip )
	nls? ( sys-devel/gettext )
	test? ( =dev-lang/python-2* )
	vst? ( dev-lang/swig )"

REQUIRED_USE="vst? ( csoundac )
	java? ( cxx )
	linear? ( double-precision )
	lua? ( cxx )
	python? ( cxx )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if use openmp ; then
		tc-has-openmp || die "Please switch to an openmp compatible compiler"
	fi

	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-scons.patch
	epatch "${FILESDIR}"/${P}-tests.patch
	epatch "${FILESDIR}"/${P}-install.patch

	cat > custom.py <<-EOF
		platform = 'linux'
		customCPPPATH = []
		customCCFLAGS = "${CFLAGS}".split()
		customCXXFLAGS = "${CXXFLAGS}".split()
		customLIBS = []
		customLIBPATH = []
		customSHLINKFLAGS = []
		customSWIGFLAGS = []
	EOF
}

src_compile() {
	local myconf
	[[ $(get_libdir) == "lib64" ]] && myconf+=" Lib64=1"

	escons \
		prefix=/usr \
		CC="$(tc-getCC)" \
		CXX="$(tc-getCXX)" \
		LINKFLAGS="${LDFLAGS}" \
		buildNewParser=1 \
		pythonVersion=$(python_get_version) \
		$(use_scons alsa useALSA) \
		$(use_scons beats buildBeats) \
		$(use_scons chua buildChuaOpcodes) \
		$(use_scons csoundac buildCsoundAC) \
		$(use_scons cxx buildInterfaces) \
		$(use_scons !debug buildRelease) \
		$(use_scons !debug noDebug) \
		$(use_scons debug NewParserDebug) \
		$(use_scons double-precision useDouble) \
		$(use_scons dssi buildDSSI) \
		$(use_scons fluidsynth buildFluidOpcodes) \
		$(use_scons fltk buildCsound5GUI) \
		$(use_scons fltk useFLTK) \
		$(use_scons image buildImageOpcodes) \
		$(use_scons jack useJack) \
		$(use_scons java buildJavaWrapper) \
		$(use_scons keyboard buildVirtual) \
		$(use_scons linear buildLinearOpcodes) \
		$(use_scons lua buildLuaOpcodes) \
		$(use_scons lua buildLuaWrapper) \
		$(use_scons nls useGettext) \
		$(use_scons osc useOSC) \
		$(use_scons openmp useOpenMP) \
		$(use_scons portaudio usePortAudio) \
		$(use_scons portmidi usePortMIDI) \
		$(use_scons pulseaudio usePulseAudio) \
		$(use_scons python buildPythonOpcodes) \
		$(use_scons python buildPythonWrapper) \
		$(use_scons !static-libs dynamicCsoundLibrary) \
		$(use_scons stk buildStkOpcodes) \
		$(use_scons tcl buildTclcsound) \
		$(use_scons !threads noFLTKThreads) \
		$(use_scons threads buildMultiCore) \
		$(use_scons utils buildUtilities) \
		$(use_scons vst buildCsoundVST) \
		${myconf}
}

src_test() {
	export LD_LIBRARY_PATH="${S}" OPCODEDIR="${S}" OPCODEDIR64="${S}"
	cd tests
	./test.py || die "tests failed"
}

src_install() {
	local myconf
	[[ $(get_libdir) == "lib64" ]] && myconf+=" --word64"

	use vim-syntax && myconf+=" --vimdir=/usr/share/vim/vimfiles"

	./install.py --instdir="${D}" --prefix=/usr ${myconf} || die "install failed"
	dodoc AUTHORS ChangeLog readme-csound5-complete.txt

	# Generate env.d file
	if use double-precision ; then
		echo OPCODEDIR64=/usr/$(get_libdir)/${PN}/plugins64 > "${T}"/62${PN}
	else
		echo OPCODEDIR=/usr/$(get_libdir)/${PN}/plugins > "${T}"/62${PN}
	fi
	echo "CSSTRNGS=/usr/share/locale" >> "${T}"/62${PN}
	use stk && echo "RAWWAVE_PATH=/usr/share/csound/rawwaves" >> "${T}"/62${PN}
	doenvd "${T}"/62${PN}

	insinto /usr/share/locale
	for lang in ${LANGS} ; do
		use linguas_${lang} && doins -r po/${lang}
	done

	if use examples ; then
		dodoc -r examples
		docompress -x /usr/share/doc/${PF}/examples
	fi

	if use html ; then
		dohtml -r "${WORKDIR}"/html/*
	fi

	if use doc ; then
		if use linguas_fr ; then
			dodoc "${WORKDIR}"/${DOCS_P}_manual-fr.pdf
		else
			dodoc "${WORKDIR}"/${DOCS_P}_manual.pdf
		fi
	fi

	use samples && dodoc -r samples
}



1.1                  media-sound/csound/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-sound/csound
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/csound/ChangeLog,v 1.1 2012/02/27 05:37:48 radhermit Exp $

*csound-5.16.6 (27 Feb 2012)

  27 Feb 2012; Tim Harder <radhermit@g.o> +csound-5.16.6.ebuild,
  +files/csound-5.16.6-install.patch, +files/csound-5.16.6-scons.patch,
  +files/csound-5.16.6-tests.patch, +metadata.xml:
  Initial import. Ebuild by me.




1.1                  media-sound/csound/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>proaudio</herd>
  <use>
    <flag name="beats">Build the beats score frontend</flag>
    <flag name="chua">Build the chua opcodes</flag>
	<flag name="csoundac">Build the CsoundAC extension module</flag>
	<flag name="double-precision">Use double-precision floating point for audio samples</flag>
	<flag name="dssi">Build the DSSI opcodes</flag>
	<flag name="fluidsynth">Build the fluidsynth opcodes</flag>
	<flag name="html">Install the html version of the manual</flag>
	<flag name="image">Build the image opcodes</flag>
	<flag name="keyboard">Build Virtual MIDI keyboard</flag>
	<flag name="linear">Build the linear algebra Opcodes</flag>
	<flag name="doc">Install the pdf version of the manual</flag>
	<flag name="portmidi">Build the PortMIDI I/O module</flag>
	<flag name="samples">Install the HRTF datafiles for use with hrtfmove, hrtfmove2, hrtfstat, hrtfearly, and hrtfreverb</flag>
	<flag name="stk">Build the stk opcodes</flag>
	<flag name="tcl">Build the tcl interface and clients</flag>
	<flag name="utils">Build stand-alone executables for utilities that can also be used via `csound -U`</flag>
	<flag name="vst">Build the CsoundVST frontend</flag>
  </use>
</pkgmetadata>



1.1                  media-sound/csound/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
AUX csound-5.16.6-install.patch 7054 RMD160 7ff541583f2d3d3afdca88e380fe3a5b1f97d137 SHA1 692d48704e66c5db7cc8eb020927d21a706bbcd0 SHA256 8972ccea60614ee85c5eb3f0eba73c1f5441ff6ebcab1805659b3ebe8ee81879
AUX csound-5.16.6-scons.patch 8289 RMD160 ef1c41d8b418bdf7beb5c6717474781637859f5b SHA1 c43f252566922a7c531f52d5096d9fabe517040b SHA256 dc539056f99103578dcfb59666d883f177c8a8c57a9b34abb924905624768b1a
AUX csound-5.16.6-tests.patch 2356 RMD160 6b3d93e4e062d009b7776ece4cf9c39a7da7ac0c SHA1 11e2132a702565c7386c4b54b2e42d63820fd568 SHA256 0b242d94b1718671d325b20cbd3faf4bc2437738fd88d49586a73fc84e5e9dca
DIST Csound5.16.6.tar.gz 8735038 RMD160 49f3f7af3cfca6e129750564822698f4d2433329 SHA1 28bbf5d34ee5bb11dc1d50fb122b5a706d317c33 SHA256 0ba912850152aeddb7eb757a33c185e3d50b4807548db6d7ba6cf85de15e7ffb
DIST Csound5.16_manual-fr_html.zip 9711044 RMD160 951a5e6872c888b49917e172f1b5a2a034656b5b SHA1 4eeb02ac504cb159aab9201b88ca204d78634909 SHA256 eeaa0bbd050b2dc44f65d64410e4affb456690635c37c67355819ec9709b9ca0
DIST Csound5.16_manual-fr_pdf.zip 5969838 RMD160 8710496e4909ac80df2a2fb48c124d811f3cffe7 SHA1 68a7dc63bf08b04aee8635d0cf13c44214fe743d SHA256 a30f30554529d891018534dc1de06cb7c7499d80f1b618f9977cf457194e8091
DIST Csound5.16_manual_html.zip 9451986 RMD160 262888c476044827f872764ba3a5ffab3717d42f SHA1 4dbe80c06a6573066269ce1ee0ac466a03414a65 SHA256 572b1b3825fd5203d00e3db6db7a190a17212b28de425cc0373e705d44aa2c8b
DIST Csound5.16_manual_pdf.zip 5661273 RMD160 a63c6806366e0b7bb702096d10d956194d2c9378 SHA1 91ee66b4c4aa93757165a391a19e8039ef9a6982 SHA256 66550eb53a77b942ad073be63c12dca66b6960d5995a6a241dde255d2d0be85b
EBUILD csound-5.16.6.ebuild 5724 RMD160 210efc032ca0fb2a05cf409cd90c34a54726e038 SHA1 2f56111dc739a88706c3f205d7c56903c19614d6 SHA256 3f55e94f4f2d8614387a0f8fa40fa79fcda574540fa7ea9de1316f75d756a877
MISC ChangeLog 377 RMD160 9251ff5c88e1011c8b261925e454d553920bf1b4 SHA1 9f21699866776574faa05896580758b32400e01b SHA256 085d2e0a5328af15a8db51968fc8063631a7bb25bce7e6f3894846b350791c6a
MISC metadata.xml 1316 RMD160 0e7e9557f2d89f0cdfdc8607c03b8705d55f85ab SHA1 c38e613165aa62aed53e166c8d06c1ec40a45741 SHA256 7863a87fba3453a2c062eb07babc0626d77d6c27540c6b4bec3f95b73cf3f2eb