[gentoo-commits] gentoo-x86 commit in x11-misc/synergy: ChangeLog synergy-1.4.2.ebuild

[Michael Weber (xmw)]

xmw         11/02/28 22:38:21

  Modified:             ChangeLog
  Added:                synergy-1.4.2.ebuild
  Log:
  Version bump (bug 354037) and support qsynergy (bug 234673)
  
  (Portage version: 2.1.9.41/cvs/Linux x86_64)

Revision  Changes    Path
1.66                 x11-misc/synergy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/synergy/ChangeLog?rev=1.66&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/synergy/ChangeLog?rev=1.66&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/synergy/ChangeLog?r1=1.65&r2=1.66

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/synergy/ChangeLog,v
retrieving revision 1.65
retrieving revision 1.66
diff -u -r1.65 -r1.66
--- ChangeLog	28 Feb 2011 20:35:32 -0000	1.65
+++ ChangeLog	28 Feb 2011 22:38:21 -0000	1.66
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/synergy
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/synergy/ChangeLog,v 1.65 2011/02/28 20:35:32 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/synergy/ChangeLog,v 1.66 2011/02/28 22:38:21 xmw Exp $
+
+*synergy-1.4.2 (28 Feb 2011)
+
+  28 Feb 2011; Michael Weber <xmw@g.o> +synergy-1.4.2.ebuild:
+  Version bump (bug 354037) and support qsynergy (bug 234673)
 
   28 Feb 2011; Michael Weber <xmw@g.o> synergy-1.3.6.ebuild:
   Added manpages



1.1                  x11-misc/synergy/synergy-1.4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/synergy/synergy-1.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/synergy/synergy-1.4.2.ebuild?rev=1.1&content-type=text/plain

Index: synergy-1.4.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/synergy/synergy-1.4.2.ebuild,v 1.1 2011/02/28 22:38:21 xmw Exp $

EAPI=3

inherit cmake-utils qt4-r2

DESCRIPTION="Lets you easily share a single mouse and keyboard between multiple computers."
HOMEPAGE="http://synergy-foss.org/"
SRC_URI="http://${PN}.googlecode.com/files/${P}-Source.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="qt4"

RDEPEND="x11-libs/libXtst
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXinerama
	qt4? ( x11-libs/qt-gui )"
DEPEND="${RDEPEND}
	x11-proto/xextproto
	x11-proto/xproto
	x11-proto/kbproto
	x11-proto/xineramaproto
	x11-libs/libXt"

S=${WORKDIR}/${P}-Source

src_configure() {
	cmake-utils_src_configure

	if use qt4 ; then
		cd gui
		qt4-r2_src_configure
	fi
}

src_compile() {
	cmake-utils_src_compile

	if use qt4 ; then
		cd gui
		qt4-r2_src_compile
	fi
}

src_install () {
	dobin "${CMAKE_BUILD_DIR}"/${PN}{c,s} || die

	if use qt4 ; then
		dobin bin/q${PN} || die
		insinto /usr/share/icons
		newins gui/res/win/QSynergy.ico q${PN}.ico
		make_desktop_entry q${PN} ${PN/s/S} q${PN} Utility;
	fi

	insinto /etc
	doins conf/synergy.conf || die

	mv doc/${PN}c.man  doc/${PN}c.1 || die
	mv doc/${PN}s.man  doc/${PN}s.1 || die
	doman doc/${PN}{c,s}.1 || die

	dodoc README doc/synergy.conf.example* || die
}