[gentoo-commits] gentoo-x86 commit in games-arcade/stepmania: ChangeLog stepmania-3.9-r2.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/02/24 21:26:02

  Modified:             ChangeLog
  Added:                stepmania-3.9-r2.ebuild
  Log:
  Fix crash with "Select Style" wrt #298611.
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.33                 games-arcade/stepmania/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-arcade/stepmania/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	7 Sep 2009 07:30:11 -0000	1.32
+++ ChangeLog	24 Feb 2010 21:26:02 -0000	1.33
@@ -1,6 +1,12 @@
 # ChangeLog for games-arcade/stepmania
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-arcade/stepmania/ChangeLog,v 1.32 2009/09/07 07:30:11 ssuominen Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/stepmania/ChangeLog,v 1.33 2010/02/24 21:26:02 ssuominen Exp $
+
+*stepmania-3.9-r2 (24 Feb 2010)
+
+  24 Feb 2010; Samuli Suominen <ssuominen@g.o>
+  +stepmania-3.9-r2.ebuild:
+  Fix crash with "Select Style" wrt #298611.
 
   07 Sep 2009; Samuli Suominen <ssuominen@g.o>
   stepmania-3.9-r1.ebuild:



1.1                  games-arcade/stepmania/stepmania-3.9-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/stepmania-3.9-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/stepmania-3.9-r2.ebuild?rev=1.1&content-type=text/plain

Index: stepmania-3.9-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/stepmania/stepmania-3.9-r2.ebuild,v 1.1 2010/02/24 21:26:02 ssuominen Exp $

EAPI=2
inherit autotools eutils games

MY_P=StepMania-${PV}
DESCRIPTION="An advanced DDR simulator"
HOMEPAGE="http://www.stepmania.com/stepmania/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}-src.tar.gz
	mirror://sourceforge/${PN}/${MY_P}-linux.tar.gz
	http://dev.gentoo.org/~ssuominen/${P}-patches-6.tar.bz2"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug ffmpeg force-oss gtk jpeg mad vorbis"

RESTRICT="test"

RDEPEND="gtk? ( x11-libs/gtk+:2 )
	mad? ( media-libs/libmad )
	>=dev-lang/lua-5
	media-libs/libsdl[joystick,opengl]
	jpeg? ( media-libs/jpeg )
	media-libs/libpng
	ffmpeg? ( >=media-video/ffmpeg-0.5 )
	vorbis? ( media-libs/libvorbis )
	virtual/opengl
	virtual/glu"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}-src

src_prepare() {
	sed "s:/usr/share/games/${PN}:${GAMES_DATADIR}/${PN}:" \
		"${FILESDIR}"/${P}-gentoo.patch > "${T}"/${P}.patch

	EPATCH_SUFFIX=patch epatch "${T}"/${P}.patch "${WORKDIR}"/patches
	AT_M4DIR=autoconf/m4 eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_with debug) \
		$(use_with jpeg) \
		$(use_with vorbis) \
		$(use_with mad mp3) \
		$(use_enable gtk gtk2) \
		$(use_enable force-oss)
}

src_install() {
	local dir=${GAMES_DATADIR}/${PN}

	exeinto "${dir}"
	doexe src/stepmania || die "doexe failed"

	if use gtk; then
		doexe src/GtkModule.so || die "doexe failed"
	fi

	cd "${WORKDIR}"/${MY_P}

	insinto "${dir}"
	doins -r Announcers BGAnimations CDTitles Characters Courses Data Docs \
		NoteSkins RandomMovies Songs Themes Visualizations || die "doins failed"

	dodoc Copying.txt NEWS
	dohtml README-FIRST.html

	newicon "Themes/default/Graphics/Common window icon.png" ${PN}.png
	make_desktop_entry ${PN} StepMania

	games_make_wrapper ${PN} "${dir}"/${PN} "${dir}"
	prepgamesdirs
}