[gentoo-commits] gentoo-x86 commit in net-analyzer/openvas-scanner: ChangeLog openvas-scanner-4.0.3-r3.ebuild

[Justin Lecher (jlec)]

jlec        14/10/01 13:03:13

  Modified:             ChangeLog
  Added:                openvas-scanner-4.0.3-r3.ebuild
  Log:
  net-analyzer/openvas-scanner: Add initial cache generation to init-script
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.12                 net-analyzer/openvas-scanner/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	1 Oct 2014 11:02:39 -0000	1.11
+++ ChangeLog	1 Oct 2014 13:03:13 -0000	1.12
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/openvas-scanner
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog,v 1.11 2014/10/01 11:02:39 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog,v 1.12 2014/10/01 13:03:13 jlec Exp $
+
+*openvas-scanner-4.0.3-r3 (01 Oct 2014)
+
+  01 Oct 2014; Justin Lecher <jlec@g.o>
+  +openvas-scanner-4.0.3-r3.ebuild, files/openvassd.init:
+  Add initial cache generation to init-script
 
   01 Oct 2014; Justin Lecher <jlec@g.o> openvas-scanner-4.0.3-r2.ebuild:
   Drop unneeded dep on cmake; prefix love



1.1                  net-analyzer/openvas-scanner/openvas-scanner-4.0.3-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-4.0.3-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-4.0.3-r3.ebuild?rev=1.1&content-type=text/plain

Index: openvas-scanner-4.0.3-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-4.0.3-r3.ebuild,v 1.1 2014/10/01 13:03:13 jlec Exp $

EAPI=5

inherit cmake-utils systemd

MY_PN=openvassd

DESCRIPTION="A remote security scanner for Linux (OpenVAS-scanner)"
HOMEPAGE="http://www.openvas.org/"
SRC_URI="http://wald.intevation.org/frs/download.php/1726/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE=""

RDEPEND="
	>=net-analyzer/openvas-libraries-7.0.4
	!net-analyzer/openvas-plugins
	!net-analyzer/openvas-server"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

PATCHES=(
	"${FILESDIR}"/${P}-bsdsource.patch
	"${FILESDIR}"/${P}-mkcertclient.patch
	"${FILESDIR}"/${P}-rulesdir.patch
	"${FILESDIR}"/${P}-run.patch
	)

src_prepare() {
	sed \
		-e '/^install.*OPENVAS_CACHE_DIR.*/d' \
		-i CMakeLists.txt || die
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		"-DLOCALSTATEDIR=${EPREFIX}/var"
		"-DSYSCONFDIR=${EPREFIX}/etc"
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	newinitd "${FILESDIR}"/${MY_PN}.init ${MY_PN}

	insinto /etc/openvas
	doins "${FILESDIR}"/${MY_PN}.conf "${FILESDIR}"/${MY_PN}-daemon.conf
	dosym ../openvas/${MY_PN}-daemon.conf /etc/conf.d/${PN}

	insinto /etc/logrotate.d
	doins "${FILESDIR}"/${MY_PN}.logrotate

	dodoc "${FILESDIR}"/openvas-nvt-sync-cron

	systemd_newtmpfilesd "${FILESDIR}"/${MY_PN}.tmpfiles.d ${MY_PN}.conf
	systemd_dounit "${FILESDIR}"/${MY_PN}.service
}

pkg_postinst() {
	elog "To use ${MY_PN}, you first need to:"
	elog "1. Call 'openvas-nvt-sync' to download/update plugins"
	elog "2. Call 'openvas-mkcert' to generate a server certificate"
}