[gentoo-commits] repo/gentoo:master commit in: dev-python/sphinx/

[Michał Górny]

commit:     031410bb1ea4376f5ed19fd8ac3e242001e14d41
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 12 22:54:48 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jul 12 22:56:01 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=031410bb

dev-python/sphinx: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/sphinx/Manifest            |   1 -
 dev-python/sphinx/sphinx-4.0.2.ebuild | 131 ----------------------------------
 2 files changed, 132 deletions(-)

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 41739bd3533..dbbe37102cb 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,4 +1,3 @@
 DIST Sphinx-3.5.4.tar.gz 5911093 BLAKE2B 8740714dfaf3733bf57d0b277315b4e7b5cad86247ea30dcbc4f5dadf5f5169329050b7be43ec8625c47df9dcc19afcc6c4d782725c7007f8178b7eb7be7dc05 SHA512 853379f3b0496772846be9beb072c2c8a69ff899ffe4c6435b448ea639a32138c61403f9c14f62f4f78b2e526a2ee7c05b4196eabdeee37bcae6aa98df992125
-DIST Sphinx-4.0.2.tar.gz 6162889 BLAKE2B c0309ca6752a76c11b5071d3ee368e80499bf68ca51a7f396be10d15b9bf9b03f85de3fef2b4e3c4795de99efa78af42a5b95b00d1f737952e6775631e63128a SHA512 836727258a83d38430de4f6073f637ec3c6c813707701b96c9ec58e35648fd1eb9af1c7c5da17dd95b63914fafcb9e25668129514701c5fdd3f49f7303c3f8ec
 DIST Sphinx-4.0.3.tar.gz 6164298 BLAKE2B 60726ed4cc4f92910bcfff20dde09beef89e4c171b6f12a327e981df8fa6569a901c0b8e994cd66263b87056548f9f966a2e3049341447ad28797bf120a42a70 SHA512 8dd561b220779efb4cf779f46b342a298f18bfeb7670e0485ba8fcae7a03b2bd30368b441237ed597e1d8f001e35bae13a7d4d44d6921a4fa1b8a7804a5850c7
 DIST Sphinx-4.1.0.tar.gz 6302885 BLAKE2B 7e2eafa236173c0fe7d761d1692ff8bb0c12ad8fae2894e2088fff0415d085a3ea652c59d4efc94788829c4261cbee161d85a5c35d6a282fb1a201f658425bb7 SHA512 482378b85b51e74bc2c841bc5ac7b7d5a0034b28e62d36182972439a1e48ce5faaa82e6c3daa35ff6a3f1b1ed1c4187564c77806e6d1804dae0f2c24262adbe6

diff --git a/dev-python/sphinx/sphinx-4.0.2.ebuild b/dev-python/sphinx/sphinx-4.0.2.ebuild
deleted file mode 100644
index 7cc217f2e35..00000000000
--- a/dev-python/sphinx/sphinx-4.0.2.ebuild
+++ /dev/null
@@ -1,131 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DISTUTILS_USE_SETUPTOOLS=rdepend
-PYTHON_COMPAT=( python3_{7..10} pypy3 )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1
-
-DESCRIPTION="Python documentation generator"
-HOMEPAGE="https://www.sphinx-doc.org/
-	https://github.com/sphinx-doc/sphinx"
-SRC_URI="mirror://pypi/S/${PN^}/${P^}.tar.gz"
-S=${WORKDIR}/${P^}
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
-IUSE="doc latex"
-
-RDEPEND="
-	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
-	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
-	dev-python/docutils[${PYTHON_USEDEP}]
-	dev-python/imagesize[${PYTHON_USEDEP}]
-	>=dev-python/jinja-2.3[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
-	>=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
-	>=dev-python/snowballstemmer-1.1[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-htmlhelp[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-serializinghtml[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		dev-python/typed-ast[${PYTHON_USEDEP}]
-	' python3_7)
-	latex? (
-		dev-texlive/texlive-latexextra
-		dev-texlive/texlive-luatex
-		app-text/dvipng
-	)"
-BDEPEND="
-	doc? (
-		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
-		media-gfx/graphviz
-	)
-	test? (
-		dev-python/html5lib[${PYTHON_USEDEP}]
-		virtual/imagemagick-tools[jpeg,png,svg]
-		dev-texlive/texlive-fontsextra
-		dev-texlive/texlive-latexextra
-		dev-texlive/texlive-luatex
-		app-text/dvipng
-	)"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-3.2.1-doc-link.patch"
-	"${FILESDIR}/${P}-py310.patch"
-)
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	# disable internet access
-	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
-		doc/conf.py || die
-
-	# remove unnecessary upper bounds
-	sed -e '/Jinja2/s:,<3.0::' \
-		-e '/MarkupSafe/s:<2.0::' \
-		-i setup.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile() {
-	distutils-r1_python_compile
-
-	# Generate the grammar. It will be caught by install somehow.
-	# Note that the tests usually do it for us. However, I don't want
-	# to trust USE=test really running all the tests, especially
-	# with FEATURES=test-fail-continue.
-	pushd "${BUILD_DIR}"/lib >/dev/null || die
-	"${EPYTHON}" -m sphinx.pycode.__init__ || die "Grammar generation failed."
-	popd >/dev/null || die
-}
-
-python_compile_all() {
-	if use doc; then
-		esetup.py build_sphinx
-		HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
-	fi
-}
-
-python_test() {
-	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
-	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
-
-	local deselect=(
-		# these tests require Internet access
-		tests/test_build_latex.py::test_latex_images
-		tests/test_build_linkcheck.py::test_defaults
-		tests/test_build_linkcheck.py::test_defaults_json
-		tests/test_build_linkcheck.py::test_anchors_ignored
-	)
-	[[ ${EPYTHON} == pypy3 ]] && deselect+=(
-		tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
-		tests/test_ext_autodoc.py::test_automethod_for_builtin
-		tests/test_ext_autodoc.py::test_partialfunction
-		tests/test_ext_autodoc.py::test_autodoc_typed_instance_variables
-		tests/test_ext_autodoc.py::test_autodoc_typed_inherited_instance_variables
-		tests/test_ext_autodoc.py::test_cython
-		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
-		tests/test_ext_autodoc_autodata.py::test_autodata_type_comment
-		tests/test_ext_autodoc_autofunction.py::test_builtin_function
-		tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
-		tests/test_ext_autodoc_configs.py::test_autodoc_typehints_signature
-		tests/test_ext_autodoc_configs.py::test_autodoc_type_aliases
-		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
-		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
-		tests/test_pycode_parser.py::test_annotated_assignment
-		tests/test_build_linkcheck.py::test_connect_to_selfsigned_fails
-	)
-
-	epytest ${deselect[@]/#/--deselect }
-}