[gentoo-commits] gentoo-x86 commit in games-sports/vdrift: ChangeLog vdrift-20090615.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    09/07/31 02:51:17

  Modified:             ChangeLog
  Added:                vdrift-20090615.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.11                 games-sports/vdrift/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/vdrift/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/vdrift/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/vdrift/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-sports/vdrift/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	1 Jun 2009 13:03:39 -0000	1.10
+++ ChangeLog	31 Jul 2009 02:51:16 -0000	1.11
@@ -1,6 +1,12 @@
 # ChangeLog for games-sports/vdrift
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-sports/vdrift/ChangeLog,v 1.10 2009/06/01 13:03:39 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-sports/vdrift/ChangeLog,v 1.11 2009/07/31 02:51:16 mr_bones_ Exp $
+
+*vdrift-20090615 (31 Jul 2009)
+
+  31 Jul 2009; Michael Sterrett <mr_bones_@g.o>
+  +vdrift-20090615.ebuild:
+  version bump
 
   01 Jun 2009; Markus Meier <maekke@g.o> vdrift-20090215.ebuild:
   amd64/x86 stable, bug #272048



1.1                  games-sports/vdrift/vdrift-20090615.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/vdrift/vdrift-20090615.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/vdrift/vdrift-20090615.ebuild?rev=1.1&content-type=text/plain

Index: vdrift-20090615.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-sports/vdrift/vdrift-20090615.ebuild,v 1.1 2009/07/31 02:51:16 mr_bones_ Exp $

EAPI=2
inherit eutils games

MY_P=${PN}-${PV:0:4}-${PV:4:2}-${PV:6}
DESCRIPTION="A driving simulation made with drift racing in mind"
HOMEPAGE="http://vdrift.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}-src.tar.bz2"

LICENSE="GPL-2 ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls"

RDEPEND="virtual/opengl
	virtual/glu
	media-libs/glew
	media-libs/libsdl[opengl,video]
	media-libs/openal
	media-libs/sdl-gfx
	media-libs/sdl-image[png]
	media-libs/sdl-net
	media-libs/libvorbis
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	dev-cpp/asio
	dev-util/scons
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${PN}-${PV:0:4}-${PV:4:2}-${PV:6:2}

src_prepare() {
	sed -i \
		-e "s/'-O1',\?//" \
		SConstruct \
		|| die "sed failed"
}

src_compile() {
	local sconsopts=$(echo "${MAKEOPTS}" | sed -ne "/-j/ { s/.*\(-j[0-9]\+\).*/\1/; p }")

	scons \
		${sconsopts} \
		NLS=$(use nls && echo 1 || echo 0) \
		destdir="${D}" \
		bindir="${GAMES_BINDIR}" \
		datadir="${GAMES_DATADIR}"/${PN} \
		localedir=/usr/share/locale \
		prefix= \
		use_binreloc=0 \
		release=1 \
		os_cc=1 \
		os_cxx=1 \
		os_cxxflags=1 \
		|| die "scons failed"
}

src_install() {
	dogamesbin build/vdrift || die "dogamesbin failed"
	insinto "${GAMES_DATADIR}/${PN}"
	doins -r data/* || die "doins failed"
	newicon data/textures/icons/vdrift-64x64.png ${PN}.png
	make_desktop_entry ${PN} VDrift
	dodoc docs/*
	find "${D}" -name "SCon*" -exec rm \{\} +
	cd "${D}"
	keepdir $(find "${GAMES_DATADIR/\//}/${PN}" -type d -empty)
	prepgamesdirs
}