[gentoo-commits] gentoo-x86 commit in app-arch/libarchive: ChangeLog libarchive-2.4.4.ebuild

[Samuli Suominen (drac)]

drac        07/12/04 16:24:54

  Modified:             ChangeLog
  Added:                libarchive-2.4.4.ebuild
  Log:
  Version bump, thanks to Tim Kientzle <kientzle at freebsd.org> for applying our patch fixing automagic acl and xattr. This version also fixes most of the test suite.
  (Portage version: 2.1.4_rc4)

Revision  Changes    Path
1.9                  app-arch/libarchive/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	3 Dec 2007 15:43:16 -0000	1.8
+++ ChangeLog	4 Dec 2007 16:24:53 -0000	1.9
@@ -1,6 +1,13 @@
 # ChangeLog for app-arch/libarchive
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.8 2007/12/03 15:43:16 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.9 2007/12/04 16:24:53 drac Exp $
+
+*libarchive-2.4.4 (04 Dec 2007)
+
+  04 Dec 2007; Samuli Suominen <drac@g.o> +libarchive-2.4.4.ebuild:
+  Version bump, thanks to Tim Kientzle <kientzle at freebsd.org> for applying
+  our patch fixing automagic acl and xattr. This version also fixes most of
+  the test suite.
 
 *libarchive-2.4.2 (03 Dec 2007)
 



1.1                  app-arch/libarchive/libarchive-2.4.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.4.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.4.4.ebuild?rev=1.1&content-type=text/plain

Index: libarchive-2.4.4.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/libarchive-2.4.4.ebuild,v 1.1 2007/12/04 16:24:53 drac Exp $

inherit eutils libtool toolchain-funcs

DESCRIPTION="BSD tar command"
HOMEPAGE="http://people.freebsd.org/~kientzle/libarchive"
SRC_URI="http://people.freebsd.org/~kientzle/libarchive/src/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="build static acl xattr kernel_linux"

RDEPEND="!dev-libs/libarchive
	kernel_linux? (
		acl? ( sys-apps/acl )
		xattr? ( sys-apps/attr )
	)
	!static? ( !build? (
		app-arch/bzip2
		sys-libs/zlib ) )"
DEPEND="${RDEPEND}
	kernel_linux? ( sys-fs/e2fsprogs
		virtual/os-headers )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	elibtoolize
	epunt_cxx
}

src_compile() {
	local myconf

	if ! use static && ! use build ; then
		myconf="--enable-bsdtar=shared --enable-bsdcpio=shared"
	fi

	econf --bindir=/bin --enable-bsdcpio \
		$(use_enable acl) $(use_enable xattr) \
		${myconf} || die "econf failed."

	emake || die "emake failed."
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "emake install failed."

	# Create tar symlink for FreeBSD
	if [[ ${CHOST} == *-freebsd* ]]; then
		dosym bsdtar /bin/tar
		dosym bsdtar.1 /usr/share/man/man1/tar.1
		# We may wish to switch to symlink bsdcpio to cpio too one day
	fi

	dodoc NEWS README

	if use build; then
		rm -rf "${D}"/usr
		rm -rf "${D}"/lib/*.so*
		return 0
	fi

	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)
	gen_usr_ldscript libarchive.so
}



-- 
gentoo-commits@g.o mailing list