[gentoo-commits] repo/gentoo:master commit in: dev-python/Babel/

[Manuel Rüger]

commit:     cabcd4c4c31b528722d7fea231b7baa6f7796336
Author:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
AuthorDate: Fri Apr  6 22:31:25 2018 +0000
Commit:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
CommitDate: Fri Apr  6 22:31:25 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cabcd4c4

dev-python/Babel: Add missing test dependency

Thanks to Matt Turner

Closes: https://bugs.gentoo.org/651796
Package-Manager: Portage-2.3.28, Repoman-2.3.9

 dev-python/Babel/Babel-2.5.3-r1.ebuild | 49 ++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-python/Babel/Babel-2.5.3-r1.ebuild b/dev-python/Babel/Babel-2.5.3-r1.ebuild
new file mode 100644
index 00000000000..70d214cb414
--- /dev/null
+++ b/dev-python/Babel/Babel-2.5.3-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of tools for internationalizing Python applications"
+HOMEPAGE="http://babel.edgewall.org/ https://pypi.python.org/pypi/Babel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
+IUSE="doc test"
+
+RDEPEND="dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${DEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# Make the tests use implementation-specific datadir,
+	# because they try to write in it.
+	sed -e '/datadir =/s:os\.path\.dirname(__file__):os.environ["BUILD_DIR"]:' \
+		-i tests/messages/test_frontend.py || die
+	sed -e '/^intersphinx_mapping/,+3d' -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Create implementation-specific datadir for tests.
+	cp -R -l tests/messages/data "${BUILD_DIR}"/ || die
+	py.test || die
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}