[gentoo-commits] gentoo-x86 commit in dev-util/debhelper: ChangeLog debhelper-9.20131127.ebuild

[Jeroen Roovers (jer)]

jer         13/11/28 11:42:58

  Modified:             ChangeLog
  Added:                debhelper-9.20131127.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.95                 dev-util/debhelper/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/ChangeLog?rev=1.95&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/ChangeLog?rev=1.95&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/ChangeLog?r1=1.94&r2=1.95

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v
retrieving revision 1.94
retrieving revision 1.95
diff -u -r1.94 -r1.95
--- ChangeLog	10 Nov 2013 23:10:07 -0000	1.94
+++ ChangeLog	28 Nov 2013 11:42:58 -0000	1.95
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/debhelper
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v 1.94 2013/11/10 23:10:07 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v 1.95 2013/11/28 11:42:58 jer Exp $
+
+*debhelper-9.20131127 (28 Nov 2013)
+
+  28 Nov 2013; Jeroen Roovers <jer@g.o> +debhelper-9.20131127.ebuild:
+  Version bump.
 
 *debhelper-9.20131110 (10 Nov 2013)
 



1.1                  dev-util/debhelper/debhelper-9.20131127.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/debhelper-9.20131127.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/debhelper-9.20131127.ebuild?rev=1.1&content-type=text/plain

Index: debhelper-9.20131127.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/debhelper-9.20131127.ebuild,v 1.1 2013/11/28 11:42:58 jer Exp $

EAPI=5
inherit eutils toolchain-funcs

DESCRIPTION="Collection of programs that can be used to automate common tasks in debian/rules"
HOMEPAGE="http://packages.qa.debian.org/d/debhelper.html http://joeyh.name/code/debhelper/"
SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux"
IUSE="test"
DH_LINGUAS=( de es fr )
IUSE+=" ${DH_LINGUAS[@]/#/linguas_}"

NLS_DEPEND=$(
	printf "linguas_%s? ( >=app-text/po4a-0.24 )\n" ${DH_LINGUAS[@]}
)

RDEPEND="
	>=dev-lang/perl-5.10
	app-arch/dpkg
	dev-perl/TimeDate
	virtual/perl-Getopt-Long
"
DEPEND="${RDEPEND}
	${NLS_DEPEND}
	test? ( dev-perl/Test-Pod )
"

S=${WORKDIR}/${PN}

src_compile() {
	tc-export CC

	local LANGS="" USE_NLS=no lingua
	for lingua in ${DH_LINGUAS[@]}; do
		if use linguas_${lingua}; then
			LANGS+=" ${lingua}"
			USE_NLS=yes
		fi
	done

	emake USE_NLS="${USE_NLS}" LANGS="${LANGS}" build
}

src_install() {
	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
	dodoc doc/* debian/changelog
	docinto examples
	dodoc examples/*
	local lingua
	for manfile in *.1 *.7 ; do
		for lingua in ${DH_LINGUAS[@]}; do
			case ${manfile} in
				*.${lingua}.?)
					use linguas_${lingua} \
						&& cp ${manfile} "${T}"/${manfile/.${lingua}/} \
						&& doman -i18n=${lingua} "${T}"/${manfile/.${lingua}/}
					;;
				*)
					doman ${manfile}
					;;
			esac
		done
	done
}