[gentoo-commits] repo/gentoo:master commit in: www-client/opera/

[Stephan Hartmann]

commit:     f90a8cfca6ff92c6da4a44dd2b8ecded4a78e92d
Author:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
AuthorDate: Sun Nov  1 18:19:38 2020 +0000
Commit:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
CommitDate: Sun Nov  1 18:20:09 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f90a8cfc

www-client/opera: bump to 72.0.3815.186

Bug: https://bugs.gentoo.org/750929
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Stephan Hartmann <sultan <AT> gentoo.org>

 www-client/opera/Manifest                   |  1 +
 www-client/opera/opera-72.0.3815.186.ebuild | 97 +++++++++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index 6e9ae34e3e7..c3349bfe429 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1 +1,2 @@
 DIST opera-stable_71.0.3770.271_amd64.deb 67845484 BLAKE2B f15d1948aee0e74fd1fdb1abf9ff9f819725b4b44763c34f79d28a91f24e9a0389e8181c58ce9a774017e2aec302121abcd2a4894091085e60ed9cf5eb438476 SHA512 63a4c2753f5cd2655b15abb87b80e01d98d44fb5c8119e846b3c484f07c99065a7358c72c4219cd5a431988112b73c5801ae2ae84d91d3a4ba0b93c545f469e0
+DIST opera-stable_72.0.3815.186_amd64.deb 69752980 BLAKE2B 2fcc33ccd89d92e0860840563b36e0c2333cdc07476bcd3583d0b0ba586c9fd1f4a927ec2b89f813e1e2e9dd9cb238753a7ce3b497740367bb3b4fd3fc2efae7 SHA512 1f6711aa0f292d021f871929e603501924e4ee40e039410e2b6f7dafb0d505d7e962020e91ff8606d1dcfe9ef628769397b6f806b6806a399e8310e180efe787

diff --git a/www-client/opera/opera-72.0.3815.186.ebuild b/www-client/opera/opera-72.0.3815.186.ebuild
new file mode 100644
index 00000000000..3705d75b221
--- /dev/null
+++ b/www-client/opera/opera-72.0.3815.186.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/desktop/${PV}/linux/${PN}-stable_${PV}_amd64.deb"
+"
+done
+KEYWORDS="~amd64"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa[gbm]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/libdrm
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libxcb
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+pkg_setup() {
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	default
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+	esac
+
+	rm usr/bin/${PN} || die
+
+	rm usr/share/doc/${PN}-stable/copyright || die
+	mv usr/share/doc/${PN}-stable usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	rm "${OPERA_HOME}"/${PN}_autoupdate || die
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}