[gentoo-commits] gentoo-x86 commit in app-editors/nano: ChangeLog nano-2.1.11.ebuild

[Mike Frysinger (vapier)]

vapier      09/11/02 22:58:24

  Modified:             ChangeLog
  Added:                nano-2.1.11.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc46/cvs/Linux x86_64)

Revision  Changes    Path
1.242                app-editors/nano/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.242&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.242&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?r1=1.241&r2=1.242

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v
retrieving revision 1.241
retrieving revision 1.242
diff -u -r1.241 -r1.242
--- ChangeLog	31 Oct 2009 14:42:29 -0000	1.241
+++ ChangeLog	2 Nov 2009 22:58:23 -0000	1.242
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.241 2009/10/31 14:42:29 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.242 2009/11/02 22:58:23 vapier Exp $
+
+*nano-2.1.11 (02 Nov 2009)
+
+  02 Nov 2009; Mike Frysinger <vapier@g.o> +nano-2.1.11.ebuild,
+  +files/nano-2.1.11-proto.patch:
+  Version bump.
 
   31 Oct 2009; Brent Baude <ranger@g.o> nano-2.1.10.ebuild:
   Marking nano-2.1.10 ppc64 for bug 287407



1.1                  app-editors/nano/nano-2.1.11.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.1.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.1.11.ebuild?rev=1.1&content-type=text/plain

Index: nano-2.1.11.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.1.11.ebuild,v 1.1 2009/11/02 22:58:23 vapier Exp $

EAPI=2
inherit eutils
if [[ ${PV} == "9999" ]] ; then
	ESVN_REPO_URI="svn://svn.savannah.gnu.org/nano/trunk/nano"
	inherit subversion
else
	MY_P=${PN}-${PV/_}
	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
fi

DESCRIPTION="GNU GPL'd Pico clone with more functionality"
HOMEPAGE="http://www.nano-editor.org/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="debug justify minimal ncurses nls slang spell unicode"

DEPEND=">=sys-libs/ncurses-5.2[unicode?]
	nls? ( sys-devel/gettext )
	!ncurses? ( slang? ( sys-libs/slang ) )"

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		subversion_src_unpack
	else
		unpack ${A}
	fi
	cd "${S}"
	epatch "${FILESDIR}"/${P}-proto.patch
	if [[ ! -e configure ]] ; then
		./autogen.sh || die "autogen failed"
	fi
}

src_configure() {
	local myconf=""
	use ncurses \
		&& myconf="--without-slang" \
		|| myconf="${myconf} $(use_with slang)"

	econf \
		--bindir=/bin \
		$(use_enable !minimal color) \
		$(use_enable !minimal multibuffer) \
		$(use_enable !minimal nanorc) \
		--disable-wrapping-as-root \
		$(use_enable spell speller) \
		$(use_enable justify) \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_enable unicode utf8) \
		$(use_enable minimal tiny) \
		${myconf} \
		|| die "configure failed"
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
	dohtml doc/faq.html
	insinto /etc
	newins doc/nanorc.sample nanorc

	dodir /usr/bin
	dosym /bin/nano /usr/bin/nano

	insinto /usr/share/nano
	local f
	for f in "${FILESDIR}"/*.nanorc ; do
		[[ -e ${D}/usr/share/nano/${f##*/} ]] && continue
		doins "${f}" || die
		echo "# include \"/usr/share/nano/${f##*/}\"" >> "${D}"/etc/nanorc
	done
}

pkg_postinst() {
	einfo "More helpful info about nano, visit the GDP page:"
	einfo "http://www.gentoo.org/doc/en/nano-basics-guide.xml"
}