[gentoo-commits] gentoo-x86 commit in net-wireless/broadcom-sta: ChangeLog broadcom-sta-5.100.82.112-r2.ebuild

[Matsuu Takuto (matsuu)]

matsuu      11/11/21 16:03:44

  Modified:             ChangeLog
  Added:                broadcom-sta-5.100.82.112-r2.ebuild
  Log:
  Fixed to work with linux-3.2, bug #390627.
  
  (Portage version: 2.1.10.29/cvs/Linux x86_64)

Revision  Changes    Path
1.42                 net-wireless/broadcom-sta/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/broadcom-sta/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	11 Nov 2011 16:51:58 -0000	1.41
+++ ChangeLog	21 Nov 2011 16:03:44 -0000	1.42
@@ -1,6 +1,13 @@
 # ChangeLog for net-wireless/broadcom-sta
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/broadcom-sta/ChangeLog,v 1.41 2011/11/11 16:51:58 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/broadcom-sta/ChangeLog,v 1.42 2011/11/21 16:03:44 matsuu Exp $
+
+*broadcom-sta-5.100.82.112-r2 (21 Nov 2011)
+
+  21 Nov 2011; MATSUU Takuto <matsuu@g.o>
+  +broadcom-sta-5.100.82.112-r2.ebuild,
+  +files/broadcom-sta-5.100.82.112-linux-3.2.patch:
+  Fixed to work with linux-3.2, bug #390627.
 
 *broadcom-sta-5.100.82.112-r1 (11 Nov 2011)
 



1.1                  net-wireless/broadcom-sta/broadcom-sta-5.100.82.112-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/broadcom-sta-5.100.82.112-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/broadcom-sta-5.100.82.112-r2.ebuild?rev=1.1&content-type=text/plain

Index: broadcom-sta-5.100.82.112-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/broadcom-sta/broadcom-sta-5.100.82.112-r2.ebuild,v 1.1 2011/11/21 16:03:44 matsuu Exp $

EAPI="4"
inherit eutils linux-mod

DESCRIPTION="Broadcom's IEEE 802.11a/b/g/n hybrid Linux device driver."
HOMEPAGE="http://www.broadcom.com/support/802.11/linux_sta.php"
SRC_BASE="http://www.broadcom.com/docs/linux_sta/hybrid-portsrc_x86_"
SRC_URI="x86? ( ${SRC_BASE}32-v${PV//\./_}.tar.gz )
	amd64? ( ${SRC_BASE}64-v${PV//\./_}.tar.gz )"

LICENSE="Broadcom"
KEYWORDS="~amd64 ~x86"
IUSE=""

RESTRICT="mirror"

DEPEND="virtual/linux-sources"
RDEPEND=""

S="${WORKDIR}"

MODULE_NAMES="wl(net/wireless)"
MODULESD_WL_ALIASES=("wlan0 wl")

pkg_setup() {
	# bug #300570
	# NOTE<lxnay>: module builds correctly anyway with b43 and SSB enabled
	# make checks non-fatal. The correct fix is blackisting ssb and, perhaps
	# b43 via udev rules. Moreover, previous fix broke binpkgs support.
	CONFIG_CHECK="~!B43 ~!SSB"
	if kernel_is ge 2 6 32; then
		CONFIG_CHECK="${CONFIG_CHECK} CFG80211 LIB80211 ~!MAC80211"
	elif kernel_is ge 2 6 31; then
		CONFIG_CHECK="${CONFIG_CHECK} LIB80211 WIRELESS_EXT ~!MAC80211"
	elif kernel_is ge 2 6 29; then
		CONFIG_CHECK="${CONFIG_CHECK} LIB80211 WIRELESS_EXT ~!MAC80211 COMPAT_NET_DEV_OPS"
	else
		CONFIG_CHECK="${CONFIG_CHECK} IEEE80211 IEEE80211_CRYPT_TKIP"
	fi
	linux-mod_pkg_setup

	BUILD_PARAMS="-C ${KV_DIR} M=${S}"
	BUILD_TARGETS="wl.ko"
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-5.10.91.9-license.patch" \
		"${FILESDIR}/${PN}-5.100.82.38-gcc.patch" \
		"${FILESDIR}/${PN}-5.100.82.111-linux-3.0.patch" \
		"${FILESDIR}/${PN}-5.100.82.112-linux-2.6.39.patch" \
		"${FILESDIR}/${PN}-5.100.82.112-linux-3.2.patch"
}