[gentoo-commits] gentoo-x86 commit in gnome-extra/yelp: ChangeLog yelp-2.30.2.ebuild

[Gilles Dartiguelongue (eva)]

eva         10/09/29 21:17:22

  Modified:             ChangeLog
  Added:                yelp-2.30.2.ebuild
  Log:
  Version bump. Include patches from r1, plus i18n updates.
  
  (Portage version: 2.2_rc88/cvs/Linux x86_64)

Revision  Changes    Path
1.243                gnome-extra/yelp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/yelp/ChangeLog?rev=1.243&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/yelp/ChangeLog?rev=1.243&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/yelp/ChangeLog?r1=1.242&r2=1.243

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/yelp/ChangeLog,v
retrieving revision 1.242
retrieving revision 1.243
diff -u -r1.242 -r1.243
--- ChangeLog	11 Sep 2010 18:52:26 -0000	1.242
+++ ChangeLog	29 Sep 2010 21:17:22 -0000	1.243
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-extra/yelp
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/yelp/ChangeLog,v 1.242 2010/09/11 18:52:26 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/yelp/ChangeLog,v 1.243 2010/09/29 21:17:22 eva Exp $
+
+*yelp-2.30.2 (29 Sep 2010)
+
+  29 Sep 2010; Gilles Dartiguelongue <eva@g.o> +yelp-2.30.2.ebuild:
+  Version bump. Include patches from r1, plus i18n updates.
 
   11 Sep 2010; Joseph Jezak <josejx@g.o> yelp-2.30.1-r1.ebuild:
   Marked ppc for bug #324077.



1.1                  gnome-extra/yelp/yelp-2.30.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/yelp/yelp-2.30.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/yelp/yelp-2.30.2.ebuild?rev=1.1&content-type=text/plain

Index: yelp-2.30.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/yelp/yelp-2.30.2.ebuild,v 1.1 2010/09/29 21:17:22 eva Exp $

EAPI="2"

inherit autotools eutils gnome2

DESCRIPTION="Help browser for GNOME"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
IUSE="beagle lzma"

RDEPEND=">=gnome-base/gconf-2
	>=app-text/gnome-doc-utils-0.19.1
	>=x11-libs/gtk+-2.18
	>=dev-libs/glib-2.16
	>=dev-libs/libxml2-2.6.5
	>=dev-libs/libxslt-1.1.4
	>=x11-libs/startup-notification-0.8
	>=dev-libs/dbus-glib-0.71
	beagle? ( || (
		>=dev-libs/libbeagle-0.3.0
		=app-misc/beagle-0.2* ) )
	net-libs/xulrunner:1.9
	sys-libs/zlib
	app-arch/bzip2
	lzma? ( || (
		app-arch/xz-utils
		app-arch/lzma-utils ) )
	>=app-text/rarian-0.7
	>=app-text/scrollkeeper-9999"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.9
	gnome-base/gnome-common"
# If eautoreconf:
#	gnome-base/gnome-common

DOCS="AUTHORS ChangeLog NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		--with-gecko=libxul-embedding
		$(use_enable lzma)"

	if use beagle; then
		G2CONF="${G2CONF} --with-search=beagle"
	else
		G2CONF="${G2CONF} --with-search=basic"
	fi
}

src_prepare() {
	gnome2_src_prepare

	# Fix automagic lzma support, bug #266128
	epatch "${FILESDIR}/${PN}-2.26.0-automagic-lzma.patch"

	# Fix build with xulrunner-1.9.2
	epatch "${FILESDIR}/${PN}-2.28.1-system-nspr.patch"

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf

	# strip stupid options in configure, see bug #196621
	sed -i 's|$AM_CFLAGS -pedantic -ansi|$AM_CFLAGS|' configure || die "sed	failed"
}