[gentoo-commits] repo/gentoo:master commit in: dev-python/django-debug-toolbar/

[Michał Górny]

commit:     e82ea9867321af24d1c16e02dd04b5202999780f
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 26 17:45:43 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Feb 26 17:59:45 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e82ea986

dev-python/django-debug-toolbar: Migrate to PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../django-debug-toolbar-3.2.4-r1.ebuild           | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-python/django-debug-toolbar/django-debug-toolbar-3.2.4-r1.ebuild b/dev-python/django-debug-toolbar/django-debug-toolbar-3.2.4-r1.ebuild
new file mode 100644
index 000000000000..415fa5669079
--- /dev/null
+++ b/dev-python/django-debug-toolbar/django-debug-toolbar-3.2.4-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A configurable set of panels that display debug information"
+HOMEPAGE="
+	https://pypi.org/project/django-debug-toolbar/
+	https://github.com/jazzband/django-debug-toolbar/"
+SRC_URI="
+	https://github.com/jazzband/django-debug-toolbar/archive/${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-1.11[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+	)
+"
+
+distutils_enable_sphinx docs
+
+python_test() {
+	emake TEST_ARGS='-v 2 tests' test
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}