[gentoo-commits] gentoo-x86 commit in dev-python/scrapy: scrapy-0.19.0.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     14/06/09 08:50:30

  Modified:             ChangeLog
  Added:                scrapy-0.19.0.ebuild
  Log:
  bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.21                 dev-python/scrapy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/scrapy/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/scrapy/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/scrapy/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/scrapy/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	3 Jun 2014 06:58:12 -0000	1.20
+++ ChangeLog	9 Jun 2014 08:50:30 -0000	1.21
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/scrapy
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/scrapy/ChangeLog,v 1.20 2014/06/03 06:58:12 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/scrapy/ChangeLog,v 1.21 2014/06/09 08:50:30 idella4 Exp $
+
+*scrapy-0.19.0 (09 Jun 2014)
+
+  09 Jun 2014; Ian Delaney <idella4@g.o> +scrapy-0.19.0.ebuild:
+  bump
 
 *scrapy-0.18.4 (03 Jun 2014)
 



1.1                  dev-python/scrapy/scrapy-0.19.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/scrapy/scrapy-0.19.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/scrapy/scrapy-0.19.0.ebuild?rev=1.1&content-type=text/plain

Index: scrapy-0.19.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/scrapy/scrapy-0.19.0.ebuild,v 1.1 2014/06/09 08:50:30 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="sqlite(+)"

inherit vcs-snapshot distutils-r1

DESCRIPTION="A high-level Python Screen Scraping framework"
HOMEPAGE="http://scrapy.org http://pypi.python.org/pypi/Scrapy/"
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="boto doc ibl test ssl"

RDEPEND="dev-python/six[${PYTHON_USEDEP}]
	dev-libs/libxml2[python,${PYTHON_USEDEP}]
	virtual/python-imaging[${PYTHON_USEDEP}]
	dev-python/lxml[${PYTHON_USEDEP}]
	ibl? ( dev-python/numpy[${PYTHON_USEDEP}] )
	ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
	boto? ( dev-python/boto[${PYTHON_USEDEP}] )
	>=dev-python/twisted-core-8.0[${PYTHON_USEDEP}]
	>=dev-python/twisted-conch-8.0[${PYTHON_USEDEP}]
	>=dev-python/twisted-mail-8.0[${PYTHON_USEDEP}]
	>=dev-python/twisted-web-8.0[${PYTHON_USEDEP}]
	>=dev-python/w3lib-1.2[${PYTHON_USEDEP}]
	dev-python/queuelib[${PYTHON_USEDEP}]"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	dev-python/six[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	test? ( ${RDEPEND}
		dev-python/boto[${PYTHON_USEDEP}]
		dev-python/django[${PYTHON_USEDEP}]
		net-ftp/vsftpd
		dev-python/pillow[${PYTHON_USEDEP}] )"

REQUIRED_USE="test? ( ssl boto )"

python_prepare_all() {
	# Skip failing tests; https://github.com/scrapy/scrapy/issues/725
	sed -e s':test_process_parallel_failure:_&:' \
		 -i scrapy/tests/test_utils_defer.py || die
	distutils-r1_python_prepare_all
}

python_compile_all() {
	if use doc; then
		PYTHONPATH="${S}" emake -C docs html || die "emake html failed"
	fi
}

python_test() {
	PYTHONPATH="${PWD}" bin/runtests.sh || die
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/build/html/. )
	distutils-r1_python_install_all
}