[gentoo-commits] repo/gentoo:master commit in: dev-util/eric/

[Davide Pesavento]

commit:     75e7253dbd2c24d4b5ec3e2482ba05de49821e21
Author:     Davide Pesavento <pesa <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  4 05:09:02 2017 +0000
Commit:     Davide Pesavento <pesa <AT> gentoo <DOT> org>
CommitDate: Wed Jan  4 05:09:45 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=75e7253d

dev-util/eric: version bump

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 dev-util/eric/Manifest          |  1 +
 dev-util/eric/eric-17.01.ebuild | 68 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-util/eric/Manifest b/dev-util/eric/Manifest
index 30fc9df..acb675d 100644
--- a/dev-util/eric/Manifest
+++ b/dev-util/eric/Manifest
@@ -1 +1,2 @@
 DIST eric6-16.12.tar.gz 18764980 SHA256 cfb70ef9c68fe88ea0752bc0141efc04c7fce118fd9166ec5ef57dfe23a492c6 SHA512 53506c52e289db141abf8faf1a90a7b1a2d32ab6932d6254aa8cb3e69ed8b78932d648c8625335cfae187053c3f7d3adf84f60867591ab804215b645a1719340 WHIRLPOOL 085a0048805d33b8a0426e743eb112643a6aa54668185eeeedb0ecadf68ae7f41aae98e0f853a0183e62b4c82ffcad7aca94d97087d00d10b57c0cdb5f3d5eb2
+DIST eric6-17.01.tar.gz 18810473 SHA256 ef6c105248ceb895780022e68bef9136b0659fc9cf2e7b9f78bd272364ab67f8 SHA512 db0490f67e080f31b555f7fa57180a341f50b18753dca6aea9d56ab51a24006a33a6652fcbe5552138b21f3370a54cac16182a891d5ae301f2d34f618fe0d952 WHIRLPOOL b580c610998bc16cbc663620bf98778656a7c17ef4f4776e24ecb63f2be3fa27fc8321f35778e3f0be71cf23370e4d0eafd1e1b55b20af8b9ef6f8802c4652a6

diff --git a/dev-util/eric/eric-17.01.ebuild b/dev-util/eric/eric-17.01.ebuild
new file mode 100644
index 00000000..eb2727e
--- /dev/null
+++ b/dev-util/eric/eric-17.01.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_REQ_USE="sqlite,xml"
+
+inherit python-single-r1
+
+DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
+HOMEPAGE="http://eric-ide.python-projects.org/"
+LICENSE="GPL-3"
+SLOT="6"
+
+MY_P=${PN}${SLOT}-${PV}
+SRC_URI="mirror://sourceforge/eric-ide/${PN}${SLOT}/stable/${PV}/${MY_P}.tar.gz"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/sip-4.14.3[${PYTHON_USEDEP}]
+	>=dev-python/PyQt4-4.10[${PYTHON_USEDEP},X,help,sql,svg,webkit]
+	>=dev-python/qscintilla-python-2.8[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	>=dev-python/chardet-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/coverage-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.1.3[${PYTHON_USEDEP}]
+	!dev-util/eric:4
+	!dev-util/eric:5
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=(changelog README.rst THANKS)
+
+src_prepare() {
+	default
+
+	# Delete internal copies of dev-python/chardet and dev-python/pygments
+	rm -fr eric/ThirdParty/{CharDet,Pygments} || die
+
+	# Delete internal copy of dev-python/coverage
+	rm -fr eric/DebugClients/Python{,3}/coverage || die
+	sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
+		$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
+
+	# Fix desktop files (bug 458092)
+	sed -i -re '/^Categories=/s:(Python|QtWeb):X-&:g' eric/eric6{,_{,web}browser}.desktop || die
+}
+
+src_install() {
+	"${PYTHON}" install.py \
+		-b "${EPREFIX}/usr/bin" \
+		-d "$(python_get_sitedir)" \
+		-i "${D}" \
+		-c \
+		-z \
+		--pyqt=4 \
+		|| die
+
+	python_optimize
+	einstalldocs
+}