[gentoo-commits] repo/gentoo:master commit in: dev-python/setuptools/

[Michał Górny]

commit:     8e5aab10c31129a70b510a93a9b2a3fa7a3f5ec2
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue May 17 07:02:29 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue May 17 07:03:05 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e5aab10

dev-python/setuptools: Revert "Bump to 62.3.0"

The new release is buggy, a new one is coming.

Reverts: 8a53ced10aae599d2512f3571f84e7835492ab83
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/setuptools/Manifest                 |   2 -
 dev-python/setuptools/setuptools-62.3.0.ebuild | 131 -------------------------
 2 files changed, 133 deletions(-)

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 9332d2224f32..ca3685b86803 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -1,7 +1,5 @@
 DIST python-gentoo-patches-3.10.0_p1.tar.xz 10068 BLAKE2B 1c9817b449831559f0a0b722c02a5f55d94b3dfde98e5882c1403fe24a4addf7074ab39c09b91cff6fd7ace2e4b6e8ed899d9a0b9ffd6612ce315c4c192bd309 SHA512 39aa41dbf17b6dc5255491c75031a3dae6962b44125e426dbfdce365a6533c5dae9856b1fff8016a189124b7cff72d2665ce99da344c2f9dff005ba685e8c2c4
 DIST python-gentoo-patches-3.10.4.tar.xz 8592 BLAKE2B 67fba3e1fedb17430e5cd93da995b4acaf714db512031b5a2f775a25f793f007941561663cfa413d645ccddc2e22d65d250a40fa166cafda8805488d877ff57d SHA512 3ed2b8ff8f1eb8febe7dcd4b5d13d6d54468be1d525f8f1118977d3bbc78f690a597b09383939d023b03380a306e4bff1693382e29ff562312d803305b1709b2
-DIST python-gentoo-patches-3.10.4_p1.tar.xz 9648 BLAKE2B e89fa6d4d0d56614242e23d112931cab3447db258548f86e6d09af3db95a3c4f97bb4a939659b85fcc897c0ce4d613c5d55af5da3ae2bd074c2cfc91210d4d34 SHA512 d6bb91ce471cb01891bf5bc1f03914714a34e6a1780f279b937dfb21aea1cf65d84c89c792e0d46286f3c9030ad99bc42b2657aa7e8c6bf0ed0d973b381fb5f9
 DIST setuptools-60.10.0.tar.gz 2420706 BLAKE2B 66d7f3b648b1e3222736ddf46ff97441bc9ed4dc528e0d4ee32ef18c99b2d3488e7525a1598a18df4f2cbdac409a4096a40539807c343d99707068a15003111d SHA512 e679bd84d31cb68f92899e0b25d5a6bf85cf63d9c8e1dfbfe974d7bf819cb36f451596b8715000be6a93656b972dc6c4d90a8a8534a6c88874a0be8140f2f091
 DIST setuptools-62.1.0.tar.gz 2512885 BLAKE2B a26a6bd5001922885b623bc7f1d42da90c59e6d9e195e9dd292ce2e73cd35a51f07fc714261c12db2fdf4510fa1137f57e7f3f649312f6a75035b9d927936a7c SHA512 41f39b5aa22e908c123e8e04c11e505e23cd3aaaae72793e106015dc14b1a44ff3b17aa15ca3da34f34a4becc887ceea7f41932650e38d409f95d7227707d2e1
 DIST setuptools-62.2.0.tar.gz 2512927 BLAKE2B 34932917fb635aa434b574d2e47d1dd0dd742275dc577e7592fc7ad2b7892d7e0fa5281b687873a8a70ab44cb28ecc7a5b8889c954ffcafc2ce298e10a28f3f0 SHA512 4d5b9a88088ef6cb0a742bd708ab52798ee5202a0be33dd6102fa44975d121496edda1ddd9abd4a97e4c29fe804687a1d298d930004a53ee2935c0a15821917f
-DIST setuptools-62.3.0.tar.gz 2583841 BLAKE2B 61247278b34b1a90efe77a4ef5e75321540831e7feeab1b6ea6be57d2373de69fd67f5d605f46cddf907be8f3588eb4ea36562d9509eb0fd2e3129ec9ca93ce7 SHA512 76001e87cd3893407c6e8ef3c606ac46e123a5e9c2b73c7f440863c64e5fc1960a73fca100a7cb4a1df5f4e58fa333f1ee5f88a96f9fe451434d932c8f359f0f

diff --git a/dev-python/setuptools/setuptools-62.3.0.ebuild b/dev-python/setuptools/setuptools-62.3.0.ebuild
deleted file mode 100644
index 0f314f2dadca..000000000000
--- a/dev-python/setuptools/setuptools-62.3.0.ebuild
+++ /dev/null
@@ -1,131 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
-EAPI=7
-
-DISTUTILS_USE_PEP517=standalone
-PYTHON_COMPAT=( python3_{8..11} pypy3 )
-PYTHON_REQ_USE="xml(+)"
-
-inherit distutils-r1 multiprocessing
-
-CPY_PATCHSET="python-gentoo-patches-3.10.4_p1"
-DESCRIPTION="Collection of extensions to Distutils"
-HOMEPAGE="
-	https://github.com/pypa/setuptools/
-	https://pypi.org/project/setuptools/
-"
-SRC_URI="
-	mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
-	https://dev.gentoo.org/~mgorny/dist/python/${CPY_PATCHSET}.tar.xz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-solaris"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-python/appdirs-1.4.4-r2[${PYTHON_USEDEP}]
-	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
-	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
-	dev-python/nspektr[${PYTHON_USEDEP}]
-	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
-	>=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		>=dev-python/importlib_metadata-4.10.1-r1[${PYTHON_USEDEP}]
-	' 3.8 3.9)
-	$(python_gen_cond_dep '
-		>=dev-python/importlib_resources-5.4.0-r3[${PYTHON_USEDEP}]
-	' 3.8)
-"
-BDEPEND="
-	${RDEPEND}
-	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/build[${PYTHON_USEDEP}]
-			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
-			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
-			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
-			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
-			dev-python/mock[${PYTHON_USEDEP}]
-			dev-python/pip[${PYTHON_USEDEP}]
-			dev-python/pip-run[${PYTHON_USEDEP}]
-			dev-python/pytest[${PYTHON_USEDEP}]
-			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
-			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
-			dev-python/pytest-xdist[${PYTHON_USEDEP}]
-			dev-python/tomli[${PYTHON_USEDEP}]
-			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
-			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
-			dev-python/wheel[${PYTHON_USEDEP}]
-		' python3_{8..11} pypy3)
-	)
-"
-PDEPEND="
-	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
-	dev-python/setuptools_scm[${PYTHON_USEDEP}]
-"
-
-DOCS=( {CHANGES,README}.rst )
-
-src_prepare() {
-	# remove bundled dependencies, setuptools will switch to system deps
-	# automatically
-	rm -r */_vendor || die
-
-	# remove the ugly */extern hack that breaks on unvendored deps
-	rm -r */extern || die
-	find -name '*.py' -exec sed \
-		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
-		-i {} + || die
-
-	# apply distutils patches to the bundled distutils
-	pushd setuptools/_distutils >/dev/null || die
-	eapply -p3 "${WORKDIR}/${CPY_PATCHSET}/0006-distutils-make-OO-enable-both-opt-1-and-opt-2-optimi.patch"
-	popd >/dev/null || die
-
-	distutils-r1_src_prepare
-
-	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
-}
-
-python_test() {
-	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
-
-	# keep in sync with python_gen_cond_dep above!
-	has "${EPYTHON}" python3.{8..11} pypy3 || return
-
-	local EPYTEST_DESELECT=(
-		# network
-		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
-		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
-		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
-		setuptools/tests/test_distutils_adoption.py
-		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
-		setuptools/tests/test_virtualenv.py::test_clean_env_install
-		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
-		'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
-		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
-		# unhappy with pytest-xdist?
-		setuptools/tests/test_easy_install.py::TestUserInstallTest::test_local_index
-		# TODO
-		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
-		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
-		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
-		setuptools/tests/test_extern.py::test_distribution_picklable
-		setuptools/tests/test_test.py::test_tests_are_run_once
-		# expects bundled deps in virtualenv
-		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
-		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
-		setuptools/tests/test_editable_install.py::test_editable_with_pyproject
-	)
-
-	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
-	# It tries to sandbox the test in a tempdir
-	HOME="${PWD}" epytest \
-		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" setuptools
-}