[gentoo-commits] gentoo-x86 commit in app-mobilephone/kannel: kannel-1.4.1.ebuild kannel-1.4.3.ebuild ChangeLog

[Alin Nastac (mrness)]

mrness      09/03/01 16:04:24

  Modified:             kannel-1.4.1.ebuild ChangeLog
  Added:                kannel-1.4.3.ebuild
  Log:
  Set LICENSE to Kannel.
  Version bump.
  Disable sqlite2 support.
  Use libuuid installed by e2fsprogs-libs (#252857).
  (Portage version: 2.1.6.7/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 app-mobilephone/kannel/kannel-1.4.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/kannel/kannel-1.4.1.ebuild?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/kannel/kannel-1.4.1.ebuild?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/kannel/kannel-1.4.1.ebuild?r1=1.9&r2=1.10

Index: kannel-1.4.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/kannel/kannel-1.4.1.ebuild,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- kannel-1.4.1.ebuild	24 Jun 2008 00:32:49 -0000	1.9
+++ kannel-1.4.1.ebuild	1 Mar 2009 16:04:24 -0000	1.10
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/kannel/kannel-1.4.1.ebuild,v 1.9 2008/06/24 00:32:49 mrness Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/kannel/kannel-1.4.1.ebuild,v 1.10 2009/03/01 16:04:24 mrness Exp $
 
 WANT_AUTOMAKE=none
 
@@ -10,7 +10,7 @@
 HOMEPAGE="http://www.kannel.org/"
 SRC_URI="http://www.kannel.org/download/${PV}/gateway-${PV}.tar.gz"
 
-LICENSE="BSD"
+LICENSE="Kannel"
 SLOT="0"
 KEYWORDS="~amd64 x86"
 IUSE="ssl mysql sqlite sqlite3 postgres pcre doc debug pam"



1.18                 app-mobilephone/kannel/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/kannel/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/kannel/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/kannel/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/kannel/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	24 Jun 2008 00:31:46 -0000	1.17
+++ ChangeLog	1 Mar 2009 16:04:24 -0000	1.18
@@ -1,6 +1,16 @@
 # ChangeLog for app-mobilephone/kannel
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/kannel/ChangeLog,v 1.17 2008/06/24 00:31:46 mrness Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/kannel/ChangeLog,v 1.18 2009/03/01 16:04:24 mrness Exp $
+
+*kannel-1.4.3 (01 Mar 2009)
+
+  01 Mar 2009; Alin Năstac <mrness@g.o>
+  +files/kannel-1.4.3-custom-wap-ports.patch,
+  +files/kannel-1.4.3-external-libuuid.patch,
+  +files/kannel-1.4.3-nolex.patch, kannel-1.4.1.ebuild,
+  +kannel-1.4.3.ebuild:
+  Set LICENSE to Kannel. Version bump. Disable sqlite2 support. Use libuuid
+  installed by e2fsprogs-libs (#252857).
 
   24 Jun 2008; Alin Năstac <mrness@g.o>
   +files/kannel-1.4.1-nolex.patch, kannel-1.4.1.ebuild:



1.1                  app-mobilephone/kannel/kannel-1.4.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/kannel/kannel-1.4.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/kannel/kannel-1.4.3.ebuild?rev=1.1&content-type=text/plain

Index: kannel-1.4.3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/kannel/kannel-1.4.3.ebuild,v 1.1 2009/03/01 16:04:24 mrness Exp $

EAPI="2"
WANT_AUTOMAKE=none

inherit eutils autotools flag-o-matic

DESCRIPTION="Powerful SMS and WAP gateway"
HOMEPAGE="http://www.kannel.org/"
SRC_URI="http://www.kannel.org/download/${PV}/gateway-${PV}.tar.gz"

LICENSE="Kannel"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ssl mysql sqlite postgres pcre doc debug pam"

RDEPEND="sys-libs/e2fsprogs-libs
	>=dev-libs/libxml2-2.6.26
	>=dev-lang/perl-5.8.8
	>=sys-libs/zlib-1.2.3
	ssl? ( >=dev-libs/openssl-0.9.8d )
	mysql? ( virtual/mysql )
	sqlite? ( >=dev-db/sqlite-3.2.1 )
	postgres? ( virtual/postgresql-server )
	pcre? ( dev-libs/libpcre )
	doc? ( media-gfx/transfig
		app-text/jadetex
		app-text/docbook-dsssl-stylesheets )
	pam? ( virtual/pam )"
DEPEND="${RDEPEND}
	>=sys-devel/bison-2.2"

S="${WORKDIR}/gateway-${PV}"

pkg_setup() {
	enewgroup kannel
	enewuser kannel -1 -1 /var/log/kannel kannel
}

src_unpack() {
	unpack ${A}

	cd "${S}"
	epatch "${FILESDIR}/${P}-custom-wap-ports.patch"
	epatch "${FILESDIR}/${P}-nolex.patch" # flex is not used
	epatch "${FILESDIR}/${P}-external-libuuid.patch"

	#by default, use current directory for logging
	sed -i -e 's:/tmp/::' doc/examples/kannel.conf

	eautoconf
}

src_configure() {
	append-flags -fno-strict-aliasing # some code breaks strict aliasing
	econf --docdir=/usr/share/doc/${P} \
		--enable-localtime \
		--disable-start-stop-daemon \
		--without-sqlite2 \
		$(use_enable pam) \
		$(use_enable debug debug) \
		$(use_enable pcre) \
		$(use_enable doc docs) \
		$(use_enable ssl) \
		$(use_with mysql) \
		$(use_with sqlite sqlite3) \
		$(use_with postgres pgsql) \
		|| die "econf failed"
}

src_test() {
	emake check || die "make check failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	if use doc; then
		emake DESTDIR="${D}" install-docs || die "emake install-docs failed"
	fi
	dodoc README

	diropts -g kannel -m0750
	dodir /etc/kannel
	insinto /etc/kannel
	newins doc/examples/kannel.conf kannel.conf.sample
	newins doc/examples/modems.conf modems.conf.sample
	use mysql && newins doc/examples/dlr-mysql.conf dlr-mysql.conf.sample

	diropts -g kannel -m0770
	keepdir /var/log/kannel

	newinitd "${FILESDIR}/kannel-initd" kannel
	newconfd "${FILESDIR}/kannel-confd" kannel
}