[gentoo-commits] gentoo-x86 commit in kde-base/gwenview: ChangeLog gwenview-4.11.3.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    13/11/05 22:22:50

  Modified:             ChangeLog
  Added:                gwenview-4.11.3.ebuild
  Log:
  Version bump KDE SC 4.11.3
  
  (Portage version: 2.2.7/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key EBE6A336BE19039C!)

Revision  Changes    Path
1.199                kde-base/gwenview/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?rev=1.199&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?rev=1.199&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?r1=1.198&r2=1.199

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v
retrieving revision 1.198
retrieving revision 1.199
diff -u -r1.198 -r1.199
--- ChangeLog	10 Oct 2013 01:26:37 -0000	1.198
+++ ChangeLog	5 Nov 2013 22:22:50 -0000	1.199
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/gwenview
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v 1.198 2013/10/10 01:26:37 creffett Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v 1.199 2013/11/05 22:22:50 dilfridge Exp $
+
+*gwenview-4.11.3 (05 Nov 2013)
+
+  05 Nov 2013; Andreas K. Huettel <dilfridge@g.o>
+  +gwenview-4.11.3.ebuild:
+  Version bump KDE SC 4.11.3
 
   10 Oct 2013; Chris Reffett <creffett@g.o> -gwenview-4.11.1.ebuild:
   Drop KDE SC 4.11.1



1.1                  kde-base/gwenview/gwenview-4.11.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/gwenview-4.11.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/gwenview-4.11.3.ebuild?rev=1.1&content-type=text/plain

Index: gwenview-4.11.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/gwenview-4.11.3.ebuild,v 1.1 2013/11/05 22:22:50 dilfridge Exp $

EAPI=5

KDE_HANDBOOK="optional"
OPENGL_REQUIRED="always"
inherit kde4-base

DESCRIPTION="KDE image viewer"
HOMEPAGE="
	http://www.kde.org/applications/graphics/gwenview/
	http://gwenview.sourceforge.net/
"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug kipi semantic-desktop"

# tests fail, last checked 4.11.0
RESTRICT="test"

DEPEND="
	$(add_kdebase_dep kdelibs 'semantic-desktop?')
	$(add_kdebase_dep libkonq)
	$(add_kdebase_dep kactivities)
	>=media-gfx/exiv2-0.19
	media-libs/lcms:2
	media-libs/libpng:0=
	virtual/jpeg:0
	x11-libs/libX11
	kipi? ( $(add_kdebase_dep libkipi) )
"
RDEPEND="${DEPEND}"

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with semantic-desktop Soprano)
		$(cmake-utils_use_with kipi)
	)
	# Workaround for bug #479510
	if [[ -e ${EPREFIX}/usr/include/${CHOST}/jconfig.h ]]; then
		mycmakeargs+=( -DJCONFIG_H="${EPREFIX}/usr/include/${CHOST}/jconfig.h" )
	fi

	if use semantic-desktop; then
		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=Nepomuk)
	else
		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=None)
	fi

	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if ! has_version kde-base/svgpart:${SLOT} ; then
		elog "For SVG support, install kde-base/svgpart:${SLOT}"
	fi

	if use kipi && ! has_version media-plugins/kipi-plugins ; then
		elog "The plugins for the KIPI inteface can be found in media-plugins/kipi-plugins"
	fi
}