[gentoo-commits] gentoo-x86 commit in kde-base/gwenview: gwenview-4.12.4.ebuild ChangeLog

[Johannes Huber (johu)]

johu        14/04/01 18:09:18

  Modified:             ChangeLog
  Added:                gwenview-4.12.4.ebuild
  Log:
  Version bump KDE SC 4.12.4
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.225                kde-base/gwenview/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?rev=1.225&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?rev=1.225&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?r1=1.224&r2=1.225

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v
retrieving revision 1.224
retrieving revision 1.225
diff -u -r1.224 -r1.225
--- ChangeLog	11 Mar 2014 13:07:09 -0000	1.224
+++ ChangeLog	1 Apr 2014 18:09:18 -0000	1.225
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/gwenview
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v 1.224 2014/03/11 13:07:09 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v 1.225 2014/04/01 18:09:18 johu Exp $
+
+*gwenview-4.12.4 (01 Apr 2014)
+
+  01 Apr 2014; Johannes Huber <johu@g.o> +gwenview-4.12.4.ebuild:
+  Version bump KDE SC 4.12.4
 
   11 Mar 2014; Johannes Huber <johu@g.o> -gwenview-4.12.2.ebuild:
   Remove KDE SC 4.12.2



1.1                  kde-base/gwenview/gwenview-4.12.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/gwenview-4.12.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/gwenview-4.12.4.ebuild?rev=1.1&content-type=text/plain

Index: gwenview-4.12.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/gwenview-4.12.4.ebuild,v 1.1 2014/04/01 18:09:18 johu Exp $

EAPI=5

KDE_HANDBOOK="optional"
OPENGL_REQUIRED="always"
inherit kde4-base

DESCRIPTION="KDE image viewer"
HOMEPAGE="
	http://www.kde.org/applications/graphics/gwenview/
	http://gwenview.sourceforge.net/
"
KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug kipi semantic-desktop"

# tests fail, last checked 4.11.0
RESTRICT="test"

DEPEND="
	$(add_kdebase_dep kdelibs 'semantic-desktop?')
	$(add_kdebase_dep libkonq)
	$(add_kdebase_dep kactivities)
	media-gfx/exiv2:=
	media-libs/lcms:2
	media-libs/libpng:0=
	virtual/jpeg:0
	x11-libs/libX11
	kipi? ( $(add_kdebase_dep libkipi) )
	semantic-desktop? ( $(add_kdebase_dep nepomuk-core) )
"
RDEPEND="${DEPEND}"

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with semantic-desktop Soprano)
		$(cmake-utils_use_with kipi)
	)
	# Workaround for bug #479510
	if [[ -e ${EPREFIX}/usr/include/${CHOST}/jconfig.h ]]; then
		mycmakeargs+=( -DJCONFIG_H="${EPREFIX}/usr/include/${CHOST}/jconfig.h" )
	fi

	if use semantic-desktop; then
		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=Nepomuk)
	else
		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=None)
	fi

	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if ! has_version kde-base/svgpart:${SLOT} ; then
		elog "For SVG support, install kde-base/svgpart:${SLOT}"
	fi

	if use kipi && ! has_version media-plugins/kipi-plugins ; then
		elog "The plugins for the KIPI inteface can be found in media-plugins/kipi-plugins"
	fi
}