[gentoo-commits] gentoo-x86 commit in kde-base/kdm: metadata.xml ChangeLog kdm-4.2.0.ebuild

[Alexey Shvetsov (alexxy)]

alexxy      09/01/27 17:06:47

  Modified:             metadata.xml ChangeLog
  Added:                kdm-4.2.0.ebuild
  Log:
  Bump shiny new KDE 4.2.0
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  kde-base/kdm/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kdm/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	5 Apr 2005 16:04:39 -0000	1.2
+++ metadata.xml	27 Jan 2009 17:06:47 -0000	1.3
@@ -2,4 +2,7 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>kde</herd>
+<use>
+	<flag name="consolekit">Enables support for authorization using consolekit</flag>
+</use>
 </pkgmetadata>



1.146                kde-base/kdm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/ChangeLog?rev=1.146&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/ChangeLog?rev=1.146&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/ChangeLog?r1=1.145&r2=1.146

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kdm/ChangeLog,v
retrieving revision 1.145
retrieving revision 1.146
diff -u -r1.145 -r1.146
--- ChangeLog	14 Jan 2009 14:50:14 -0000	1.145
+++ ChangeLog	27 Jan 2009 17:06:47 -0000	1.146
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdm
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdm/ChangeLog,v 1.145 2009/01/14 14:50:14 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdm/ChangeLog,v 1.146 2009/01/27 17:06:47 alexxy Exp $
+
+*kdm-4.2.0 (27 Jan 2009)
+
+  27 Jan 2009; Alexey Shvetsov <alexxy@g.o> +kdm-4.2.0.ebuild:
+  Bump KDE-4.2.0
 
   14 Jan 2009; Alexey Shvetsov <alexxy@g.o> -kdm-4.1.2.ebuild,
   -kdm-4.1.3.ebuild:



1.1                  kde-base/kdm/kdm-4.2.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/kdm-4.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdm/kdm-4.2.0.ebuild?rev=1.1&content-type=text/plain

Index: kdm-4.2.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kdm/kdm-4.2.0.ebuild,v 1.1 2009/01/27 17:06:47 alexxy Exp $

EAPI="2"

KMNAME="kdebase-workspace"
inherit kde4-meta

DESCRIPTION="KDE login manager, similar to xdm and gdm"
KEYWORDS="~amd64 ~x86"
IUSE="consolekit debug htmlhandbook kerberos pam"

DEPEND="x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXtst
	kerberos? ( virtual/krb5 )
	pam? (
		>=kde-base/kcheckpass-${PV}:${SLOT}
		sys-libs/pam
	)
	consolekit? (
		>=sys-apps/dbus-1.0.2
		sys-auth/consolekit
	)"
RDEPEND="${DEPEND}
	>=kde-base/kdepasswd-${PV}:${SLOT}
	>=x11-apps/xinit-1.0.5-r2
	x11-apps/xmessage"

KMEXTRACTONLY="kcontrol/kdm/"
KMEXTRA="libs/kdm/"

PATCHES=("${FILESDIR}/kdebase-4.0.2-pam-optional.patch")

src_configure() {
	mycmakeargs="${mycmakeargs}
		$(use kerberos && echo "-DKDE4_KRB5AUTH=ON" || echo "-DKDE4_KRB5AUTH=OFF")
		$(cmake-utils_use_with pam PAM)
		$(cmake-utils_use_with consolekit CkConnector)"

	kde4-meta_src_configure
}

src_install() {
	export GENKDMCONF_FLAGS="--no-old --no-backup"

	kde4-meta_src_install

	# Customize the kdmrc configuration
	sed -i -e "s:^.*SessionsDirs=.*$:#&\nSessionsDirs=/usr/share/xsessions:" \
		"${D}"/${PREFIX}/share/config/kdm/kdmrc \
		|| die "Failed to set SessionsDirs correctly."

	# Don't install empty dir
	rmdir "${D}${KDEDIR}"/share/config/kdm/sessions
}

pkg_postinst() {
	kde4-meta_pkg_postinst

	# Set the default kdm face icon if it's not already set by the system admin
	# because this is user-overrideable in that way, it's not in src_install
	if [[ ! -e "${ROOT}${KDEDIR}/share/apps/kdm/faces/.default.face.icon" ]];	then
		mkdir -p "${ROOT}${KDEDIR}/share/apps/kdm/faces"
		cp "${ROOT}${KDEDIR}/share/apps/kdm/pics/users/default1.png" \
			"${ROOT}${KDEDIR}/share/apps/kdm/faces/.default.face.icon"
	fi
	if [[ ! -e "${ROOT}${KDEDIR}/share/apps/kdm/faces/root.face.icon" ]]; then
		mkdir -p "${ROOT}${KDEDIR}/share/apps/kdm/faces"
		cp "${ROOT}${KDEDIR}/share/apps/kdm/pics/users/root1.png" \
			"${ROOT}${KDEDIR}/share/apps/kdm/faces/root.face.icon"
	fi

	if use consolekit; then
		echo
		elog "You have compiled 'kdm' with consolekit support. If you want to use kdm,"
		elog "make sure consolekit daemon is running and started at login time"
		elog
		elog "rc-update add consolekit default && /etc/init.d/consolekit start"
		echo
	fi
}