[gentoo-commits] gentoo-x86 commit in dev-python/bokeh: metadata.xml ChangeLog bokeh-0.4.4.ebuild

[Justin Lecher (jlec)]

jlec        14/07/07 06:52:43

  Modified:             metadata.xml ChangeLog
  Added:                bokeh-0.4.4.ebuild
  Log:
  dev-python/bokeh: Importing Version BUmp from sci overlay, thanks olifre; #516052
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.2                  dev-python/bokeh/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bokeh/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bokeh/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bokeh/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/bokeh/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	6 Feb 2014 20:02:28 -0000	1.1
+++ metadata.xml	7 Jul 2014 06:52:43 -0000	1.2
@@ -1,12 +1,15 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>sci</herd>
-<longdescription lang="en">
+  <herd>sci</herd>
+  <longdescription lang="en">
   Bokeh is a Python interactive visualization library for large
   datasets that natively uses the latest web technologies. Its goal is
   to provide elegant, concise construction of novel graphics in the
   style of Protovis/D3, while delivering high-performance
   interactivity over large data to thin clients.
 </longdescription>
+  <use>
+    <flag name="chaco">Enable interface for implementing qplot and ggplot like functionality using chaco</flag>
+  </use>
 </pkgmetadata>



1.5                  dev-python/bokeh/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bokeh/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bokeh/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bokeh/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/bokeh/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	6 Jul 2014 12:40:22 -0000	1.4
+++ ChangeLog	7 Jul 2014 06:52:43 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/bokeh
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/bokeh/ChangeLog,v 1.4 2014/07/06 12:40:22 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/bokeh/ChangeLog,v 1.5 2014/07/07 06:52:43 jlec Exp $
+
+*bokeh-0.4.4 (07 Jul 2014)
+
+  07 Jul 2014; Justin Lecher <jlec@g.o> +bokeh-0.4.4.ebuild,
+  +files/bokeh-0.4.4-fix_test_object.patch, metadata.xml:
+  Importing Version BUmp from sci overlay, thanks olifre; #516052
 
   06 Jul 2014; Michał Górny <mgorny@g.o> bokeh-0.4.1.ebuild,
   bokeh-0.4.2.ebuild, bokeh-0.4.ebuild:



1.1                  dev-python/bokeh/bokeh-0.4.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bokeh/bokeh-0.4.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bokeh/bokeh-0.4.4.ebuild?rev=1.1&content-type=text/plain

Index: bokeh-0.4.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/bokeh/bokeh-0.4.4.ebuild,v 1.1 2014/07/07 06:52:43 jlec Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} )

inherit distutils-r1

DESCRIPTION="Statistical and interactive HTML plots for Python"
HOMEPAGE="http://bokeh.pydata.org/"
SRC_URI="https://github.com/ContinuumIO/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

SLOT="0"
LICENSE="BSD"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="examples test chaco"
# docs require napoleon sphinx extension which will be included in next sphinx release

RDEPEND="
	>=dev-python/flask-0.10.1[${PYTHON_USEDEP}]
	>=dev-python/greenlet-0.4.1[${PYTHON_USEDEP}]
	>=dev-python/itsdangerous-0.23[${PYTHON_USEDEP}]
	>=dev-python/jinja-2.7[${PYTHON_USEDEP}]
	>=dev-python/markdown-2.3.1[${PYTHON_USEDEP}]
	>=dev-python/markupsafe-0.18[${PYTHON_USEDEP}]
	>=dev-python/numpy-1.7.1[${PYTHON_USEDEP}]
	>=dev-python/pandas-0.11[${PYTHON_USEDEP}]
	>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
	>=dev-python/pystache-0.5.3[${PYTHON_USEDEP}]
	>=dev-python/pytz-2013b[${PYTHON_USEDEP}]
	>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
	>=dev-python/redis-py-2.7.6[${PYTHON_USEDEP}]
	>=dev-python/requests-1.2.3[${PYTHON_USEDEP}]
	>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
	>=dev-python/werkzeug-0.9.1[${PYTHON_USEDEP}]
	$(python_gen_cond_dep '>=dev-python/gevent-1.0[${PYTHON_USEDEP}]' python2_7)
	$(python_gen_cond_dep '>=dev-python/gevent-websocket-0.9.2[${PYTHON_USEDEP}]' python2_7)
	chaco? (
		$(python_gen_cond_dep '>=dev-python/traits-4.4[${PYTHON_USEDEP}]' python2_7)
		$(python_gen_cond_dep '>=dev-python/chaco-4.4[${PYTHON_USEDEP}]' python2_7)
	)

"
# testing server: needs websocket not in portage yet
#			>=dev-python/websocket[${PYTHON_USEDEP}]
# hdf5 backend: needs array management not in portage yet
DEPEND="
	test? (
		${RDEPEND}
		>=dev-python/nose-1.3.0[${PYTHON_USEDEP}]
		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
		>=dev-python/colorama-0.2.7[${PYTHON_USEDEP}]
	)
"
DOCS=( CHANGELOG QUICKSTART.md README.md )

python_prepare_all() {
	# Fix test_references_by_ref_by_value from test_object.py
	local PATCHES=( "${FILESDIR}"/${P}-fix_test_object.patch )
	# Remove broken test case
	sed -i -e "s:MetaTest:_&:" bokeh/tests/test_bokeh_init.py || die

	if ! use chaco; then
		sed -i -e "/'bokeh.chaco_gg'/d" setup.py || die
	fi

	distutils-r1_python_prepare_all
}

python_install_all() {
	use examples && local EXAMPLES=( examples/. )

	distutils-r1_python_install_all
}

python_test() {
	cd "${BUILD_DIR}"/lib || die
	# exclude server tests for now
	nosetests -v \
		-e multiuser_auth_test \
		-e usermodel_test \
		|| die
}

pkg_postinst() {
	elog "websockets work only with python2_7"
	local chaco_msg="chaco useflag doesn't affect python targets other than python2_7"
	if use chaco; then
		if use python_targets_python2_7; then
			elog "${chaco_msg}"
		else
			ewarn "${chaco_msg}"
		fi
	fi
}