[gentoo-commits] repo/gentoo:master commit in: media-sound/kid3/

[Andreas Sturmlechner]

commit:     cca93ac8b6ba77a484acabca72b5fba6dc0341f8
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Aug  8 11:33:14 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Aug  8 12:07:49 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cca93ac8

media-sound/kid3: add 3.9.2

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-sound/kid3/Manifest          |   1 +
 media-sound/kid3/kid3-3.9.2.ebuild | 100 +++++++++++++++++++++++++++++++++++++
 2 files changed, 101 insertions(+)

diff --git a/media-sound/kid3/Manifest b/media-sound/kid3/Manifest
index 817b4f59d871..5ac84b27b105 100644
--- a/media-sound/kid3/Manifest
+++ b/media-sound/kid3/Manifest
@@ -1 +1,2 @@
 DIST kid3-3.9.1.tar.xz 1796320 BLAKE2B 3404c6016a7d5195cc2e9826ef8daf452f5419566ffa9b50b20dd21072c0e34159e39bb8eeec08b7e12fe7f14df96517e929163ae4c14e28509cc51a0e96de08 SHA512 865fc2abfffd9533347ecfee037dfa15c6cedfc33ed0378b6d8dfef3436c6ec78c2100a317edf0882b16d345ea14b564cfb4055f74317634b4863ec477a80669
+DIST kid3-3.9.2.tar.xz 1952344 BLAKE2B 5a44a05f614f97dc7ddab39694a1773e1e6c55af7a9dc4ac7b793a520e54a8892c2181903a58f150885b3b4e17ebf921db719863f7ac4fd540f711a444990df3 SHA512 fc0b9db33ea948a2345968ab5da65f959bea829130f4250604d68df778218173d49f92b015d9be4e43f57ba5ae3388b0e97f558774df590b5959aa6f6293acd3

diff --git a/media-sound/kid3/kid3-3.9.2.ebuild b/media-sound/kid3/kid3-3.9.2.ebuild
new file mode 100644
index 000000000000..5e27fe36edd5
--- /dev/null
+++ b/media-sound/kid3/kid3-3.9.2.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit cmake kde.org python-any-r1 xdg
+
+DESCRIPTION="Simple tag editor based on Qt"
+HOMEPAGE="https://kid3.kde.org/"
+
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+"
+SLOT="5"
+IUSE="acoustid flac kde mp3 mp4 +mpris +taglib test vorbis"
+
+REQUIRED_USE="flac? ( vorbis )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-libs/readline:0=
+	acoustid? (
+		media-libs/chromaprint
+		media-video/ffmpeg
+	)
+	flac? (
+		media-libs/flac[cxx]
+		media-libs/libvorbis
+	)
+	kde? (
+		kde-frameworks/kconfig:5
+		kde-frameworks/kconfigwidgets:5
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+		kde-frameworks/kwidgetsaddons:5
+		kde-frameworks/kxmlgui:5
+	)
+	mp3? ( media-libs/id3lib )
+	mp4? ( media-libs/libmp4v2:0 )
+	mpris? ( dev-qt/qtdbus:5 )
+	taglib? ( >=media-libs/taglib-1.9.1 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="${PYTHON_DEPS}
+	dev-qt/linguist-tools:5
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# overengineered upstream build system
+	cmake_src_prepare
+	# applies broken python hacks, bug #614950
+	cmake_comment_add_subdirectory doc
+
+	sed -e "/^find_package.*QT NAMES/s/Qt6 //" \
+		-i CMakeLists.txt || die # ensure Qt5 build
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DWITH_CHROMAPRINT=$(usex acoustid)
+		-DWITH_DBUS=$(usex mpris)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_ID3LIB=$(usex mp3)
+		-DWITH_MP4V2=$(usex mp4)
+		-DWITH_TAGLIB=$(usex taglib)
+		-DBUILD_TESTING=$(usex test)
+		-DWITH_VORBIS=$(usex vorbis)
+	)
+
+	if use kde ; then
+		mycmakeargs+=( "-DWITH_APPS=KDE;CLI" )
+	else
+		mycmakeargs+=( "-DWITH_APPS=Qt;CLI" )
+	fi
+
+	cmake_src_configure
+}