[gentoo-commits] repo/gentoo:master commit in: media-sound/qmmp/

[Lars Wendler]

commit:     b1027d13ba5eadf1d24f3154d533af3719b26f18
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 29 20:31:55 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Sun Dec 29 20:32:23 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b1027d13

media-sound/qmmp: Bump to version 1.3.5

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 media-sound/qmmp/Manifest          |   1 +
 media-sound/qmmp/qmmp-1.3.5.ebuild | 167 +++++++++++++++++++++++++++++++++++++
 2 files changed, 168 insertions(+)

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index 687950f65fa..e9d00f68d08 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1,2 +1,3 @@
 DIST qmmp-1.3.2.tar.bz2 1221919 BLAKE2B 3081aa6b3ef4712ea064d5bb23e9ac7da5e102fde820c378438c13723bd007fe8e79ac351b0ad01ca0aa22c50f6b6773965ce418742cf1386d2ae1d7ba7b1758 SHA512 5c68d87650abf10d03dc8638df73a6694e470af1121a936bb983bcbcea04d95616ad8a55d87e8874b51b7424a890dad2c5353afe65db7029f6513a382e2144e4
 DIST qmmp-1.3.4.tar.bz2 1246048 BLAKE2B 8108e1b5f0098ee1338ccb72889614d6876855f22159e48cb54a3000a855e843d623a3a491ebcb2e7b627c014946190117bfed586729b424dd5a3564cfdc5ba0 SHA512 520a7b50a3e0bd17418bd3137a4e73a52f644ad38d7fe86647a8781ed3036cdbbd14d5311b9471443f8a2cb42422b5fa11e22acee72ff5b670a7508b55364bb5
+DIST qmmp-1.3.5.tar.bz2 1248522 BLAKE2B f59b948fc2805b376784cef429693bf2d70ba21af8699959a31b74e2c4aad2499927b48f4e5ae6166c9d9f35132418717dff8f3f9d9d447af411d97700932236 SHA512 fbf4173e6dcd78e02ee52e53d80f4477bd840047f96ef8c0bd23f56eec5efa11ac52cc458cfeae65b46cda357b986ba30e1ec4e06d35f4f96cab9a915095d735

diff --git a/media-sound/qmmp/qmmp-1.3.5.ebuild b/media-sound/qmmp/qmmp-1.3.5.ebuild
new file mode 100644
index 00000000000..88c814b238e
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.3.5.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+[[ ${PV} = 9999 ]] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2
+		mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.3"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game
+gnome jack ladspa libav lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
+pulseaudio qsui qtmedia scrobbler shout sid sndfile soxr stereo tray udisks +vorbis wavpack"
+
+REQUIRED_USE="
+	gnome? ( dbus )
+	shout? ( soxr vorbis )
+	udisks? ( dbus )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:= )
+		libav? ( media-video/libav:= )
+	)
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		media-sound/jack-audio-connection-kit
+	)
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( || (
+		media-libs/libmad
+		media-sound/mpg123
+	) )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	projectm? (
+		dev-qt/qtgui:5[-gles2]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm:=
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	shout? ( media-libs/libshout )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_ARCHIVE="$(usex archive)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FILEWRITER="$(usex vorbis)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SHOUT="$(usex shout)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}