[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-workspace/

[Andreas Sturmlechner]

commit:     685ee3e27aead80aaca02b1516108b6b3077ee40
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun May 29 20:18:50 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun May 29 20:24:25 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=685ee3e2

kde-plasma/plasma-workspace: Drop 5.24.4

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-workspace/Manifest               |   1 -
 .../plasma-workspace-5.24.4.ebuild                 | 219 ---------------------
 2 files changed, 220 deletions(-)

diff --git a/kde-plasma/plasma-workspace/Manifest b/kde-plasma/plasma-workspace/Manifest
index be5c47e6ef60..1ba2f05fc00f 100644
--- a/kde-plasma/plasma-workspace/Manifest
+++ b/kde-plasma/plasma-workspace/Manifest
@@ -1,2 +1 @@
-DIST plasma-workspace-5.24.4.tar.xz 18488324 BLAKE2B 140540a95360bc1c9ce1940ca03267bfe8c5d59a378b09a5c2abfed9ad8f8af89558c616465363f27a42a730025c081092f00dd0eb776cb7ee53a0aeff1b3881 SHA512 6c917d3ea307bca85e6ca12294357410c3442a9115a4864311df87af29919c20d8dab768f470379bbc4e0510367319a6cf8ce045ab7254db06e8c29477370d89
 DIST plasma-workspace-5.24.5.tar.xz 18490588 BLAKE2B 5a9681620f40604f631cd7ef0c9d6256cc490436dc5e29ef9434d0f129324c2d405c5647da12778c208976c0cb0b4da698a90a22b70c1cb2723cbc58f69bda1d SHA512 ae40fe545b03e42e9f8fe2e8885d3853f4b52d4fd2ed3ecf7d24fa59b4924b8f8b389e8713ec6a3a875bc66df3952de9157d4a5631b283105a9329a1a1825996

diff --git a/kde-plasma/plasma-workspace/plasma-workspace-5.24.4.ebuild b/kde-plasma/plasma-workspace/plasma-workspace-5.24.4.ebuild
deleted file mode 100644
index 8c06edc3b7e3..000000000000
--- a/kde-plasma/plasma-workspace/plasma-workspace-5.24.4.ebuild
+++ /dev/null
@@ -1,219 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="forceoptional"
-KFMIN=5.90.0
-PVCUT=$(ver_cut 1-3)
-QTMIN=5.15.2
-VIRTUALX_REQUIRED="test"
-inherit ecm kde.org
-
-DESCRIPTION="KDE Plasma workspace"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
-IUSE="appstream +calendar +fontconfig geolocation gps +policykit
-screencast +semantic-desktop telemetry"
-
-REQUIRED_USE="gps? ( geolocation )"
-RESTRICT="test"
-
-# slot op: various private QtWaylandClient headers
-COMMON_DEPEND="
-	>=dev-libs/wayland-1.15
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
-	>=dev-qt/qtgui-${QTMIN}:5=[jpeg,libinput]
-	>=dev-qt/qtnetwork-${QTMIN}:5
-	>=dev-qt/qtsql-${QTMIN}:5
-	>=dev-qt/qtsvg-${QTMIN}:5
-	>=dev-qt/qtwayland-${QTMIN}:5=
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtx11extras-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	>=kde-frameworks/kactivities-${KFMIN}:5
-	>=kde-frameworks/kactivities-stats-${KFMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	>=kde-frameworks/kauth-${KFMIN}:5
-	>=kde-frameworks/kbookmarks-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/kdeclarative-${KFMIN}:5
-	>=kde-frameworks/kded-${KFMIN}:5
-	>=kde-frameworks/kglobalaccel-${KFMIN}:5
-	>=kde-frameworks/kguiaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kidletime-${KFMIN}:5
-	>=kde-frameworks/kinit-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemmodels-${KFMIN}:5
-	>=kde-frameworks/kitemviews-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/knewstuff-${KFMIN}:5
-	>=kde-frameworks/knotifications-${KFMIN}:5
-	>=kde-frameworks/knotifyconfig-${KFMIN}:5
-	>=kde-frameworks/kpackage-${KFMIN}:5
-	>=kde-frameworks/kpeople-${KFMIN}:5
-	>=kde-frameworks/krunner-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/ktextwidgets-${KFMIN}:5
-	>=kde-frameworks/kunitconversion-${KFMIN}:5
-	>=kde-frameworks/kwallet-${KFMIN}:5
-	>=kde-frameworks/kwayland-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kwindowsystem-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=kde-frameworks/plasma-${KFMIN}:5
-	>=kde-frameworks/prison-${KFMIN}:5[qml]
-	>=kde-frameworks/solid-${KFMIN}:5
-	>=kde-plasma/breeze-${PVCUT}:5
-	>=kde-plasma/kscreenlocker-${PVCUT}:5
-	>=kde-plasma/kwin-${PVCUT}:5
-	>=kde-plasma/layer-shell-qt-${PVCUT}:5
-	>=kde-plasma/libkscreen-${PVCUT}:5
-	>=kde-plasma/libksysguard-${PVCUT}:5
-	>=kde-plasma/libkworkspace-${PVCUT}:5
-	>=media-libs/phonon-4.11.0
-	sci-libs/libqalculate:=
-	sys-libs/zlib
-	x11-libs/libICE
-	x11-libs/libSM
-	x11-libs/libX11
-	x11-libs/libXau
-	x11-libs/libxcb
-	x11-libs/libXcursor
-	x11-libs/libXfixes
-	x11-libs/libXrender
-	x11-libs/libXtst
-	x11-libs/xcb-util
-	x11-libs/xcb-util-image
-	appstream? ( dev-libs/appstream[qt5] )
-	calendar? ( >=kde-frameworks/kholidays-${KFMIN}:5 )
-	fontconfig? (
-		>=dev-qt/qtprintsupport-${QTMIN}:5
-		media-libs/fontconfig
-		x11-libs/libXft
-		x11-libs/xcb-util-image
-	)
-	geolocation? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
-	gps? ( sci-geosciences/gpsd )
-	policykit? ( virtual/libcrypt:= )
-	screencast? (
-		>=dev-qt/qtgui-${QTMIN}:5=[egl]
-		media-libs/libglvnd
-		>=media-video/pipewire-0.3:=
-		x11-libs/libdrm
-	)
-	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
-	telemetry? ( dev-libs/kuserfeedback:5 )
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-libs/plasma-wayland-protocols-1.6.0
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-	>=dev-util/wayland-scanner-1.19.0
-	x11-base/xorg-proto
-	fontconfig? ( x11-libs/libXrender )
-"
-RDEPEND="${COMMON_DEPEND}
-	app-text/iso-codes
-	>=dev-qt/qdbus-${QTMIN}:*
-	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
-	>=dev-qt/qtpaths-${QTMIN}:5
-	>=dev-qt/qtquickcontrols-${QTMIN}:5[widgets]
-	>=dev-qt/qtquickcontrols2-${QTMIN}:5
-	kde-apps/kio-extras:5
-	>=kde-frameworks/kirigami-${KFMIN}:5
-	>=kde-frameworks/kquickcharts-${KFMIN}:5
-	>=kde-plasma/milou-${PVCUT}:5
-	>=kde-plasma/plasma-integration-${PVCUT}:5
-	sys-apps/dbus
-	x11-apps/xmessage
-	x11-apps/xprop
-	x11-apps/xrdb
-	x11-apps/xsetroot
-	!<kde-plasma/breeze-5.22.90:5
-	!<kde-plasma/plasma-desktop-5.23.90:5
-	policykit? ( sys-apps/accountsservice )
-"
-BDEPEND="
-	>=dev-qt/qtwaylandscanner-${QTMIN}:5
-	virtual/pkgconfig
-"
-PDEPEND=">=kde-plasma/kde-cli-tools-${PVCUT}:5"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-5.21.5-split-libkworkspace.patch" # downstream
-	"${FILESDIR}/${PN}-5.22.5-krunner-cwd-at-home.patch" # TODO upstream: KDE-bug 432975, bug 767478
-)
-
-src_prepare() {
-	ecm_src_prepare
-
-	cmake_comment_add_subdirectory libkworkspace
-	# delete colliding libkworkspace translations
-	if [[ ${KDE_BUILD_TYPE} = release ]]; then
-		find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
-	fi
-
-	# TODO: try to get a build switch upstreamed
-	if ! use screencast; then
-		sed -e "s/^pkg_check_modules.*PipeWire/#&/" -i CMakeLists.txt || die
-	fi
-
-	# TODO: try to get a build switch upstreamed
-	if use geolocation; then
-		use gps || sed -e "s/^pkg_check_modules.*LIBGPS/#&/" \
-			-i dataengines/geolocation/CMakeLists.txt || die
-	fi
-
-	if ! use policykit; then
-		cmake_run_in kcms cmake_comment_add_subdirectory users
-	fi
-
-	ecm_punt_kf_module Su
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_xembed-sni-proxy=OFF
-		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON
-		$(cmake_use_find_package appstream AppStreamQt)
-		$(cmake_use_find_package calendar KF5Holidays)
-		$(cmake_use_find_package fontconfig Fontconfig)
-		$(cmake_use_find_package geolocation KF5NetworkManagerQt)
-		$(cmake_use_find_package semantic-desktop KF5Baloo)
-		$(cmake_use_find_package telemetry KUserFeedback)
-	)
-
-	ecm_src_configure
-}
-
-src_install() {
-	ecm_src_install
-
-	# default startup and shutdown scripts
-	insinto /etc/xdg/plasma-workspace/env
-	doins "${FILESDIR}"/10-agent-startup.sh
-
-	insinto /etc/xdg/plasma-workspace/shutdown
-	doins "${FILESDIR}"/10-agent-shutdown.sh
-	fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
-}
-
-pkg_postinst () {
-	ecm_pkg_postinst
-
-	elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
-	elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
-	elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
-}