[gentoo-commits] gentoo-x86 commit in dev-vcs/monotone: ChangeLog monotone-0.99.ebuild

[Peter Volkov (pva)]

pva         10/10/29 07:58:13

  Modified:             ChangeLog
  Added:                monotone-0.99.ebuild
  Log:
  Version bump, fixes security bug #342705 thank Tim Sammut for report.
  
  (Portage version: 2.1.9.22/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  dev-vcs/monotone/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/monotone/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	19 Oct 2010 18:12:20 -0000	1.7
+++ ChangeLog	29 Oct 2010 07:58:13 -0000	1.8
@@ -1,6 +1,11 @@
 # ChangeLog for dev-vcs/monotone
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/monotone/ChangeLog,v 1.7 2010/10/19 18:12:20 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/monotone/ChangeLog,v 1.8 2010/10/29 07:58:13 pva Exp $
+
+*monotone-0.99 (29 Oct 2010)
+
+  29 Oct 2010; Peter Volkov <pva@g.o> +monotone-0.99.ebuild:
+  Version bump, fixes security bug #342705 thank Tim Sammut for report.
 
   19 Oct 2010; Brent Baude <ranger@g.o> monotone-0.48.ebuild:
   stable ppc, bug 338345



1.1                  dev-vcs/monotone/monotone-0.99.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/monotone-0.99.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/monotone-0.99.ebuild?rev=1.1&content-type=text/plain

Index: monotone-0.99.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/monotone/monotone-0.99.ebuild,v 1.1 2010/10/29 07:58:13 pva Exp $

EAPI=2
inherit bash-completion elisp-common eutils toolchain-funcs

DESCRIPTION="Monotone Distributed Version Control System"
HOMEPAGE="http://monotone.ca"
SRC_URI="http://monotone.ca/downloads/${PV}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="1"
KEYWORDS="~amd64 ~ia64 ~ppc ~x86"
IUSE="doc emacs ipv6 nls"

RDEPEND="sys-libs/zlib
	emacs? ( virtual/emacs )
	>=dev-libs/libpcre-7.6
	>=dev-libs/botan-1.8.0
	>=dev-db/sqlite-3.3.8
	>=dev-lang/lua-5.1
	net-dns/libidn"
DEPEND="${RDEPEND}
	>=dev-libs/boost-1.33.1
	nls? ( >=sys-devel/gettext-0.11.5 )
	doc? ( sys-apps/texinfo )"

pkg_setup() {
	enewgroup monotone
	enewuser monotone -1 -1 /var/lib/monotone monotone
}

src_prepare() {
	if [[ $(gcc-major-version) -lt "3"  ||
		( $(gcc-major-version) -eq "3" && $(gcc-minor-version) -le 3 ) ]]; then
		die 'requires >=gcc-3.4'
	fi
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		$(use_enable ipv6)
}

src_compile() {
	emake || die

	if use doc; then
		emake html || die
	fi

	if use emacs; then
		cd contrib
		elisp-compile *.el || die
	fi
}

src_test() {
	if [ ${UID} != 0 ]; then
		emake check || die "emake check failed"
	else
		ewarn "Tests will fail if ran as root, skipping."
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die

	mv "${D}"/usr/share/doc/${PN} "${D}"/usr/share/doc/${PF} || die

	dobashcompletion contrib/monotone.bash_completion

	if use doc; then
		dohtml -r html/*
		dohtml -r figures
	fi

	if use emacs; then
		elisp-install ${PN} contrib/*.{el,elc} || die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el \
			|| die
	fi

	dodoc AUTHORS NEWS README* UPGRADE || die
	docinto contrib
	dodoc contrib/*
	newconfd "${FILESDIR}"/monotone.confd monotone || die
	newinitd "${FILESDIR}"/${PN}-0.36.initd monotone || die

	insinto /etc/monotone
	newins "${FILESDIR}"/hooks.lua hooks.lua || die
	newins "${FILESDIR}"/read-permissions read-permissions || die
	newins "${FILESDIR}"/write-permissions write-permissions || die

	keepdir /var/lib/monotone/keys/ /var/{log,run}/monotone
	fowners monotone:monotone /var/lib/monotone{,/keys} /var/{log,run}/monotone
}

pkg_postinst() {
	use emacs && elisp-site-regen
	bash-completion_pkg_postinst

	elog
	elog "For details and instructions to upgrade from previous versions,"
	elog "please read /usr/share/doc/${PF}/UPGRADE.bz2"
	elog
	elog "  1. edit /etc/conf.d/monotone"
	elog "  2. import the first keys to enable access with"
	elog "     env HOME=\${homedir} mtn pubkey me@×××××××.net | /etc/init.d/monotone import"
	elog "     Thereafter, those with write permission can add other keys via"
	elog "     netsync with 'monotone push --key-to-push=IDENT' and then IDENT"
	elog "     can be used in the read-permission and write-permission files."
	elog "  3. adjust permisions in /etc/monotone/read-permissions"
	elog "                      and /etc/monotone/write-permissions"
	elog "  4. start the daemon: /etc/init.d/monotone start"
	elog "  5. make persistent: rc-update add monotone default"
	elog
}

pkg_postrm() {
	use emacs && elisp-site-regen
}