[gentoo-commits] repo/gentoo:master commit in: mail-filter/mimedefang/

[Sam James]

commit:     0b811ead65db4cf28645a3256167aed39b870f30
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Aug  4 01:04:36 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Aug  4 01:05:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0b811ead

mail-filter/mimedefang: depend on libmilter

libmilter and sendmail no longer block each other, and we also need a := dep on
libmilter.

(Straight-to-stable is intentional as long been in stable anyway, but not dropping
old w/ git mv or similar yet in case folks want to downgrade to older sendmail for
now.)

Signed-off-by: Sam James <sam <AT> gentoo.org>

 mail-filter/mimedefang/mimedefang-2.84-r2.ebuild | 78 ++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/mail-filter/mimedefang/mimedefang-2.84-r2.ebuild b/mail-filter/mimedefang/mimedefang-2.84-r2.ebuild
new file mode 100644
index 000000000000..5b86e55f2dba
--- /dev/null
+++ b/mail-filter/mimedefang/mimedefang-2.84-r2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Antispam, antivirus and other customizable filters for MTAs with Milter support"
+HOMEPAGE="http://www.mimedefang.org/"
+SRC_URI="http://www.mimedefang.org/static/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clamav +poll test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/defang
+	acct-user/defang
+	dev-perl/Digest-SHA1
+	dev-perl/IO-stringy
+	dev-perl/MailTools
+	dev-perl/MIME-tools
+	dev-perl/Unix-Syslog
+	mail-filter/libmilter:=
+	virtual/perl-MIME-Base64
+	clamav? ( app-antivirus/clamav )
+"
+
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-perl/Test-Class
+		dev-perl/Test-Most
+	)
+"
+
+src_prepare() {
+	eapply "${FILESDIR}/${PN}-2.72-ldflags.patch"
+	eapply "${FILESDIR}/${PN}-tests.patch"
+	eapply_user
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-user=defang
+		$(use_enable poll)
+		$(use_enable clamav)
+		$(use_enable clamav clamd)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" INSTALL_STRIP_FLAG="" install
+
+	fowners defang:defang /etc/mail/mimedefang-filter
+	fperms 644 /etc/mail/mimedefang-filter
+	insinto /etc/mail/
+	newins "${S}"/SpamAssassin/spamassassin.cf sa-mimedefang.cf
+
+	keepdir /var/spool/{MD-Quarantine,MIMEDefang}
+	fowners defang:defang /var/spool/{MD-Quarantine,MIMEDefang}
+	fperms 700 /var/spool/{MD-Quarantine,MIMEDefang}
+
+	keepdir /var/log/mimedefang
+
+	newinitd "${FILESDIR}"/${PN}.init ${PN}
+	newconfd "${FILESDIR}"/${PN}.conf ${PN}
+
+	dodoc -r examples contrib
+}
+
+pkg_postinst() {
+	elog "You can install Mail::SpamAssassin (mail-filter/spamassassin) and"
+	elog "HTML::Parser (dev-perl/HTML-Parser) even after installing if you require"
+	elog "them as they are loaded at run-time."
+}