[gentoo-commits] repo/gentoo:master commit in: media-sound/snapcast/

[Joonas Niilola]

commit:     579442a51f8c2cb58250dbc0199d7e08b4eed4a9
Author:     Jakov Smolic <jakov.smolic <AT> sartura <DOT> hr>
AuthorDate: Mon Jul 19 18:50:36 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Jul 29 10:46:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=579442a5

media-sound/snapcast: Version bump to 0.25.0

* Drop USE=static-libs while at it

Signed-off-by: Jakov Smolic <jakov.smolic <AT> sartura.hr>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-sound/snapcast/Manifest               |  1 +
 media-sound/snapcast/snapcast-0.25.0.ebuild | 72 +++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/media-sound/snapcast/Manifest b/media-sound/snapcast/Manifest
index 0e56320be76..8a10ad86b3c 100644
--- a/media-sound/snapcast/Manifest
+++ b/media-sound/snapcast/Manifest
@@ -1 +1,2 @@
 DIST snapcast-0.20.0.tar.gz 729346 BLAKE2B 01a937b74d12f40717cec049e9af0c03f01cc957a97aa0c7316cac2c90f29d8a79dae99a0ae390b72e1a6ff8dce8e6134d40c83ac051641a97bbcd8df90ef64e SHA512 55542a5d915e359b4d8dcb69292dc8ee61067c5b35318151542d875b47a357b8713780ec03fb247ee424645457e68371499e84bae38fbb197737b1369dc7b622
+DIST snapcast-0.25.0.tar.gz 1412827 BLAKE2B 54d0c7b4fd20ec7d7ea414ed9915da9458c0875e5ca0277ba9c4d1415d50b0ef5940530ede3a09fe7d6bb94c7b17c7d0c6194105aa88a9719506f7494e79c723 SHA512 bc5e0540574f96a73971bae4b185a96f8ce0ca6619a51d9418368cf19f1e5b5248052a3a1e8922a15ba6b54dc8c3234c2f800fa2951fa5e97b9dd5610f78419d

diff --git a/media-sound/snapcast/snapcast-0.25.0.ebuild b/media-sound/snapcast/snapcast-0.25.0.ebuild
new file mode 100644
index 00000000000..b27a764a85c
--- /dev/null
+++ b/media-sound/snapcast/snapcast-0.25.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Synchronous multi-room audio player"
+HOMEPAGE="https://github.com/badaix/snapcast"
+SRC_URI="https://github.com/badaix/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+client +expat +flac +opus +server tremor +vorbis +zeroconf"
+REQUIRED_USE="|| ( server client )"
+
+RDEPEND="
+	client? (
+		acct-user/snapclient
+		media-libs/alsa-lib
+	)
+	expat? ( dev-libs/expat )
+	flac? ( media-libs/flac )
+	opus? ( media-libs/opus )
+	server? (
+		acct-group/snapserver
+		acct-user/snapserver
+	)
+	tremor? ( media-libs/tremor )
+	vorbis? ( media-libs/libvorbis )
+	zeroconf? ( net-dns/avahi[dbus] )
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-cpp/aixlog-1.2.1
+	>=dev-cpp/asio-1.12.1
+	>=dev-cpp/popl-1.2.0
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.20.0-gcc-11.patch )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLIENT=$(usex client)
+		-DBUILD_WITH_EXPAT=$(usex expat)
+		-DBUILD_WITH_FLAC=$(usex flac)
+		-DBUILD_WITH_OPUS=$(usex opus)
+		-DBUILD_SERVER=$(usex server)
+		-DBUILD_STATIC_LIBS=no
+		-DBUILD_TESTS=no
+		-DBUILD_WITH_TREMOR=$(usex tremor)
+		-DBUILD_WITH_VORBIS=$(usex vorbis)
+		-DBUILD_WITH_AVAHI=$(usex zeroconf)
+		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	for bin in server client ; do
+		if use ${bin} ; then
+			doman "${bin}/snap${bin}.1"
+
+			newconfd "${FILESDIR}/snap${bin}.confd" "snap${bin}"
+			newinitd "${FILESDIR}/snap${bin}.initd" "snap${bin}"
+		fi
+	done
+}