[gentoo-commits] repo/gentoo:master commit in: dev-games/tiled/

[Michael Palimaka]

commit:     c251c0ca9e0a4e8609868d9d225d3c3a274504fd
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Tue Jun  2 11:53:51 2020 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Tue Jun  2 11:54:47 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c251c0ca

dev-games/tiled: version bump 1.3.5

Closes: https://bugs.gentoo.org/726152
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Michael Palimaka <kensington <AT> gentoo.org>

 dev-games/tiled/Manifest           |  1 +
 dev-games/tiled/tiled-1.3.5.ebuild | 63 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index b87761317e6..fd005e8abe5 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-1.3.4.tar.gz 15860089 BLAKE2B cdc06f82a5bd92179ff4c6402da7094dfa33d1281f358cd82a5125fe9672b5f317f578f3332c1b07c4603bb8930dd50c736f0a41a156594fbd419d94147c0525 SHA512 f78772f74d9f7a241ff9191ed6152f965b7a5342db877fa63a2d84f266d956cb2fa487776cf503db36bc5da9aa825c8bab87e13293e43a129f560020e323bd61
+DIST tiled-1.3.5.tar.gz 15899657 BLAKE2B 3540fb9f4c6994d7b3df382aded53f16a2861f9864836ce295b0d6ab7cc8971b28272d52ff039c8281b7e453e4fbd98651d5b7cf6a2a8fc04f7ea4ab908f2496 SHA512 a8c5faba7eaf14c1062acf693cc0fd43b64003d886f876ac179d21b9aa18bbc1859a2b13dfabe4c0363ebe21a4d64bdd0adb697427ef68c82072cf8e706d7de8

diff --git a/dev-games/tiled/tiled-1.3.5.ebuild b/dev-games/tiled/tiled-1.3.5.ebuild
new file mode 100644
index 00000000000..b0e8f2726bb
--- /dev/null
+++ b/dev-games/tiled/tiled-1.3.5.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+inherit gnome2-utils multilib python-single-r1 qmake-utils xdg-utils
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="https://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-qt/qtcore-5.10:5
+	>=dev-qt/qtdeclarative-5.10:5
+	>=dev-qt/qtgui-5.10:5
+	>=dev-qt/qtnetwork-5.10:5
+	>=dev-qt/qtwidgets-5.10:5
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/linguist-tools:5"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	eqmake5 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+
+	if use examples ; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}