[gentoo-commits] gentoo-x86 commit in net-im/pyicq-t: ChangeLog pyicq-t-0.8.1.5.ebuild

[Maurice van der Pot (griffon26)]

griffon26    09/08/26 19:16:57

  Modified:             ChangeLog
  Added:                pyicq-t-0.8.1.5.ebuild
  Log:
  Bump pyicq-t to version 0.8.1.5 (bug #282717)
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 net-im/pyicq-t/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pyicq-t/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pyicq-t/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pyicq-t/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/pyicq-t/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	18 Aug 2009 16:14:30 -0000	1.15
+++ ChangeLog	26 Aug 2009 19:16:56 -0000	1.16
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/pyicq-t
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/pyicq-t/ChangeLog,v 1.15 2009/08/18 16:14:30 griffon26 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/pyicq-t/ChangeLog,v 1.16 2009/08/26 19:16:56 griffon26 Exp $
+
+*pyicq-t-0.8.1.5 (26 Aug 2009)
+
+  26 Aug 2009; Maurice van der Pot <griffon26@g.o>
+  +pyicq-t-0.8.1.5.ebuild:
+  Version bump because of memory leak in 0.8.1.4.
 
 *pyicq-t-0.8.1.4 (18 Aug 2009)
 



1.1                  net-im/pyicq-t/pyicq-t-0.8.1.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pyicq-t/pyicq-t-0.8.1.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pyicq-t/pyicq-t-0.8.1.5.ebuild?rev=1.1&content-type=text/plain

Index: pyicq-t-0.8.1.5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/pyicq-t/pyicq-t-0.8.1.5.ebuild,v 1.1 2009/08/26 19:16:56 griffon26 Exp $

NEED_PYTHON=2.3

inherit eutils multilib python

MY_P="${P/pyicq-t/pyicqt}"

DESCRIPTION="Python based jabber transport for ICQ"
HOMEPAGE="http://code.google.com/p/pyicqt/"
SRC_URI="http://pyicqt.googlecode.com/files/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="webinterface"

DEPEND="net-im/jabber-base"
RDEPEND="${DEPEND}
	>=dev-python/twisted-2.2.0
	>=dev-python/twisted-words-0.1.0
	>=dev-python/twisted-web-0.5.0
	webinterface? ( >=dev-python/nevow-0.4.1 )
	>=dev-python/imaging-1.1"

src_install() {
	local inspath

	python_version
	inspath=/usr/$(get_libdir)/python${PYVER}/site-packages/${PN}
	insinto ${inspath}
	doins -r data src tools
	newins PyICQt.py ${PN}.py

	insinto /etc/jabber
	newins config_example.xml ${PN}.xml
	fperms 600 /etc/jabber/${PN}.xml
	fowners jabber:jabber /etc/jabber/${PN}.xml
	dosed \
		"s:<spooldir>[^\<]*</spooldir>:<spooldir>/var/spool/jabber</spooldir>:" \
		/etc/jabber/${PN}.xml
	dosed \
		"s:<pid>[^\<]*</pid>:<pid>/var/run/jabber/${PN}.pid</pid>:" \
		/etc/jabber/${PN}.xml

	newinitd "${FILESDIR}/${PN}-0.8-initd" ${PN}
	dosed "s:INSPATH:${inspath}:" /etc/init.d/${PN}
}

pkg_postinst() {
	python_version
	python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/${PN}

	elog "A sample configuration file has been installed in /etc/jabber/${PN}.xml."
	elog "Please edit it and the configuration of your Jabber server to match."

	ewarn "If you are storing user accounts in MySQL and are upgrading from a "
	ewarn "version older than 0.8.1, then you will need to run the following "
	ewarn "command to create some new tables:"
	ewarn "	 mysql -u user_name -p pyicqt < /usr/$(get_libdir)/python${PYVER}/site-packages/${PN}/tools/db-setup.mysql"

	elog  "These instructions along with a list of new config variables are "
	elog  "available at: http://code.google.com/p/pyicqt/wiki/Upgrade"
}

pkg_postrm() {
	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/${PN}
}