[gentoo-commits] gentoo-x86 commit in dev-python/mwlib: mwlib-0.15.15.ebuild ChangeLog

[Tiziano Mueller (dev-zero)]

dev-zero    14/06/06 14:14:53

  Modified:             ChangeLog
  Added:                mwlib-0.15.15.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x1A5D023975B0583D!)

Revision  Changes    Path
1.32                 dev-python/mwlib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/mwlib/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	30 Jan 2014 13:36:42 -0000	1.31
+++ ChangeLog	6 Jun 2014 14:14:53 -0000	1.32
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/mwlib
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib/ChangeLog,v 1.31 2014/01/30 13:36:42 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib/ChangeLog,v 1.32 2014/06/06 14:14:53 dev-zero Exp $
+
+*mwlib-0.15.15 (06 Jun 2014)
+
+  06 Jun 2014; Tiziano Müller <dev-zero@g.o> +mwlib-0.15.15.ebuild:
+  Version bump.
 
 *mwlib-0.15.14 (30 Jan 2014)
 



1.1                  dev-python/mwlib/mwlib-0.15.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib/mwlib-0.15.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib/mwlib-0.15.15.ebuild?rev=1.1&content-type=text/plain

Index: mwlib-0.15.15.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib/mwlib-0.15.15.ebuild,v 1.1 2014/06/06 14:14:53 dev-zero Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )

inherit distutils-r1 user

DESCRIPTION="Tools for parsing Mediawiki content to other formats"
HOMEPAGE="http://code.pediapress.com/code/ http://pypi.python.org/pypi/mwlib https://github.com/pediapress/mwlib/"
SRC_URI="https://github.com/pediapress/mwlib/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc server test"

RDEPEND="dev-python/lxml[${PYTHON_USEDEP}]
	>=dev-python/odfpy-0.9[${PYTHON_USEDEP}]
	<dev-python/odfpy-0.10[${PYTHON_USEDEP}]
	>=dev-python/pyPdf-1.12[${PYTHON_USEDEP}]
	>=dev-python/pyparsing-1.5.5[${PYTHON_USEDEP}]
	<dev-python/pyparsing-1.6[${PYTHON_USEDEP}]
	>=dev-python/timelib-0.2[${PYTHON_USEDEP}]
	virtual/latex-base
	>=dev-python/simplejson-2.3[${PYTHON_USEDEP}]
	dev-python/gevent[${PYTHON_USEDEP}]
	>=dev-python/bottle-0.10[${PYTHON_USEDEP}]
	>=dev-python/apipkg-1.2[${PYTHON_USEDEP}]
	>=dev-python/qserve-0.2.7[${PYTHON_USEDEP}]
	dev-python/roman[${PYTHON_USEDEP}]
	>=dev-python/py-1.4[${PYTHON_USEDEP}]
	dev-python/sqlite3dbm[${PYTHON_USEDEP}]
	dev-python/pillow[${PYTHON_USEDEP}]
	server? ( app-admin/sudo )"
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	app-arch/unzip
	doc? ( dev-python/sphinx )
	test? ( >=dev-python/wsgiintercept-0.6 )"

# TODO: requires ploticus to generate timelines

DOCS=(changelog.rst)

pkg_setup() {
	if use server ;  then
		enewgroup mwlib
		enewuser mwlib -1 -1 -1 mwlib
	fi
}

python_prepare_all() {
	# mwlib.apipkg is actually used.
	sed -e 's/, "apipkg"//' -i setup.py || die

	# Execute odflint script.
	sed \
		-e "/def _get_odflint_module():/,/odflint =	_get_odflint_module()/d" \
		-e "s/odflint.lint(path)/os.system('odflint %s' % path)/" \
		-i tests/test_odfwriter.py || die

	# Disable test which requires installed mw-zip or mw-render script
	# which don't get generated in distutils_install_for_testing for some reason
	rm -f tests/test_{nuwiki,redirect,render,zipwiki}.py || die

	distutils-r1_python_prepare_all
}

python_compile() {
	if [[ ${EPYTHON} == python2* ]] ; then
		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
		export CFLAGS
	fi

	distutils-r1_python_compile
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	distutils_install_for_testing
	PATH="${TEST_DIR}/scripts:${PATH}" py.test || die
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )
	distutils-r1_python_install_all

	if use server ; then
		keepdir /var/log/mwlib
		keepdir /var/cache/mwlib

		fowners mwlib:mwlib /var/log/mwlib /var/cache/mwlib
		fperms 0750 /var/log/mwlib /var/cache/mwlib

		insinto /etc/logrotate.d
		for d in mw-qserve nserve ; do
			newins "${FILESDIR}/${d}.logrotate" "${d}"
			newinitd "${FILESDIR}/${d}.initd" "${d}"
			newconfd "${FILESDIR}/${d}.confd" "${d}"
		done

		newins "${FILESDIR}/nslave.logrotate" "nslave"
		newinitd "${FILESDIR}/nslave.initd-r1" "nslave"
		newconfd "${FILESDIR}/nslave.confd-r1" "nslave"

		newins "${FILESDIR}/postman.logrotate" "postman"
		newinitd "${FILESDIR}/postman.initd-r1" "postman"
		newconfd "${FILESDIR}/postman.confd" "postman"

		insinto /etc/cron.d
		newins "${FILESDIR}/mwlib-purge-cache.cron-r1" "mwlib-purge-cache"
	else
		rm "${D}"/usr/bin/{mw-qserve,nserve,nslave,postman}* || die "removing binaries failed"
	fi
}

pkg_postinst() {
	elog "Please enable required image formats for dev-python/pillow"
	if use server ; then
		elog "A cronjob to cleanup the cache files got installed to"
		elog "  /etc/cron.d/mwlib-purge-cache"
		elog "Default parameters are to clean every 24h, adjust it to your needs."
	fi
}