[gentoo-commits] gentoo-x86 commit in net-misc/mosh: mosh-9999.ebuild metadata.xml ChangeLog mosh-1.1.3.ebuild Manifest

[Michael Weber (xmw)]

xmw         12/04/06 14:43:06

  Added:                mosh-9999.ebuild metadata.xml ChangeLog
                        mosh-1.1.3.ebuild Manifest
  Log:
  Initial import.
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  net-misc/mosh/mosh-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/mosh-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/mosh-9999.ebuild?rev=1.1&content-type=text/plain

Index: mosh-9999.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/mosh-9999.ebuild,v 1.1 2012/04/06 14:43:06 xmw Exp $

EAPI=4
EGIT_REPO_URI="https://github.com/keithw/mosh.git"

inherit autotools git-2 toolchain-funcs

DESCRIPTION="Mobile shell that supports roaming and intelligent local echo"
HOMEPAGE="http://mosh.mit.edu"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
IUSE="+client examples +server +utempter"
REQUIRED_USE="|| ( client server )
	examples? ( client )"

RDEPEND="dev-libs/protobuf
	dev-libs/skalibs
	sys-libs/ncurses:5
	virtual/ssh
	client? ( dev-lang/perl
		dev-perl/IO-Tty )
	utempter? ( sys-libs/libutempter )"
DEPEND="${RDEPEND}
	dev-libs/boost
	dev-util/pkgconfig"

src_prepare() {
	echo 'char const * PROG = "mosh-client" ;' >> src/frontend/mosh-client.cc
	echo 'char const * PROG = "mosh-server" ;' >> src/frontend/mosh-server.cc
	echo 'char const * PROG = "termemu" ;' >> src/examples/termemu.cc
	eautoreconf
}

src_configure() {
	econf \
		--with-skalibs=/ \
		--with-skalibs-include=/usr/include/skalibs \
		--with-skalibs-libdir=/usr/$(get_libdir)/skalibs \
		$(use_enable client) \
		$(use_enable server) \
		$(use_enable examples) \
		$(use_with utempter)
}

src_install() {
	default

	for myprog in $(find src/examples -type f -perm /0111) ; do
		newbin ${myprog} ${PN}-$(basename ${myprog})
		elog "${myprog} installed as ${PN}-$(basename ${myprog})"
	done
}



1.1                  net-misc/mosh/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer>
<email>xmw@g.o</email>
<name>Michael Weber</name>
</maintainer>
<use>
<flag name="client">Build network client</flag>
<flag name="server">Build network server</flag>
<flag name="examples">Include example scripts</flag>
<flag name="utempter">Include libutempter support</flag>
</use>
<longdescription>
Mosh is a remote terminal application that supports:
  - intermittent network connectivity,
  - roaming to different IP address without dropping the connection, and
  - intelligent local echo and line editing to reduce the effects
    of "network lag" on high-latency connections.
</longdescription>
</pkgmetadata>




1.1                  net-misc/mosh/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for net-misc/mosh
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/ChangeLog,v 1.1 2012/04/06 14:43:06 xmw Exp $

*mosh-9999 (06 Apr 2012)
*mosh-1.1.3 (06 Apr 2012)

  06 Apr 2012; Michael Weber <xmw@g.o> +mosh-1.1.3.ebuild,
  +mosh-9999.ebuild, +metadata.xml:
  Initial import.




1.1                  net-misc/mosh/mosh-1.1.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/mosh-1.1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/mosh-1.1.3.ebuild?rev=1.1&content-type=text/plain

Index: mosh-1.1.3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/mosh-1.1.3.ebuild,v 1.1 2012/04/06 14:43:06 xmw Exp $

EAPI=4

inherit autotools toolchain-funcs

DESCRIPTION="Mobile shell that supports roaming and intelligent local echo"
HOMEPAGE="http://mosh.mit.edu"
SRC_URI="https://github.com/keithw/mosh/tarball/${P} -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+client examples +server +utempter"
REQUIRED_USE="|| ( client server )
	examples? ( client )"

RDEPEND="dev-libs/protobuf
	dev-libs/skalibs
	sys-libs/ncurses:5
	virtual/ssh
	client? ( dev-lang/perl
		dev-perl/IO-Tty )
	utempter? ( sys-libs/libutempter )"
DEPEND="${RDEPEND}
	dev-libs/boost
	dev-util/pkgconfig"

src_unpack() {
	default
	mv *-${PN}-* ${P} || die
}

src_prepare() {
	echo 'char const * PROG = "mosh-client" ;' >> src/frontend/mosh-client.cc
	echo 'char const * PROG = "mosh-server" ;' >> src/frontend/mosh-server.cc
	echo 'char const * PROG = "termemu" ;' >> src/examples/termemu.cc
	eautoreconf
}

src_configure() {
	econf \
		--with-skalibs=/ \
		--with-skalibs-include=/usr/include/skalibs \
		--with-skalibs-libdir=/usr/$(get_libdir)/skalibs \
		$(use_enable client) \
		$(use_enable server) \
		$(use_enable examples) \
		$(use_with utempter)
}

src_install() {
	default

	for myprog in $(find src/examples -type f -perm /0111) ; do
		newbin ${myprog} ${PN}-$(basename ${myprog})
		elog "${myprog} installed as ${PN}-$(basename ${myprog})"
	done
}



1.1                  net-misc/mosh/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
DIST mosh-1.1.3.tar.gz 135180 RMD160 58c916e7c01ed202ee4f8d059ede382c4bb87801 SHA1 011a59ebaf1cd8230ca8320c15b95db0575889f9 SHA256 6d0fd2382662d2fa2604a7fa62a7d43fc1284035c65f1b67aa880ca95421a184
EBUILD mosh-1.1.3.ebuild 1463 RMD160 75b8cc0290a44ad87f086cfd6dd6991dd691271a SHA1 5a779ad862e762171444e7cf33fc7ddb69d78161 SHA256 12f28904278cf4e281a99779a488cb1903d00437f48e3d0f4c89dd339105c028
EBUILD mosh-9999.ebuild 1387 RMD160 6d3c71a422fc977198ef7a4e49ea762685e16e3a SHA1 4e78d6217998a34aeb4bdd06737699d5d0193f8f SHA256 48755a2ca4256ab819db255ab15635dca6fdb162f85e2f7cc9ba5881011fb3ad
MISC ChangeLog 287 RMD160 ee400d84fc390cf9ffa34d33a1da844b9107c25a SHA1 bc6765ae064ac6aeea1f0bd83cae415aa6b05e05 SHA256 9add01de5d31e04401297da80fa6243bbf619838737d35a379d1e765cce00528
MISC metadata.xml 761 RMD160 f9474551c2d01a25d8cceabad1595bf450f1d225 SHA1 b287a1d5b79a05f1e230f7c71316abf6808ef816 SHA256 af9c5a3a61b5dd347ddf6101d68a5e934fc1895aad842d4ee0a103bc626ed8c1