[gentoo-commits] repo/gentoo:master commit in: games-strategy/tornado/

[Ionen Wolkens]

commit:     dd2c4782fed467879fc5f3a57f902c560920a136
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Sat Oct 16 13:56:40 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Oct 21 03:38:19 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dd2c4782

games-strategy/tornado: EAPI8 bump, minor improvements

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-strategy/tornado/tornado-1.4-r3.ebuild | 47 ++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/games-strategy/tornado/tornado-1.4-r3.ebuild b/games-strategy/tornado/tornado-1.4-r3.ebuild
new file mode 100644
index 00000000000..082cbe23940
--- /dev/null
+++ b/games-strategy/tornado/tornado-1.4-r3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Clone of a C64 game - destroy the opponent's house"
+HOMEPAGE="https://github.com/kouya/tornado"
+SRC_URI="https://github.com/kouya/tornado/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="
+	acct-group/gamestat
+	sys-libs/ncurses:=
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-r2-gentoo.patch
+)
+
+src_configure() {
+	if ! use nls; then
+		sed -i \
+			-e '/^all:/s|locales||g' \
+			-e '/^install:/s|install-locale-data||g' \
+			Makefile || die
+	fi
+
+	tc-export CC PKG_CONFIG
+}
+
+src_install() {
+	default
+
+	fowners :gamestat /usr/bin/${PN} /var/games/${PN}.scores
+	fperms g+s /usr/bin/${PN}
+	fperms 660 /var/games/${PN}.scores
+}