[gentoo-commits] repo/gentoo:master commit in: media-sound/pragha/

[Michał Górny]

commit:     a878666113abec1ca22c468f1873a40fb93c20a9
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Apr  5 16:52:46 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Apr  5 17:38:56 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a8786661

media-sound/pragha: Bump to 1.3.91

 media-sound/pragha/Manifest             |  1 +
 media-sound/pragha/metadata.xml         |  1 +
 media-sound/pragha/pragha-1.3.91.ebuild | 96 +++++++++++++++++++++++++++++++++
 3 files changed, 98 insertions(+)

diff --git a/media-sound/pragha/Manifest b/media-sound/pragha/Manifest
index 43c55511415..5fe0495a36e 100644
--- a/media-sound/pragha/Manifest
+++ b/media-sound/pragha/Manifest
@@ -1,2 +1,3 @@
 DIST pragha-1.3.3.tar.bz2 679754 BLAKE2B e9e785998d5ae805aa8427d18d1cbdcdd1e23224ce18b3927933c0986fd8793dec9457eedcb005be498b37940cc3c7e36e68940ccaa675f4b350931315c3d997 SHA512 3dc87d4e75cd9f145c3921af4c09140a705611d72176fd80db2d89048bc22c8edda5f87bce75f26e0cce4f6934c927e814e5c54fec7820116485cf4e04e876a9
 DIST pragha-1.3.90.tar.bz2 760153 BLAKE2B 22cb90225cad5b19ecd95691bafd11f55b35e5f2b59e877c2c998b2e4744f1298f28469bdb11f00598f31fc154c55427d000a995d952112b238cf84302993564 SHA512 877d27814927ab67a0b1defe70d753466e3ad14a0274a2168eb2521ded4eddeb04bce5177869b19ca57b38e7374047ee36982cce3f7e8a75b801cd060f8460d2
+DIST pragha-1.3.91.tar.bz2 740279 BLAKE2B c42f1b6d0c7071b56080d8feb8a11c9ba00b1339bc653a61cc80f09e1f076b2183091dbe2cbc42e7aa7347826492fa77cbbac980c25999ce3968a8e74dbc3623 SHA512 49b03ef69e7d12086e324a2088b4540eaebc01fd56247c43f069bd1b9fadbdd1b5f27af87b5086cc3e9a957281c3f7ff72c8ce3b0a6474514714a017ca5e0ab5

diff --git a/media-sound/pragha/metadata.xml b/media-sound/pragha/metadata.xml
index 965cbf1c844..230b2002c97 100644
--- a/media-sound/pragha/metadata.xml
+++ b/media-sound/pragha/metadata.xml
@@ -9,6 +9,7 @@
     <flag name="glyr">Enable music metadata searchengine support using <pkg>media-libs/glyr</pkg></flag>
     <flag name="grilo">Play songs on DLNA servers using <pkg>media-libs/grilo</pkg></flag>
     <flag name="keybinder">Enable shortcut support using <pkg>dev-libs/keybinder</pkg></flag>
+    <flag name="koel">Append music on Koel server</flag>
     <flag name="lastfm">Enable last.fm support using <pkg>media-libs/libclastfm</pkg></flag>
     <flag name="peas">Enable various plugins that will pull in <pkg>dev-libs/libpeas</pkg> as a dependency</flag>
     <flag name="playlist">Enable enhanced playlist support using <pkg>dev-libs/totem-pl-parser</pkg></flag>

diff --git a/media-sound/pragha/pragha-1.3.91.ebuild b/media-sound/pragha/pragha-1.3.91.ebuild
new file mode 100644
index 00000000000..eddc9428400
--- /dev/null
+++ b/media-sound/pragha/pragha-1.3.91.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="A lightweight music player (for Xfce)"
+HOMEPAGE="https://github.com/pragha-music-player/pragha"
+SRC_URI="https://github.com/pragha-music-player/${PN}/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cdda +glyr grilo +keybinder koel lastfm libnotify mtp +peas +playlist rygel soup +udev"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3=
+	>=dev-libs/glib-2.42:=
+	media-libs/gstreamer:1.0=
+	media-libs/gst-plugins-base:1.0=
+	>=media-libs/taglib-1.8:=
+	>=x11-libs/gtk+-3.14:3=
+	>=xfce-base/libxfce4ui-4.11:=[gtk3(+)]
+	cdda? ( >=dev-libs/libcdio-0.90:=
+		>=dev-libs/libcdio-paranoia-0.90:=
+		>=media-libs/libcddb-1.3.0:= )
+	glyr? ( >=media-libs/glyr-1.0.1:= )
+	grilo? ( media-libs/grilo:0.3=[network] )
+	keybinder? ( >=dev-libs/keybinder-0.2.0:3= )
+	koel? ( dev-libs/json-glib:= )
+	lastfm? ( >=media-libs/libclastfm-0.5:= )
+	libnotify? ( >=x11-libs/libnotify-0.7.5:= )
+	mtp? ( >=media-libs/libmtp-1.1.0:= )
+	peas? ( >=dev-libs/libpeas-1.0.0:=[gtk] )
+	playlist? ( >=dev-libs/totem-pl-parser-2.26:= )
+	rygel? ( >=net-misc/rygel-0.26:= )
+	soup? ( >=net-libs/libsoup-2.38:= )
+	udev? ( virtual/libgudev:= )"
+RDEPEND="${COMMON_DEPEND}
+	media-plugins/gst-plugins-meta:1.0"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	>=dev-util/xfce4-dev-tools-4.10
+	sys-devel/gettext
+	virtual/pkgconfig
+	xfce-base/exo"
+REQUIRED_USE="glyr? ( peas )
+	grilo? ( peas )
+	koel? ( soup )
+	libnotify? ( peas )
+	mtp? ( udev )
+	rygel? ( peas )
+	soup? ( peas )
+	udev? ( peas )"
+
+src_configure() {
+	local myconf=(
+		$(use_enable peas libpeas-1.0)
+		$(use_enable glyr libglyr)
+		$(use_enable lastfm libclastfm)
+		$(use_enable cdda libcdio)
+		$(use_enable cdda libcdio_paranoia)
+		$(use_enable cdda libcddb)
+		$(use_enable playlist totem-plparser)
+
+		$(use_enable libnotify)
+		$(use_enable keybinder)
+		$(use_enable udev gudev-1.0)
+		$(use_enable mtp libmtp)
+		$(use_enable koel json-glib-1.0)
+		$(use_enable soup libsoup-2.4)
+		$(use_enable rygel rygel-server-2.6)
+		$(use_enable grilo grilo-0.3)
+		$(use_enable grilo grilo-net-0.3)
+		# avoid trying to use 0.2 & 0.3 simultaneously
+		# https://github.com/pragha-music-player/pragha/issues/124
+		--disable-grilo-0.2
+		--disable-grilo-net-0.2
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}