[gentoo-commits] gentoo-x86 commit in app-editors/jedit: ChangeLog jedit-4.3.1.ebuild jedit-4.3_pre18.ebuild

[Vlastimil Babka (caster)]

caster      10/01/31 00:57:31

  Modified:             ChangeLog
  Added:                jedit-4.3.1.ebuild
  Removed:              jedit-4.3_pre18.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.90                 app-editors/jedit/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/ChangeLog?rev=1.90&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/ChangeLog?rev=1.90&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/ChangeLog?r1=1.89&r2=1.90

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/jedit/ChangeLog,v
retrieving revision 1.89
retrieving revision 1.90
diff -u -r1.89 -r1.90
--- ChangeLog	25 Dec 2009 01:34:48 -0000	1.89
+++ ChangeLog	31 Jan 2010 00:57:31 -0000	1.90
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/jedit
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/jedit/ChangeLog,v 1.89 2009/12/25 01:34:48 caster Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/jedit/ChangeLog,v 1.90 2010/01/31 00:57:31 caster Exp $
+
+*jedit-4.3.1 (31 Jan 2010)
+
+  31 Jan 2010; Vlastimil Babka <caster@g.o> -jedit-4.3_pre18.ebuild,
+  +jedit-4.3.1.ebuild:
+  Version bump.
 
 *jedit-4.3 (25 Dec 2009)
 



1.1                  app-editors/jedit/jedit-4.3.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/jedit-4.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/jedit-4.3.1.ebuild?rev=1.1&content-type=text/plain

Index: jedit-4.3.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/jedit/jedit-4.3.1.ebuild,v 1.1 2010/01/31 00:57:31 caster Exp $

WANT_ANT_TASKS="ant-nodeps"

inherit java-pkg-2 java-ant-2 eutils fdo-mime

# TODO use versionator
MY_PV="${PV//_/}"

DESCRIPTION="Programmer's editor written in Java"
HOMEPAGE="http://www.jedit.org"
SRC_URI="mirror://sourceforge/${PN}/${PN}${MY_PV}source.tar.bz2"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
SLOT="0"
IUSE="doc"

RDEPEND=">=virtual/jre-1.5"
DEPEND=">=virtual/jdk-1.5
	doc? (
		=app-text/docbook-xml-dtd-4.3*
		>=app-text/docbook-xsl-stylesheets-1.65.1
		dev-libs/libxslt
	)"

S="${WORKDIR}/jEdit"

JEDIT_HOME="/usr/share/${PN}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	if use doc; then
		local xsl=$(echo /usr/share/sgml/docbook/xsl-stylesheets-*)
		xsl=${xsl// *}

		local xml=$(echo /usr/share/sgml/docbook/xml-dtd-4.3*)
		xml=${xml// *}

		echo "build.directory=." > build.properties
		echo "docbook.dtd.catalog=${xml}/docbook.cat" >> build.properties
		echo "docbook.xsl=${xsl}" >> build.properties
	fi

	# still need to do: bsh, com.microstar.xml.*, org.gjt.*
	java-pkg_filter-compiler jikes
}

JAVA_ANT_REWRITE_CLASSPATH="true"
EANT_BUILD_TARGET="build"
# TODO could build more docs, ie userdocs target instead of generate-javadoc
EANT_DOC_TARGET="generate-javadoc"
# in fact needed only for docs, but shouldn't hurt
EANT_NEEDS_TOOLS="true"

src_install () {
	dodir ${JEDIT_HOME}
	cp -R build/${PN}.jar jars doc macros modes properties startup \
		"${D}/usr/share/jedit"

	java-pkg_regjar ${JEDIT_HOME}/${PN}.jar

	java-pkg_dolauncher ${PN} --main org.gjt.sp.jedit.jEdit

	use doc && java-pkg_dojavadoc build/classes/javadoc/api

	make_desktop_entry ${PN} \
		jEdit \
		${JEDIT_HOME}/doc/${PN}.png \
		"Development;Utility;TextEditor"

	# keep the plugin directory
	keepdir ${JEDIT_HOME}/jars
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	elog "The system directory for jEdit plugins is"
	elog "${JEDIT_HOME}/jars"
	elog "If you get plugin related errors on startup, first try updating them."
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	elog "jEdit plugins installed into /usr/share/jedit/jars"
	elog "(after installation of jEdit itself) haven't been"
	elog "removed. To get rid of jEdit completely, you may"
	elog "want to run"
	elog ""
	elog "\trm -r ${JEDIT_HOME}"
	elog "Ignore this message if you are reinstalling or upgrading."
}