[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgdata/

[Gilles Dartiguelongue]

commit:     5057a5c782d119c73dce3791081fb814fbd8b3f3
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 27 17:01:54 2017 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Aug 27 17:56:56 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5057a5c7

dev-libs/libgdata: version bump 0.17.8-r1 → 0.17.9

Drop GSETTINGS_BACKEND which is handled by eclass. Switch dbus wrapping
to dbus-run-session to avoid implicit dependency on X11 server.

Package-Manager: Portage-2.3.8, Repoman-2.3.3

 dev-libs/libgdata/Manifest               |  1 +
 dev-libs/libgdata/libgdata-0.17.9.ebuild | 66 ++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/dev-libs/libgdata/Manifest b/dev-libs/libgdata/Manifest
index 98cc2607b4e..084c60707e9 100644
--- a/dev-libs/libgdata/Manifest
+++ b/dev-libs/libgdata/Manifest
@@ -1 +1,2 @@
 DIST libgdata-0.17.8.tar.xz 1464812 SHA256 e5e735bfac219c6cbe4a14df481cb3cb4b1c4b8b5e70f9a105a884035bc3a161 SHA512 dfc4c825a7053a6fd7659d04c7077bed8539b4cf3ef3da1d5ece4da3ce17941900e960a300a50b284010ed890dcab87e4c4726403f04481c672832fd34b975b0 WHIRLPOOL e0772008cdf0816efe118f69f9bcc86d85de2a26fc2fd5127bcdb942af264536764da130ccb194a01f0bb97ad9bb070eec84c659e9e82b64a4f7eeb6b0602797
+DIST libgdata-0.17.9.tar.xz 1434700 SHA256 85c4f7674c0098ffaf060ae01b6b832cb277b3673d54ace3bdedaad6b127453a SHA512 90289309cbdc4ec6932bf385ddbfcc75c0c2f8b9ca356329298aaa37f6c3db7a16de20e5c947c16c595e43e729a664e4d6d3e2c5a60bb1e463a13d1306f374ce WHIRLPOOL c51322d21ba89d4a96c0a52307d760ff0f399bd5cfd62ee6cf02bc0a81aab1a576471e419aff14ebf9a2b6c330e48c3668133930c46f5614799803436798ad56

diff --git a/dev-libs/libgdata/libgdata-0.17.9.ebuild b/dev-libs/libgdata/libgdata-0.17.9.ebuild
new file mode 100644
index 00000000000..03f11210125
--- /dev/null
+++ b/dev-libs/libgdata/libgdata-0.17.9.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+GNOME2_EAUTORECONF="yes"
+
+inherit gnome2 vala
+
+DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/22" # subslot = libgdata soname version
+
+IUSE="+crypt gnome-online-accounts +introspection static-libs test vala"
+REQUIRED_USE="
+	gnome-online-accounts? ( crypt )
+	vala? ( introspection )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/json-glib-0.15
+	>=dev-libs/libxml2-2:2
+	>=net-libs/liboauth-0.9.4
+	>=net-libs/libsoup-2.55.90:2.4[introspection?]
+	>=x11-libs/gdk-pixbuf-2.14:2
+	crypt? ( app-crypt/gcr:= )
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.25
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	test? ( >=net-libs/uhttpmock-0.5 )
+	vala? ( $(vala_depend) )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.17.8-disable-demos.patch
+)
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-build-demos \
+		$(use_enable crypt gnome) \
+		$(use_enable gnome-online-accounts goa) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(use_enable static-libs static) \
+		$(use_enable test always-build-tests)
+}
+
+src_test() {
+	unset ORBIT_SOCKETDIR
+	dbus-run-session emake check
+}